Slim Node Si7021 sensor example

m26872

@rsachoc It's probably it. And yes, it's rigth there. Make sure all of the three small pads interconnect.

rsachoc

@m26872 thanks! No time tonight, but a job for testing tomorrow.

DavidZH

You could also use the 328 pullups! I had an unwilling Chinese light sensor (MAX44099) that drew a lot of power either with the VCC on or off. Since it's battery powered that is undesireable.

I used digitalWrite(SDA, LOW); digitalWrite(SCL, LOW); to tie the bus to ground. When the sensor wakes up, it writes HIGH to those pins and the bus is back online. Used a 500ms wait after this to let the sensors stabilise.

That sensor is now on a 6µA sleep current and a average 128µA over 2 hours measured with a 2 minute sleep cycle.

rsachoc

Tried it this evening, still no luck, let me see what I can get up to over the weekend.

m26872

@DavidZH True, internal pull-ups (20k?) should probably be enough for the normal i2c use (short wires, low speed, etc). But I wonder if pull-ups are consuming any significant power during passive state like sleeping sensor. Of course it's a good solution in case there're issues preventing the bus from beeing silent. Or worse, pulled down continuously.
What was your current before the change?
I think 500ms awake is a lot.

m26872

@rsachoc Crap. Maybe it's something else then.:disappointed:

DavidZH

I switch them off with a LOW write before the sensor goes to sleep and you're absolutely right about the wait time being very long. In this case I didn't mind because the sensor is powered by a solar panel.
I can't really remember what the exact value but it was an order of magnitude... I also used the voltage divider way to measure voltage because the Moteino has a regulator on board, so that upped the sleep current a little (10M resistor to keep the current low).

I went searching because the current went UP when I switched the power to the sensor off before sleep. Gammon.co.au is a very useful source, but I can't remember where I dug this hack up.
I will be making other battery sensors for inside with a HTU21d and I will post more on those in a 'My Project' mega gallery including measurements. (And dig around in the HTU datasheet for the start up time....)

rollercontainer

According to the datasheet the absolute maximum time to get ready is 80ms.

DavidZH

Thanx! Saves me a trip! :grin:

rollercontainer

RTFM :-P

https://www.silabs.com/Support Documents/TechnicalDocs/Si7021-A20.pdf

Page 5

rsachoc

Ok, so I messed up my previous sensor trying to solder the bridge (don't ask...) I have now (I think) soldered it and reconnected it, am now getting the following:

Serial started
Voltage: 3359 mV
send: 132-132-0-0 s=255,c=3,t=15,pt=2,l=2,sg=0,st=fail:0
send: 132-132-0-0 s=255,c=0,t=17,pt=0,l=5,sg=0,st=fail:1.5.4
send: 132-132-0-0 s=255,c=3,t=6,pt=1,l=1,sg=0,st=fail:0
sensor started, id=132, parent=0, distance=1
send: 132-132-0-0 s=255,c=3,t=11,pt=0,l=15,sg=0,st=fail:EgTmpHumBat5min
send: 132-132-0-0 s=255,c=3,t=12,pt=0,l=10,sg=0,st=fail:1.0 151106
send: 132-132-0-0 s=0,c=0,t=6,pt=0,l=0,sg=0,st=fail:
find parent
send: 132-132-255-255 s=255,c=3,t=7,pt=0,l=0,sg=0,st=bc:
send: 132-132-0-0 s=1,c=0,t=7,pt=0,l=0,sg=0,st=fail:
Node and 2 children presented.

I'm going to try get everything on a breadboard, but now I see fails, what's that all about?

PS will upload some pics of the soldered bridge...

m26872

@rsachoc google "mysensors st fail"

LastSamurai

I am currently trying to use that red 3.3v module too and it doesn't seem to work. I have the sketch from above running with the "normal" blue module where I remove the voltage converter so that it works at 3.3V without a problem.
Then I switched to the red one (with these small 3 solderpads connected) and the scl/sda lines switched (the order is different form the blue one) but the program gets stuck at the same position as above (without the st=fail's though). So I assume that

si7021_env data = humiditySensor.getHumidityAndTemperature();

fails. Does anyone have one of these sensors up and running? Any ideas where the error is? Otherwise I guess I have to stick with the blue ones.

GertSanders

@LastSamurai
The red ones are HTU21D and need another library (they are different from the SI7021).
Use the Adafruit library for this module (look on their site for HTU21D).

rsachoc

@GertSanders hmmm I think I'm using that same one as @LastSamurai so I suspect that's the issue? It's the one linked in the first post

I guess if that's the problem it should have been obvious to me, it even says HTU21D on mine! Silly me!

GertSanders

@rsachoc
Either one of these libraries will work with the HTU21D modules.

0_1463432234134_Screen Shot 2016-05-16 at 22.55.51.png

Both modules do the same, but have different I2C adresses so you can actually use both at the same time (of you like to compare them), but you need different libraries to call each one.

LastSamurai

@GertSanders Thanks, I don't know why I didn't realize that ;)
I will try that out tomorrow.

rsachoc

@LastSamurai I'm having a go as well at updating the .ino file with the different library, but I'm not a coder so I'm "having a hack" - if you have any luck could you post your code?

LastSamurai

@rsachoc Yes, I actually just tried it out and its working.
Here is my code for now (just for testing):
I basically just switched libraries

/* Sketch with Si7021 and battery monitoring.
by m26872, 20151109 
Changed by LastSamurai
15052016
*/
#include <MySensor.h>  
#include <Wire.h>
#include <SPI.h>
#include <SparkFunHTU21D.h>
#include <RunningAverage.h>

//#define DEBUG

#ifdef DEBUG
#define DEBUG_SERIAL(x) Serial.begin(x)
#define DEBUG_PRINT(x) Serial.print(x)
#define DEBUG_PRINTLN(x) Serial.println(x)
#else
#define DEBUG_SERIAL(x)
#define DEBUG_PRINT(x) 
#define DEBUG_PRINTLN(x) 
#endif

#define NODE_ID 100             // <<<<<<<<<<<<<<<<<<<<<<<<<<<   Enter Node_ID
#define CHILD_ID_TEMP 0
#define CHILD_ID_HUM 1
// #define SLEEP_TIME 15000 // 15s for DEBUG
#define SLEEP_TIME 300000   // 5 min
#define FORCE_TRANSMIT_CYCLE 36  // 5min*12=1/hour, 5min*36=1/3hour 
#define BATTERY_REPORT_CYCLE 2016   // Once per 5min   =>   12*24*7 = 2016 (one report/week)
#define VMIN 1900
#define VMAX 3300
#define HUMI_TRANSMIT_THRESHOLD 3.0  // THRESHOLD tells how much the value should have changed since last time it was transmitted.
#define TEMP_TRANSMIT_THRESHOLD 0.5
#define AVERAGES 2

int batteryReportCounter = BATTERY_REPORT_CYCLE - 1;  // to make it report the first time.
int measureCount = 0;
float lastTemperature = -100;
int lastHumidity = -100;

RunningAverage raHum(AVERAGES);
HTU21D humiditySensor;

MySensor gw;
MyMessage msgTemp(CHILD_ID_TEMP,V_TEMP); // Initialize temperature message
MyMessage msgHum(CHILD_ID_HUM,V_HUM);

void setup() {
  DEBUG_SERIAL(9600);    // <<<<<<<<<<<<<<<<<<<<<<<<<< Note BAUD_RATE in MySensors.h
  DEBUG_PRINTLN("Serial started");
  
  DEBUG_PRINT("Voltage: ");
  DEBUG_PRINT(readVcc()); 
  DEBUG_PRINTLN(" mV");

  delay(500);
  DEBUG_PRINT("Internal temp: ");
  DEBUG_PRINT(GetInternalTemp()); // Probably not calibrated. Just to print something.
  DEBUG_PRINTLN(" *C");

  delay(500); // Allow time for radio if power useed as reset
  gw.begin(NULL, NODE_ID);
  gw.sendSketchInfo("TempHumTest2", "1.0 17052016"); 
  gw.present(CHILD_ID_TEMP, S_TEMP);   // Present sensor to controller
  gw.present(CHILD_ID_HUM, S_HUM);
  DEBUG_PRINT("Node and "); DEBUG_PRINTLN("2 children presented.");
  
  raHum.clear();
  humiditySensor.begin();  
}

void loop() { 

  measureCount ++;
  batteryReportCounter ++;
  bool forceTransmit = false;
  
  if (measureCount > FORCE_TRANSMIT_CYCLE) {
    forceTransmit = true; 
  }
  sendTempHumidityMeasurements(forceTransmit);
/*
  // Read and print internal temp
  float temperature0 = static_cast<float>(static_cast<int>((GetInternalTemp()+0.5) * 10.)) / 10.;
  DEBUG_PRINT("Internal Temp: "); DEBUG_PRINT(temperature0); DEBUG_PRINTLN(" *C");        
*/
  // Check battery
  if (batteryReportCounter >= BATTERY_REPORT_CYCLE) {
    long batteryVolt = readVcc();
    DEBUG_PRINT("Battery voltage: "); DEBUG_PRINT(batteryVolt); DEBUG_PRINTLN(" mV");
    uint8_t batteryPcnt = constrain(map(batteryVolt,VMIN,VMAX,0,100),0,255);   
    DEBUG_PRINT("Battery percent: "); DEBUG_PRINT(batteryPcnt); DEBUG_PRINTLN(" %");
    gw.sendBatteryLevel(batteryPcnt);
    batteryReportCounter = 0;
  }
  
  gw.sleep(SLEEP_TIME);
}

// function for reading Vcc by reading 1.1V reference against AVcc. Based from http://provideyourown.com/2012/secret-arduino-voltmeter-measure-battery-voltage/
// To calibrate reading replace 1125300L with scale_constant = internal1.1Ref * 1023 * 1000, where internal1.1Ref = 1.1 * Vcc1 (per voltmeter) / Vcc2 (per readVcc() function) 
long readVcc() {
  // set the reference to Vcc and the measurement to the internal 1.1V reference
  ADMUX = _BV(REFS0) | _BV(MUX3) | _BV(MUX2) | _BV(MUX1);
  delay(2); // Wait for Vref to settle
  ADCSRA |= _BV(ADSC); // Start conversion
  while (bit_is_set(ADCSRA,ADSC)); // measuring
  uint8_t low  = ADCL; // must read ADCL first - it then locks ADCH  
  uint8_t high = ADCH; // unlocks both
  long result = (high<<8) | low;
  result = 1125300L / result; // Calculate Vcc (in mV); 1125300 = 1.1*1023*1000
  return result; // Vcc in millivolts
}
// function for reading internal temp. From http://playground.arduino.cc/Main/InternalTemperatureSensor 
double GetInternalTemp(void) {  // (Both double and float are 4 byte in most arduino implementation)
  unsigned int wADC;
  double t;
  // The internal temperature has to be used with the internal reference of 1.1V. Channel 8 can not be selected with the analogRead function yet.
  ADMUX = (_BV(REFS1) | _BV(REFS0) | _BV(MUX3));   // Set the internal reference and mux.
  ADCSRA |= _BV(ADEN);  // enable the ADC
  delay(20);            // wait for voltages to become stable.
  ADCSRA |= _BV(ADSC);  // Start the ADC
  while (bit_is_set(ADCSRA,ADSC));   // Detect end-of-conversion
  wADC = ADCW;   // Reading register "ADCW" takes care of how to read ADCL and ADCH.
  t = (wADC - 88.0 ) / 1.0;   // The default offset is 324.31.
  return (t);   // The returned temperature in degrees Celcius.
}

/*********************************************
 * * Sends temperature and humidity from Si7021 sensor
 * Parameters
 * - force : Forces transmission of a value (even if it's the same as previous measurement)
 *********************************************/
void sendTempHumidityMeasurements(bool force) {
  bool tx = force;
  
  float temperature = humiditySensor.readTemperature();
  DEBUG_PRINT("T: ");DEBUG_PRINTLN(temperature);

  float diffTemp = abs(lastTemperature - temperature);
  DEBUG_PRINT(F("TempDiff :"));DEBUG_PRINTLN(diffTemp);

  if (diffTemp > TEMP_TRANSMIT_THRESHOLD || tx) {
    gw.send(msgTemp.set(temperature,1));
    lastTemperature = temperature;
    measureCount = 0;
    DEBUG_PRINTLN("T sent!");
  }
  
  int humidity = humiditySensor.readHumidity();
  DEBUG_PRINT("H: ");DEBUG_PRINTLN(humidity);

  raHum.addValue(humidity);
  humidity = raHum.getAverage();  // MA sample imply reasonable fast sample frequency
  float diffHum = abs(lastHumidity - humidity);
  DEBUG_PRINT(F("HumDiff  :"));DEBUG_PRINTLN(diffHum); 

  if (diffHum > HUMI_TRANSMIT_THRESHOLD || tx) {
    gw.send(msgHum.set(humidity));
    lastHumidity = humidity;
    measureCount = 0;
    DEBUG_PRINTLN("H sent!");
  }

}

rsachoc

@LastSamurai thanks, progress, I'm getting this now, which means it's working! Finally, a working node from a complete rookie like me!

Serial started
Voltage: 3389 mV
Internal temp: 266.00 *C
send: 100-100-0-0 s=255,c=3,t=15,pt=2,l=2,sg=0,st=ok:0
send: 100-100-0-0 s=255,c=0,t=17,pt=0,l=5,sg=0,st=ok:1.5.4
send: 100-100-0-0 s=255,c=3,t=6,pt=1,l=1,sg=0,st=ok:0
read: 0-0-100 s=255,c=3,t=15,pt=0,l=2,sg=0:
sensor started, id=100, parent=0, distance=1
send: 100-100-0-0 s=255,c=3,t=11,pt=0,l=12,sg=0,st=fail:TempHumTest2
send: 100-100-0-0 s=255,c=3,t=12,pt=0,l=12,sg=0,st=fail:1.0 17052016
send: 100-100-0-0 s=0,c=0,t=6,pt=0,l=0,sg=0,st=fail:
send: 100-100-0-0 s=1,c=0,t=7,pt=0,l=0,sg=0,st=fail:
Node and 2 children presented.
T: 998.00
TempDiff :1098.00
send: 100-100-0-0 s=0,c=1,t=0,pt=7,l=5,sg=0,st=fail:998.0
T sent!
H: 118
HumDiff  :218.00
send: 100-100-0-0 s=1,c=1,t=1,pt=2,l=2,sg=0,st=ok:118
H sent!
Battery voltage: 3359 mV
Battery percent: 104 %
send: 100-100-0-0 s=255,c=3,t=0,pt=1,l=1,sg=0,st=ok:104

I think that the readings are not accurate though, not sure why, but I'll have a go at figuring our why anyway!

Slim Node Si7021 sensor example

9

11.7k

11.2k

113.0k