[SOLVED] Multisensor Node stops working after some days...



  • Hi folks...

    I have a multisensor node on my baby's room created with:

    • Arduino Nano powered by wiring VIN from an old cell phone power adapter, which is connected on a wall switch, where I can turn it on and off easily if something is wrong...
    • MQ-2 gas sensor
    • DHT-11 for humidity and temp
    • 1 channel Relay which is connected to a wall AC power to turn on/off a Humidifier.

    When connected through the VIN it works during some days and them stop working as soon as I act the relay.
    If I use the relay the same day I turn it for the first time, it works, but after 2 or 3 days it stops working.
    When reseted, it sends the first value but when reach the relay presentation stop.

    When powered by USB all works fine, because of that I have nothing on the serial monitor...

    Is it a soldering problem in VIN terminal?
    If it is a power problem, why is it intermittent?

    This is my sketch:

    #define MY_DEBUG
    #define MY_RADIO_NRF24
    #define MY_NODE_ID 10
    
    #include <SPI.h>
    #include <MySensors.h>
    #include <DHT.h>  
    #include <Bounce2.h>
    
    #define RELAY_ON 0
    #define RELAY_OFF 1
    #define RELAY_MSG_ON 1
    #define RELAY_MSG_OFF 0
    #define RELAY_PIN  3
    #define BUTTON_PIN  2
    #define HUMIDITY_SENSOR_DIGITAL_PIN 5
    #define MQ_SENSOR_ANALOG_PIN         (0)  //define which analog input channel you are going to use
    
    #define RL_VALUE                     (1)     //define the load resistance on the board, in kilo ohms
    #define RO_CLEAN_AIR_FACTOR          (9.83)  //RO_CLEAR_AIR_FACTOR=(Sensor resistance in clean air)/RO,
    #define CALIBARAION_SAMPLE_TIMES     (50)    //define how many samples you are going to take in the calibration phase
    #define CALIBRATION_SAMPLE_INTERVAL  (500)   //define the time interal(in milisecond) between each samples in the
    #define READ_SAMPLE_INTERVAL         (50)    //define how many samples you are going to take in normal operation
    #define READ_SAMPLE_TIMES            (5)     //define the time interal(in milisecond) between each samples in
    #define GAS_LPG                      (0)
    #define GAS_CO                       (1)
    #define GAS_SMOKE                    (2)
    
    #define CHILD_ID_TEMP 3
    #define CHILD_ID_HUM 2
    #define CHILD_ID_MQ 0
    #define CHILD_ID_SWITCH 1
    
    unsigned long SLEEP_TIME = 6000; // Sleep time between reads (in loops)
    unsigned long sleeptimer = 5000;
    
    DHT dht;
    signed int lastTemp;
    signed int lastHum;
    int temp_correct;
    int hum_correct;
    int med_LPG;
    int med_CO;
    int med_SMOKE;
    bool metric = true; 
    Bounce debouncer = Bounce();
    bool state;
    bool initialValueSent = false;
    
    float Ro = 10000.0;    // this has to be tuned 10K Ohm
    int val = 0;           // variable to store the value coming from the sensor
    int valMQ = 0;
    int lastMQ = 0;
    float LPGCurve[3]  =  {2.3,0.21,-0.47};   //two points are taken from the curve.
    float COCurve[3]  =  {2.3,0.72,-0.34};    //two points are taken from the curve.
    float SmokeCurve[3] = {2.3,0.53,-0.44};   //two points are taken from the curve.
    
    MyMessage msg(CHILD_ID_MQ, V_LEVEL);
    MyMessage msgPrefix(CHILD_ID_MQ, V_UNIT_PREFIX);
    MyMessage msgHum(CHILD_ID_HUM, V_HUM);
    MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
    MyMessage msgSwitch(CHILD_ID_SWITCH, V_LIGHT);
    
    void presentation()  
    { 
      sendSketchInfo("Baby", "1.0");
      wait(200);
      present(CHILD_ID_TEMP, S_TEMP);
      wait(200);
      present(CHILD_ID_HUM, S_HUM);
      wait(200);
      present(CHILD_ID_SWITCH, S_LIGHT);
      wait(200);
      present(CHILD_ID_MQ, S_AIR_QUALITY);
      metric = getControllerConfig().isMetric;
    }
    
    void setup()  
    { 
      pinMode(BUTTON_PIN, INPUT);
      digitalWrite(BUTTON_PIN, HIGH);
      debouncer.attach(BUTTON_PIN);
      debouncer.interval(5);
    
      // Make sure relays are off when starting up
      digitalWrite(RELAY_PIN, RELAY_OFF);
      pinMode(RELAY_PIN, OUTPUT);
    
      state = loadState(CHILD_ID_SWITCH);
      digitalWrite(RELAY_PIN, state?RELAY_ON:RELAY_OFF);
      
      dht.setup(HUMIDITY_SENSOR_DIGITAL_PIN); 
      wait(2000);
      signed int temperature = dht.getTemperature() + 0.5;
      wait(2000);
      signed int humidity = dht.getHumidity() + 0.5;
      wait(100);
      send(msgTemp.set(temperature));
      wait(100);
      send(msgHum.set(humidity));
      wait(100);
      send(msg.set("0"));
    
      Ro = MQCalibration(
               MQ_SENSOR_ANALOG_PIN);         //Calibrating the sensor. Please make sure the sensor is in clean air
      send(msgPrefix.set("GCF"));
    }
    
    void loop()  { 
      if (!initialValueSent) {
        Serial.println("Sending initial value");
        send(msgSwitch.set(state?RELAY_MSG_ON:RELAY_MSG_OFF));
        Serial.println("Requesting initial value from controller");
        request(CHILD_ID_SWITCH, V_STATUS);
        wait(2000, C_SET, V_STATUS);
      }
      bool changed = debouncer.update();
      int value = debouncer.read();
      if (changed && value==0) {
        // Send new state and request ack back
        send(msgSwitch.set(state?false:true), true);
      }
      
      if (sleeptimer > SLEEP_TIME)    {
        sleeptimer= 0;
        // Fetch temperatures from DHT sensor
        signed int temperature = dht.getTemperature() + 0.5;
        if (isnan(temperature)) {
            Serial.println("Failed reading temperature from DHT");
        } else if (temperature != lastTemp) {
          lastTemp = temperature;
          if (!metric) {
            temperature = dht.toFahrenheit(temperature) + 0.5;
          }
          int temp_correct = temperature * 1.08;
          send(msgTemp.set(temp_correct));
          #ifdef MY_DEBUG
          Serial.print("Temp: ");
          Serial.println(temperature);
          #endif
        }
        
        // Fetch humidity from DHT sensor
        signed int humidity = dht.getHumidity() + 0.5;
        if (isnan(humidity)) {
            Serial.println("Failed reading humidity from DHT");
        } else if (humidity != lastHum) {
          lastHum = humidity;
          int hum_correct = 2.7 * humidity - 0.015 * humidity * humidity - 31.125;
          send(msgHum.set(hum_correct));
          #ifdef MY_DEBUG
          Serial.print("Umid: ");
          Serial.println(humidity);
          #endif
        }
    
        // Air Sensor - I wanted a composed number to knowing what kind of gas is reported. Everything bellow 80 is reported as 0, and increases from 111, where each number is about a different gas
     
        med_LPG = ((int) (MQGetGasPercentage(MQRead(MQ_SENSOR_ANALOG_PIN)/Ro,GAS_LPG) + 80) / 80) * 100;
        med_CO = ((int) (MQGetGasPercentage(MQRead(MQ_SENSOR_ANALOG_PIN)/Ro,GAS_CO) + 80) / 80) * 10;
        med_SMOKE = ((int) (MQGetGasPercentage(MQRead(MQ_SENSOR_ANALOG_PIN)/Ro,GAS_SMOKE) + 80) / 80);
        valMQ = med_LPG + med_CO + med_SMOKE;
        if (valMQ != lastMQ) {
          if (valMQ < 112) {
            send(msg.set(0));
          } else send(msg.set(valMQ));
          lastMQ = valMQ;
          Serial.print("Gas (LPG CO SMOKE): ");
          Serial.println(valMQ);
        }
      } else sleeptimer++;
      wait(10);
    }
    
    void receive(const MyMessage &message) {
      if (message.isAck()) {
         Serial.println("This is an ack from gateway");
      }
    
      if (message.type == V_LIGHT) {
        if (!initialValueSent) {
          Serial.println("Receiving initial value from controller");
          initialValueSent = true;
        }
        // Change relay state
        state = message.getBool();
        digitalWrite(RELAY_PIN, state?RELAY_ON:RELAY_OFF);
        saveState(CHILD_ID_SWITCH, state);
        send(msgSwitch.set(state?RELAY_MSG_ON:RELAY_MSG_OFF));
      }
    }
    
    
    /****************** MQResistanceCalculation ****************************************
    Input:   raw_adc - raw value read from adc, which represents the voltage
    Output:  the calculated sensor resistance
    Remarks: The sensor and the load resistor forms a voltage divider. Given the voltage
             across the load resistor and its resistance, the resistance of the sensor
             could be derived.
    ************************************************************************************/
    float MQResistanceCalculation(int raw_adc)
    {
      return ( ((float)RL_VALUE*(1023-raw_adc)/raw_adc));
    }
    
    /***************************** MQCalibration ****************************************
    Input:   mq_pin - analog channel
    Output:  Ro of the sensor
    Remarks: This function assumes that the sensor is in clean air. It use
             MQResistanceCalculation to calculates the sensor resistance in clean air
             and then divides it with RO_CLEAN_AIR_FACTOR. RO_CLEAN_AIR_FACTOR is about
             10, which differs slightly between different sensors.
    ************************************************************************************/
    float MQCalibration(int mq_pin)
    {
      int i;
      float val=0;
    
      for (i=0; i<CALIBARAION_SAMPLE_TIMES; i++) {          //take multiple samples
        val += MQResistanceCalculation(analogRead(mq_pin));
        delay(CALIBRATION_SAMPLE_INTERVAL);
      }
      val = val/CALIBARAION_SAMPLE_TIMES;                   //calculate the average value
    
      val = val/RO_CLEAN_AIR_FACTOR;                        //divided by RO_CLEAN_AIR_FACTOR yields the Ro
      //according to the chart in the datasheet
    
      return val;
    }
    /*****************************  MQRead *********************************************
    Input:   mq_pin - analog channel
    Output:  Rs of the sensor
    Remarks: This function use MQResistanceCalculation to caculate the sensor resistenc (Rs).
             The Rs changes as the sensor is in the different consentration of the target
             gas. The sample times and the time interval between samples could be configured
             by changing the definition of the macros.
    ************************************************************************************/
    float MQRead(int mq_pin)
    {
      int i;
      float rs=0;
    
      for (i=0; i<READ_SAMPLE_TIMES; i++) {
        rs += MQResistanceCalculation(analogRead(mq_pin));
        delay(READ_SAMPLE_INTERVAL);
      }
    
      rs = rs/READ_SAMPLE_TIMES;
    
      return rs;
    }
    
    /*****************************  MQGetGasPercentage **********************************
    Input:   rs_ro_ratio - Rs divided by Ro
             gas_id      - target gas type
    Output:  ppm of the target gas
    Remarks: This function passes different curves to the MQGetPercentage function which
             calculates the ppm (parts per million) of the target gas.
    ************************************************************************************/
    int MQGetGasPercentage(float rs_ro_ratio, int gas_id)
    {
      if ( gas_id == GAS_LPG ) {
        return MQGetPercentage(rs_ro_ratio,LPGCurve);
      } else if ( gas_id == GAS_CO ) {
        return MQGetPercentage(rs_ro_ratio,COCurve);
      } else if ( gas_id == GAS_SMOKE ) {
        return MQGetPercentage(rs_ro_ratio,SmokeCurve);
      }
    
      return 0;
    }
    
    /*****************************  MQGetPercentage **********************************
    Input:   rs_ro_ratio - Rs divided by Ro
             pcurve      - pointer to the curve of the target gas
    Output:  ppm of the target gas
    Remarks: By using the slope and a point of the line. The x(logarithmic value of ppm)
             of the line could be derived if y(rs_ro_ratio) is provided. As it is a
             logarithmic coordinate, power of 10 is used to convert the result to non-logarithmic
             value.
    ************************************************************************************/
    int  MQGetPercentage(float rs_ro_ratio, float *pcurve)
    {
      return (pow(10,( ((log10(rs_ro_ratio)-pcurve[1])/pcurve[2]) + pcurve[0])));
    }
    

  • Mod

    Don't you have any other power supply to try? What is the output current of that power supply you are using?



  • My power supply shows 900mah written on the case... can't measure because when tried with a multimeter, it stops the arduino power supply...

    But to change the power I should decide first if it worth keep trying through VIN connection or change to USB, which will be easier because could use a phone adapter without any mod or soldering...

    Does it do seem to be a power supply problem?

    Thanks


  • Mod

    if you have already a USB power supply, just try that and see what happens. It is quite strange that it stops the arduino when measuring the voltage



  • thanks @gohan I solved the problem by changing the power supply...

    Now I'm powering through USB using a phone charger... so I'll never know if it was a soldering problem on VIN or a low current problem from the other disassembled phone charger... but it is working now...

    Thanks for the help...


  • Mod

    Arduino does not require a lot of current so it could have been an issue with wiring or the charger wasn't very stable


Log in to reply
 

Suggested Topics

  • 3
  • 3
  • 24
  • 10
  • 15
  • 2

25
Online

11.2k
Users

11.1k
Topics

112.5k
Posts