💬 MySensors NRF5 Platform

NeverDie

I use the board manager to manage the boards. I believe it connects directly into github.

Anyhow, I stripped out all the non-library stuff, and now Windows IDE works without complaining.

NeverDie

Has anyone here yet figured out how to have more than one type of interrupt at a time wake-up the MCU from sleep? Based on the examples so far, it seems as though only one type at a time can be active. I'm sure there must be some way to do it. For instance, it would be desirable if the MCU could wake up not just from a timer event every, say, 5 minutes, to take a temperature reading, but also immediately if there is a leak detected. Right now it's just one or the other.

rmtucker

@NeverDie

So we can not use the normal statement

int8_t sleep(int interrupt, int mode, unsigned long ms=0);

I did not realize that was the case as i have never tried it.

NeverDie

I believe hwSleep(..) is the preferred incantation, but beyond that I'm not sure of anything. Maybe @d00616 can comment?

I should be receiving a number of different PCB projects tomorrow for final assembly and test, and if I can't resolve this soon, I'm simply going to release them without full demo code.

scalz

@NeverDie said in 💬 MySensors NRF5 Platform:

I believe hwSleep(..) is the preferred incantation, but beyond that I'm not sure of anything.

In MySensors, the regular way to use sleep mode is by using the sleep() functions:
https://www.mysensors.org/download/sensor_api_20#sleeping

But like you said, you can also use the raw hwSleep() from the hw abstraction layer. Or you could also rewrite it!
Which means at each abstraction layer, there are additional logics. sleep() functions have more logics (regarding MySensors states and features) than the raw hwSleep for example (like testing if there is an ongoing ota, smartsleep, heartbeat etc..). I have nodes where i use raw or not, but it's good to know what's behind.

rmtucker

@scalz
So the statement
int8_t sleep(int interrupt, int mode, unsigned long ms=0);
Can be used for timer and pin interrupt at he same time on the NRF5 platform just like the arduino?

NeverDie

I'll try it, but I have strong doubts that it's going to work.

FWIW, here's the pin mapping currently being supplied by digitalPinToInterrupt(..) for the nRF5:
Digital pin 0 = interrupt pin 0
Digital pin 1 = interrupt pin 1
Digital pin 2 = interrupt pin 2
Digital pin 3 = interrupt pin 3
Digital pin 4 = interrupt pin 4
Digital pin 5 = interrupt pin 5
Digital pin 6 = interrupt pin 6
Digital pin 7 = interrupt pin 7
Digital pin 8 = interrupt pin 8
Digital pin 9 = interrupt pin 9
Digital pin 10 = interrupt pin 10
Digital pin 11 = interrupt pin 11
Digital pin 12 = interrupt pin 12
Digital pin 13 = interrupt pin 13
Digital pin 14 = interrupt pin 14
Digital pin 15 = interrupt pin 15
Digital pin 16 = interrupt pin 16
Digital pin 17 = interrupt pin 17
Digital pin 18 = interrupt pin 18
Digital pin 19 = interrupt pin 19
Digital pin 20 = interrupt pin 20
Digital pin 21 = interrupt pin 21
Digital pin 22 = interrupt pin 22
Digital pin 23 = interrupt pin 23
Digital pin 24 = interrupt pin 24
Digital pin 25 = interrupt pin 25
Digital pin 26 = interrupt pin 26
Digital pin 27 = interrupt pin 27
Digital pin 28 = interrupt pin 28
Digital pin 29 = interrupt pin 29
Digital pin 30 = interrupt pin 30

NeverDie

The last I heard, from @d00616 , we had to supply code such as:

    // Enable interrupt
  NVIC_SetPriority(RTC0_IRQn, 15);
  NVIC_ClearPendingIRQ(RTC0_IRQn);
  NVIC_EnableIRQ(RTC0_IRQn);

and

// This must be in one line
extern "C" { void RTC0_IRQHandler(void) {rtcInterruptCounter++; NRF5_RESET_EVENT(NRF_RTC0->EVENTS_OVRFLW); NRF_RTC0->EVENTS_OVRFLW=0; }}

to get interrupts to work. Even with that approach, though, I haven't gotten it to support any interrupts in addition to a timed sleeping, though I have gotten it to support one interrupt that's separate from a timed sleeping (basically, sleeps indefinitely until the interrupt happens).

NeverDie

OK, I just now tried:

  sleep(3,CHANGE,3000);

and, as I suspected, it does nothing but sleep for 3 seconds. It's not responsive to any changes on pin P03 on an nRF52.

@scalz Are you getting a different result? It seems like there's a strong disconnect somewhere between what you're recommending and what I am experiencing.

scalz

@NeverDie said in 💬 MySensors NRF5 Platform:

@scalz Are you getting a different result? It seems like there's a strong disconnect somewhere between what you're recommending and what I am experiencing.

I didn't give any recommandation, you misread. I just said the regular way to use sleep feature in mysensors, for users, is with sleep(..). But I agree, I misread you too! when you were asking for the specific nrf52 case I guess :)

That said, I got this working when I made my recessed node for door (accelerometer and hall effect sensor with sleeping). Maybe things have changed in the lib?? or not. I'm struggling between different version of the lib, and some are different from the dev branch.. I'll recheck this asap (not sure for this evening).

NeverDie

I tried toying around with it a bit, and I got a useful result:

#define MY_CORE_ONLY

#include <nrf.h>
#include <MySensors.h>


const byte ledPin = LED_BUILTIN;
const byte interruptPin = 3;
volatile byte state = LOW;

void blinkityBlink(uint8_t pulses, uint8_t repetitions) {
  for (int x=0;x<repetitions;x++) {
    for (int i=0;i<pulses;i++) {
      digitalWrite(LED_BUILTIN,HIGH);
      wait(20);
      digitalWrite(LED_BUILTIN,LOW);
      wait(100);
    }    
      wait(500);
  }
}

void setup() {
  hwPinMode(LED_BUILTIN,OUTPUT_D0H1);
  hwPinMode(interruptPin, INPUT);
  attachInterrupt(digitalPinToInterrupt(interruptPin), blink, RISING);
  blinkityBlink(2,1);  //signify power-on and start of main loop
}

volatile bool buttonPressed=false;
void loop() {
  state = !state;
  digitalWrite(ledPin, state);
  sleep(digitalPinToInterrupt(interruptPin), RISING, 3000);
  wait(20);  //wait 20 milliseconds for button to debounce if it was pressed
  if (digitalRead(interruptPin)) { //if button is pressed
    blinkityBlink(2,1);
  }
  if (buttonPressed) {
    buttonPressed=false;
    blinkityBlink(20,1);
  }
}

void blink() {
  buttonPressed=true;
}

So, with this approach, pushing the button on pin 3 does wake up the nRF52 from sleep, whereupon the button press can still be detected and serviced, but it also demonstrates that the ISR per se isn't working.

Anyhow, with this I'm able to get the PIR or leak sensor or magnet sensor or light sensor doing useful things in a timely manner, even if it isn't ideal. That puts me further ahead than I was before. :)

rmtucker

@NeverDie
This is a test program that wakes up from either that i was using some time ago.

/**
   The MySensors Arduino library handles the wireless radio link and protocol
   between your home built sensors/actuators and HA controller of choice.
   The sensors forms a self healing radio network with optional repeaters. Each
   repeater and gateway builds a routing tables in EEPROM which keeps track of the
   network topology allowing messages to be routed to nodes.

   Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
   Copyright (C) 2013-2015 Sensnology AB
   Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors

   Documentation: http://www.mysensors.org
   Support Forum: http://forum.mysensors.org

   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License
   version 2 as published by the Free Software Foundation.

 *******************************

   REVISION HISTORY
   Version 1.0 - Henrik EKblad

   DESCRIPTION
   This sketch provides an example how to implement a distance sensor using HC-SR04
   Use this sensor to measure KWH and Watt of your house meeter
   You need to set the correct pulsefactor of your meeter (blinks per KWH).
   The sensor starts by fetching current KWH value from gateway.
   Reports both KWH and Watt back to gateway.

   Unfortunately millis() won't increment when the Arduino is in
   sleepmode. So we cannot make this sensor sleep if we also want
   to calculate/report watt-number.
   http://www.mysensors.org/build/pulse_power
*/

// Enable debug prints
#define MY_DEBUG

// Enable and select radio type attached
//#define MY_RADIO_NRF24
#define MY_RADIO_NRF5_ESB
//#define MY_RADIO_RFM69
//#define MY_RADIO_RFM95

#include <MySensors.h>
#include <Wire.h> // must be included here so that Arduino library object file references work
#include <RtcDS3231.h>
RtcDS3231<TwoWire> Rtc(Wire);

#define DIGITAL_INPUT_SENSOR 2  // The digital input you attached your light sensor.  (Only 2 and 3 generates interrupt!)
#define PULSE_FACTOR 1000       // Nummber of blinks per KWH of your meeter
//#define SLEEP_MODE false        // Watt-value can only be reported when sleep mode is false.
#define MAX_WATT 10000          // Max watt value to report. This filetrs outliers.
#define CHILD_ID 1              // Id of the sensor child

unsigned long SEND_FREQUENCY = 20000; // Minimum time between send (in milliseconds). We don't wnat to spam the gateway.
double ppwh = ((double)PULSE_FACTOR) / 1000; // Pulses per watt hour
//bool pcReceived = false;
volatile unsigned long pulseCount = 0;
volatile unsigned long lastBlink = 0;
volatile unsigned long watt = 0;
volatile unsigned long kwh = 0;
unsigned long oldWatt = 0;
double oldKwh;
unsigned long lastSend;
MyMessage wattMsg(CHILD_ID, V_WATT);
MyMessage kwhMsg(CHILD_ID, V_KWH);


void setup()
{
  Serial.begin(115200);
  Rtc.Begin();
  Rtc.Enable32kHzPin(false);
  Rtc.SetSquareWavePinClockFrequency(DS3231SquareWaveClock_1Hz);
  Rtc.SetSquareWavePin(DS3231SquareWavePin_ModeClock);

  // Use the internal pullup to be able to hook up this sketch directly to an energy meter with S0 output
  // If no pullup is used, the reported usage will be too high because of the floating pin
  hwPinMode(DIGITAL_INPUT_SENSOR, INPUT_PULLUP);

  attachInterrupt(digitalPinToInterrupt(DIGITAL_INPUT_SENSOR), onPulse, FALLING);
  //pcReceived = true;
  lastSend = millis();
}

void presentation()
{
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo("Energy Meter", "1.0");

  // Register this device as power sensor
  present(CHILD_ID, S_POWER);
}

void loop()
{
  unsigned long now = millis();
  // Only send values at a maximum frequency or woken up from sleep
  bool sendTime = now - lastSend > SEND_FREQUENCY;
  if (sendTime) {
    // New watt value has been calculated
    if (watt != oldWatt) {
      // Check that we dont get unresonable large watt value.
      // could hapen when long wraps or false interrupt triggered
      if (watt < ((unsigned long)MAX_WATT)) {
        send(wattMsg.set(watt));  // Send watt value to gw
      }
      Serial.print("Watt:");
      Serial.println(watt);
      oldWatt = watt;
    }

    // Pulse count has changed
    //kwh = pulseCount;
    //double kwh = ((double)pulseCount / ((double)PULSE_FACTOR));
    send(kwhMsg.set(pulseCount));  // Send kwh value to gw
    Serial.print("Wh = ");
    Serial.println(pulseCount);
    pulseCount = 0;
    lastSend = now;
  }
  sleep(SEND_FREQUENCY);
}

void receive(const MyMessage &message)
{
}

void onPulse()
{
  unsigned long newBlink = micros();
  unsigned long interval = newBlink - lastBlink;
  if (interval < 50000L) { // Sometimes we get interrupt on RISING
    return;
  }
  watt = (3600000000.0 / interval) / ppwh;
  lastBlink = newBlink;
  pulseCount++;
}

NeverDie

Well, that's interesting. In the sketch I posted, I invoked sleep with:

  sleep(digitalPinToInterrupt(interruptPin), RISING, 3000);

which caused the mcu to wake up immediately after I press the button, but it didn't process the ISR.

Using an invocation like yours in the sketch you just posted above:

  sleep(3000);

the ISR executes and then terminates when I press the button, but the MCU doesn't wake and continue with the loop as it did with the prior incantation. Instead, it has to wait for the timer cycle to finish.

What I want is for it to wake up, do the ISR, and continue with the loop where it left off until it is explicitly put back to sleep again. How do I do that?

d00616

@NeverDie I have checked the sleep routine in all three variants. It's working with my setup.

There is no API stopping the sleep() by another ISR. Sleep only ends at one of the given conditions.

When you use the MY_CORE_ONLY define, please add "hwInit();" into the setup() routine.

NeverDie

@d00616 said in 💬 MySensors NRF5 Platform:

@NeverDie I have checked the sleep routine in all three variants. It's working with my setup.

There is no API stopping the sleep() by another ISR. Sleep only ends at one of the given conditions.

When you use the MY_CORE_ONLY define, please add "hwInit();" into the setup() routine.

Would you please post the three demo code examples that you tested?

NeverDie

@d00616 said in 💬 MySensors NRF5 Platform:

add "hwInit();" into the setup() routine.

OK, I just now did that, but I'm not getting any difference in the results.

NeverDie

In any case, I'm sure the question will ultimately turn from "How do I wake up based on a pin change?" to "How do I wake up based on the LPCOMP output, which has that pin as its input?" The reason: as covered earlier in this thread, much lower current consumption while sleeping if doing it via LPCOMP rather than the more straightforward pin monitoring.

d00616

@NeverDie said in 💬 MySensors NRF5 Platform:

In any case, I'm sure the question will ultimately turn from "How do I wake up based on a pin change?" to "How do I wake up based on the LPCOMP output, which has that pin as its input?" The reason: as covered earlier in this thread, much lower current consumption while sleeping if doing it via LPCOMP rather than the more straightforward pin monitoring.

It's a good question about, how to design the API to do this. I have no good idea.
Until an API, you can set MY_HW_RTC->CC[0] to (MY_HW_RTC->COUNTER+2). This ends sleep with some latency.

NeverDie

This post is deleted!

NeverDie

This post is deleted!

💬 MySensors NRF5 Platform

11

11.7k

11.2k

113.1k