💬 Relay

pepson

Hi
Please put to this topic code your sketch....
Thanks

lekeb

Sur,

my node controls two relays, one water pressure sensor and three DS18b20

/**
 code pour controle cave a vin, temp et pression
 */

// Enable debug prints to serial monitor
//#define MY_DEBUG

// Enable and select radio type attached
#define MY_RADIO_NRF24

// Enable repeater functionality for this node
#define MY_REPEATER_FEATURE

#define MY_NODE_ID 15
#include <SPI.h>
#include <MySensors.h>
#include <DallasTemperature.h>
#include <OneWire.h>

#define BARO_CHILD 0 //Child ID for pressure sensor
#define BAR_SENSOR_ANALOG_PIN 0 // pin for pressure sensor

#define COMPARE_TEMP 1 // Send temperature only if changed? 1 = Yes 0 = No

#define ONE_WIRE_BUS 5 // Pin where dallase sensor is connected 
#define MAX_ATTACHED_DS18B20 16
#define RELAY_PIN 3 //pin for first relay
#define NUMBER_OF_RELAYS 2
#define RELAY_ON 1  // GPIO value to write to turn on attached relay
#define RELAY_OFF 0 // GPIO value to write to turn off attached relay

OneWire oneWire(ONE_WIRE_BUS); // Setup a oneWire instance to communicate with any OneWire devices (not just Maxim/Dallas temperature ICs)
DallasTemperature sensors(&oneWire); // Pass the oneWire reference to Dallas Temperature. 
float lastTemperature[MAX_ATTACHED_DS18B20];
int numSensors=0;
bool receivedConfig = false;
bool metric = true;
float lastpression;
uint8_t DS_First_Child_ID = 4; //First Child-ID to be used by Dallas Bus
MyMessage pressureMsg(BARO_CHILD, V_PRESSURE);
MyMessage msg(0,V_TEMP);


void before()
{
    for (int sensor=1, pin=RELAY_PIN; sensor<=NUMBER_OF_RELAYS; sensor++, pin++) {
        // Then set relay pins in output mode
        pinMode(pin, OUTPUT);
        // Set relay to last known state (using eeprom storage)
        digitalWrite(pin, loadState(sensor)?RELAY_ON:RELAY_OFF);
    }
    
    // Startup up the OneWire library
  sensors.begin();
}

void setup()
{
   
// requestTemperatures() will not block current thread
  sensors.setWaitForConversion(false);
}

void presentation()
{
    // Send the sketch version information to the gateway and Controller
    sendSketchInfo("Buanderie node", "1.0");

    //present pressure sensor
    present(BARO_CHILD, S_BARO);

    for (int sensor=1, pin=RELAY_PIN; sensor<=NUMBER_OF_RELAYS; sensor++, pin++) {
        // Register all sensors to gw (they will be created as child devices)
        present(sensor, S_BINARY);
    }

    
// Fetch the number of attached temperature sensors  
  numSensors = sensors.getDeviceCount();

  // Present all sensors to controller
  for (int i=0; i<numSensors && i<MAX_ATTACHED_DS18B20; i++) {   
     present(i + DS_First_Child_ID, S_TEMP);
  }
}



void loop()
{
  //read water pressure
int lecture_adc = analogRead(BAR_SENSOR_ANALOG_PIN);
  float pression = ((lecture_adc*5/1024.0)-0.50)/1.7;
  if(pression != lastpression) { 
      send(pressureMsg.set(pression, 2));
  lastpression = pression;
  }
  
  
  // Fetch temperatures from Dallas sensors
  sensors.requestTemperatures();

  // query conversion time and sleep until conversion completed
  int16_t conversionTime = sensors.millisToWaitForConversion(sensors.getResolution());
  // sleep() call can be replaced by wait() call if node need to process incoming messages (or if node is repeater)
  sleep(conversionTime);

  // Read temperatures and send them to controller 
  for (int i=0; i<numSensors && i<MAX_ATTACHED_DS18B20; i++) {

    // Fetch and round temperature to one decimal
    float temperature = static_cast<float>(static_cast<int>((getControllerConfig().isMetric?sensors.getTempCByIndex(i):sensors.getTempFByIndex(i)) * 10.)) / 10.;

    // Only send data if temperature has changed and no error
    #if COMPARE_TEMP == 1
    if (lastTemperature[i] != temperature && temperature != -127.00 && temperature != 85.00) {
    #else
    if (temperature != -127.00 && temperature != 85.00) {
    #endif

      // Send in the new temperature
      send(msg.setSensor(i + DS_First_Child_ID).set(temperature,1));
      // Save new temperatures for next compare
      lastTemperature[i]=temperature;
    }
  }
}

void receive(const MyMessage &message)
{
    // We only expect one type of message from controller. But we better check anyway.
    if (message.type==V_STATUS) {
        // Change relay state
        digitalWrite(message.sensor-1+RELAY_PIN, message.getBool()?RELAY_ON:RELAY_OFF);
        // Store state in eeprom
        saveState(message.sensor, message.getBool());
        // Write some debug info
        Serial.print("Incoming change for sensor:");
        Serial.print(message.sensor);
        Serial.print(", New status: ");
        Serial.println(message.getBool());
    }
}

gohan

@lekeb said in 💬 Relay:

MyMessage pressureMsg(BARO_CHILD, V_PRESSURE);
MyMessage msg(0,V_TEMP);

Why are you using the same child ID (since you set #define BARO_CHILD 0)?

rejoe2

@gohan Effectively, he will never report any temp reading under ChildID 0. Within presentation() and the send() commands, the "0" is replaced by "i + DS_First_Child_ID".
But you are partly right, to avoid any misunderstandings wrt. that the statement could also be written as follows:

MyMessage msg(DS_First_Child_ID,V_TEMP);

lekeb

correct, it makes sense. I will correct this error.
However Domoticz reads correctly the temperature and links correctly the CHILD ID's, so...

Jonathan Pucel

Hello everybody !

I would like to creat a sensor with two relays and two buttons to command this relay direct from the sensor (with actualisation of their stat in domoticz)
Someone know the code to do this ? I'm a complete newbie on mysensor !

Thank's a lot !

rejoe2

@jonathan-pucel Have a look at the code in this post.

Jonathan Pucel

Excellent ! It's perfect, thank's a lot rejoe2 !

mysz0n

This post is deleted!

Vorace

Hi
Using Home assistant, and Optimistic set to false in the mysensors config, the switch in homeassistant would turn the relay on, but in the view in homeassistant the flip switch jumped off straight after switching on. It was solved by adding the following line to the sketch, ensuring that hassio knows that the actuator actually have received the command. Not sure if this is a good way of doing it, but it seems to work for me.
send(msg.set(state)); // Send new state and request ack back
in:
void receive(const MyMessage &message) {
// We only expect one type of message from controller. But we better check anyway.
if (message.isAck()) {
Serial.println("This is an ack from gateway");
}

if (message.type == V_LIGHT) {
// Change relay state
state = message.getBool();
digitalWrite(RELAY_PIN, state?RELAY_ON:RELAY_OFF);
// Store state in eeprom
saveState(CHILD_ID, state);

 // Write some debug info
 Serial.print("Incoming change for sensor:");
 Serial.print(message.sensor);
 Serial.print(", New status: ");
 Serial.println(message.getBool());
 send(msg.set(state)); // Send new state and request ack back

}
}

Thanks

arraWX

Hi!

I would like to control some 230VAC equipment (for now roller shutters), based on inputs from my mysensors sensors (temperature and light). For controller I use domoticz.

I would like a safe, robust and preferably authorized/lawful solution (I'm in EU/Denmark).

I came across the following solutions:

https://aeotec.com/z-wave-plug-in-switch
https://sonoff.itead.cc/en/products/sonoff/sonoff-basic
https://dlidirect.com/products/iot-power-relay

I think the first one and maybe the second one will be authorized/lawful...? However, I have experience only with mysensors and neither z wave nor sonoff...

Anyone has some experience/thoughts/suggestions to share?

Thanks.

gohan

There are also roller shutters nodes running via zwave if you are looking at a retail solution

arraWX

Thank you @gohan! Retail solution is not the keyword here. What I am searching for is an authorized/lawful (safe) solution.

I decided to do my own node (mysensors) with a cheap relay module for the arduino. Once I achieve the desired functionality I will change to some more robust hardware. Following your suggestion this could be a z wave roller shutter (e.g. fibaro or qubino).

bjacobse

@arrawx said in 💬 Relay:

Retail solution is not the keyword here. What I am searching for is an authorized/lawful (safe) solution.

Sorry to comment negative, but your wording doesn't make sense. either you will go for a DIY solution, cheap and illegal (but not necessary a bad solution), or you will purchase a retail solution.
Retail solution must have the required certificates to allow you to sell. Those are not cheap to get, which also provide the reason for a retail solution to
be usually fairly expensive
https://arbejdstilsynet.dk/da/regler/bekendtgorelser/i/sam-indretning-af-tekniske-hjaelpemidler-612

And also you need Notified Body
https://en.wikipedia.org/wiki/Notified_Body

And I know that Cetekom can create certificate for Country Approvals
https://www.cetecom.com/en/certification/country-appoval/

slt1

There is a problem with the example code for RelayActuator.ino It is not checking for ACK messages. See the other example called SecureActuator.ino that does this. Without checking for ACK messages my relay gets an ON signal and turns on then immediately thereafter gets an ACK signal for V_STATUS command which is assumed in this example to be a control and the value is "0" so it turns off the relay.

mfalkvidd

@slt1 I'm not sure I'm following. RelayActuator.ino does not send any messages, so it should never receive any ack messages. Compare with RelayWithButtonActuator.ino which does send messages, and therefore also checks for ack.

Could you elaborate on the problem?

slt1

@mfalkvidd

For some reason I am now unable to reproduce the issue on the standard RelayActuator.ino example. It was definitely sending ACK requests when I was testing a few days ago. I have subsequently updated MySensors library and also MyController to their latest Snapshot - so perhaps the issue comes up under one of those scenarios.

The issue around this though is that the example does not report the current status of the relay in the loop. My own sketch was doing so. I guess many people take an example and modify it like I do. Therefore copying the example and adding in the code to send the current relay status periodically means the receive function will not work properly due to the Ack messages received,

I would then suggest adding a note to the receive function of the relay example sketch to say that "if your node sends messages then you need to check for Ack and discard those messages" - or something along those lines. This will help !

mfalkvidd

@slt1 thanks for explaining.

I'll think about it for a bit but I hope to submit a pull request soon. I'll post here when it is ready.

mfalkvidd

@slt1 sending current status won't generate an ack/echo message. So there should not be a need to handle the ack/echo flag. Hardware acks (which are enabled by default) do not trigger the receive function.

The only case when an ack/echo message will be sent is if the sketch developer explicitly requests an ack/echo by setting the ack parameter in send() to true. If the sketch developer does that, they need to handle the ack/echo message inside the receive function, according to however they plan to handle the ack/echo message.

My guess is that people set the ack flag to true without understanding what they are doing. I hope to make the documentation slightly less confusing by doing https://github.com/mysensors/MySensors/issues/1103

slt1

@mfalkvidd Thanks - and yes - I did make the assumption that send with ack = true means do a hardware ack. I was unaware that a "software ack" also exists. I read your comment here : https://forum.mysensors.org/topic/3346/discussion-reliable-delivery/17 and what you mention there needs to be made loud and clear in the docs - perhaps some mention in both the message send function and message receive function,

💬 Relay

23

11.7k

11.2k

113.1k