[SOLVED] MYSBootloader FOTA Update hangs on ProMini-3V-8MHz (reboot problem)

rafael156

Can anyone help? Do i have to flash the Arduino with a USBasp?

gohan

Is sensebender gw running as usb/serial? Did you get some debug from the node?

rafael156

Thanks for the answer! I found the error yesterday:
I had OpenHab running in the background on the Linux system with the Sensebender Gateway (as USB). As a result, it appears that the gateway was "occupied" for a time. After I closed Openhab, I was able to perform a FOTA update without errors.

However, after I have uploaded the sketch "passive node", I cannot upload another sketch. After the first upload, the node executes its code normally and does not receive a new sketch anymore.

Does the sketch have to be programmed for fota updates? Maybe with a setting?

I have MYSController Version 1.0.0.3316

gohan

yes you need to enable the FOTA with its define.
For your problem with fota and openhab I think it is related to the gw being connected with USB so the 2 controllers are sharing the same serial port and I guess openhab doen't like to share much :D
If you could add an ethernet module to the GW and make it ethernet or mqtt you could connect more controllers more easily

rafael156

thanks for the info!
i thought you only needed it for DualOptiboot. I read it here:
https://www.mysensors.org/about/fota#enabling-fota-in-your-sketch-dualoptiboot-only

gohan

maybe I am wrong, I use the dual optiboot as it is much easier to use

rafael156

this has now worked:

in the sketch you don't have to activate the fota update in the mysbootloader
the last MYSBootloader 1.3.0-rc.1 works

the next problem is:
if the node has no sketch, the node boots constantly into the bootloader and can load every sketch per fota update.
as soon as the node has a sketch and is rebooted by the myscontroller, the node is only restarted by software/watchdog and apparently does not jump into the bootloader. thus it cannot load a new sketch.
Only if I reboot the node manually, the fota update works.

The only problem is the soft-reset, which does not work as expected.

Is there a way to reboot the Atmega328p like I do with the manual button?
Why does the watchdog/ soft-reset not work?

rafael156

here's what I've been trying on arduino 328P-8MHz XTAL-3v3:
fuse settings from development branch(only to external xtal changed):

MYSBL.menu.frequency.MYSBL8=ATmega328 8Mhz ext MYSBootloader_1.3.0-rc.1
MYSBL.menu.frequency.MYSBL8.build.f_cpu=8000000L
MYSBL.menu.frequency.MYSBL8.upload.speed=57600
MYSBL.menu.frequency.MYSBL8.bootloader.low_fuses=0xFF
MYSBL.menu.frequency.MYSBL8.bootloader.high_fuses=0xD2
MYSBL.menu.frequency.MYSBL8.bootloader.extended_fuses=0x06
MYSBL.menu.frequency.MYSBL8.bootloader.unlock_bits=0x3F
MYSBL.menu.frequency.MYSBL8.bootloader.lock_bits=0x0F
MYSBL.menu.frequency.MYSBL8.bootloader.file=MySensors/MYSBootloader_8MHz.hex

then i burned the bootloader from https://github.com/mysensors/MySensorsBootloaderRF24/blob/development/hex/MYSBootloader_8MHz.hex
and got warnings from arduino IDE:

avrdude: WARNING: invalid value for unused bits in fuse "lock", should be set to 1 according to datasheet
This behaviour is deprecated and will result in an error in future version
You probably want to use 0xff instead of 0x3f (double check with your datasheet first).
avrdude: WARNING: invalid value for unused bits in fuse "efuse", should be set to 1 according to datasheet
This behaviour is deprecated and will result in an error in future version
You probably want to use 0xfe instead of 0x06 (double check with your datasheet first).
avrdude: WARNING: invalid value for unused bits in fuse "lock", should be set to 1 according to datasheet
This behaviour is deprecated and will result in an error in future version
You probably want to use 0xcf instead of 0x0f (double check with your datasheet first).

Then the first firmware after flashing the bootloader:

https://ibb.co/gbQ7Sd

serial communication works, but with baud 115200. shouldn't this be 57600 at 8MHz?
https://ibb.co/cxpqfy

a manual restart of the node does nothing...
https://ibb.co/e7bp7d

after i hard-reset, the node is restarting...
https://ibb.co/jTxMnd

warum funktioniert der software reboot nicht? und warum hat der node eine baud rate von 115200 statt 57600 nach aktuellem dev.branch?

tekka

@rafael156 Please post your sketch - looks like your sketch does not process incoming messages.

rafael156

this is the current dht-sketch from mysensors-examples:

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * REVISION HISTORY
 * Version 1.0: Henrik EKblad
 * Version 1.1 - 2016-07-20: Converted to MySensors v2.0 and added various improvements - Torben Woltjen (mozzbozz)
 * 
 * DESCRIPTION
 * This sketch provides an example of how to implement a humidity/temperature
 * sensor using a DHT11/DHT-22.
 *  
 * For more information, please visit:
 * http://www.mysensors.org/build/humidity
 * 
 */

// Enable debug prints
#define MY_DEBUG

// Enable and select radio type attached 
#define MY_RADIO_NRF24
//#define MY_RADIO_RFM69
//#define MY_RS485
 
#include <SPI.h>
#include <MySensors.h>  
#include <DHT.h>

// Set this to the pin you connected the DHT's data pin to
#define DHT_DATA_PIN 3

// Set this offset if the sensor has a permanent small offset to the real temperatures
#define SENSOR_TEMP_OFFSET 0

// Sleep time between sensor updates (in milliseconds)
// Must be >1000ms for DHT22 and >2000ms for DHT11
static const uint64_t UPDATE_INTERVAL = 60000;

// Force sending an update of the temperature after n sensor reads, so a controller showing the
// timestamp of the last update doesn't show something like 3 hours in the unlikely case, that
// the value didn't change since;
// i.e. the sensor would force sending an update every UPDATE_INTERVAL*FORCE_UPDATE_N_READS [ms]
static const uint8_t FORCE_UPDATE_N_READS = 10;

#define CHILD_ID_HUM 0
#define CHILD_ID_TEMP 1

float lastTemp;
float lastHum;
uint8_t nNoUpdatesTemp;
uint8_t nNoUpdatesHum;
bool metric = true;

MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
DHT dht;


void presentation()  
{ 
  // Send the sketch version information to the gateway
  sendSketchInfo("TemperatureAndHumidity", "1.1");
  
  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP);
  
  metric = getControllerConfig().isMetric;
}


void setup()
{
  dht.setup(DHT_DATA_PIN); // set data pin of DHT sensor
  if (UPDATE_INTERVAL <= dht.getMinimumSamplingPeriod()) {
    Serial.println("Warning: UPDATE_INTERVAL is smaller than supported by the sensor!");
  }
  // Sleep for the time of the minimum sampling period to give the sensor time to power up
  // (otherwise, timeout errors might occure for the first reading)
  sleep(dht.getMinimumSamplingPeriod());
}


void loop()      
{  
  // Force reading sensor, so it works also after sleep()
  dht.readSensor(true);
  
  // Get temperature from DHT library
  float temperature = dht.getTemperature();
  if (isnan(temperature)) {
    Serial.println("Failed reading temperature from DHT!");
  } else if (temperature != lastTemp || nNoUpdatesTemp == FORCE_UPDATE_N_READS) {
    // Only send temperature if it changed since the last measurement or if we didn't send an update for n times
    lastTemp = temperature;
    if (!metric) {
      temperature = dht.toFahrenheit(temperature);
    }
    // Reset no updates counter
    nNoUpdatesTemp = 0;
    temperature += SENSOR_TEMP_OFFSET;
    send(msgTemp.set(temperature, 1));

    #ifdef MY_DEBUG
    Serial.print("T: ");
    Serial.println(temperature);
    #endif
  } else {
    // Increase no update counter if the temperature stayed the same
    nNoUpdatesTemp++;
  }

  // Get humidity from DHT library
  float humidity = dht.getHumidity();
  if (isnan(humidity)) {
    Serial.println("Failed reading humidity from DHT");
  } else if (humidity != lastHum || nNoUpdatesHum == FORCE_UPDATE_N_READS) {
    // Only send humidity if it changed since the last measurement or if we didn't send an update for n times
    lastHum = humidity;
    // Reset no updates counter
    nNoUpdatesHum = 0;
    send(msgHum.set(humidity, 1));
    
    #ifdef MY_DEBUG
    Serial.print("H: ");
    Serial.println(humidity);
    #endif
  } else {
    // Increase no update counter if the humidity stayed the same
    nNoUpdatesHum++;
  }

  // Sleep for a while to save energy
  sleep(UPDATE_INTERVAL); 
}

rafael156

@tekka Do you have an idea what´s wrong with the code? yesterday i have changed "sleep(UPDATE_INTERVAL);" to "wait(UPDATE_INTERVAL); " but bothing changed. Fota update or software reboot doesnt work.

Are the fuses and the bootloader options (txt) correct?

gohan

don't you need to reboot to trigger the update?

rafael156

Yeah, right! That's the problem! But when I click on "reboot" on myscontroller, the node does not react to any command, i.e. reboot etc.
is there a function that takes the command from myscontroller and executes it or do I have to implement it myself in the sketch?

Soloam

@rafael156 I had a similar problem, my node would stop responding when I tried to reboot it. The problem was in the fuse settings, have you checked if they are all set? What version are you using? (16,8 or 1)

gohan

@rafael156 have you tried with smartsleep instead of sleep? Of course the node would respond only when it wakes up.

rafael156

@Soloam i have checked fuse settings several times . i use the 8 mhz version. boards.txt see above .
at burn process, arduino ide (1.6.13) gave me a warning about the fuses
which fuses do you have?

@gohan no, i didnt. but i have tried wait(), with no success. i will try smartsleep() today!

tekka

@rafael156 Hmm, I don't think this is related to the fuse settings. Try again changing sleep() to wait() and upload the full logs from MYSController and the node (with MY_DEBUG enabled)

rafael156

ok, Thanks at all!
You helped me find the mistake!
it was actually because the node could not receive commands because there was a "sleep()" hidden somewhere in each sketch. after I searched all sketches thoroughly and replaced them with "wait()", everything runs without problems:

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * REVISION HISTORY
 * Version 1.0: Henrik EKblad
 * Version 1.1 - 2016-07-20: Converted to MySensors v2.0 and added various improvements - Torben Woltjen (mozzbozz)
 * 
 * DESCRIPTION
 * This sketch provides an example of how to implement a humidity/temperature
 * sensor using a DHT11/DHT-22.
 *  
 * For more information, please visit:
 * http://www.mysensors.org/build/humidity
 * 
 */

// Enable debug prints
#define MY_DEBUG

// Enable and select radio type attached 
#define MY_RADIO_NRF24
//#define MY_RADIO_RFM69
//#define MY_RS485
 
#include <SPI.h>
#include <MySensors.h>  
#include <DHT.h>

// Set this to the pin you connected the DHT's data pin to
#define DHT_DATA_PIN 3

// Set this offset if the sensor has a permanent small offset to the real temperatures
#define SENSOR_TEMP_OFFSET 0

// Sleep time between sensor updates (in milliseconds)
// Must be >1000ms for DHT22 and >2000ms for DHT11
static const uint64_t UPDATE_INTERVAL = 60000;

// Force sending an update of the temperature after n sensor reads, so a controller showing the
// timestamp of the last update doesn't show something like 3 hours in the unlikely case, that
// the value didn't change since;
// i.e. the sensor would force sending an update every UPDATE_INTERVAL*FORCE_UPDATE_N_READS [ms]
static const uint8_t FORCE_UPDATE_N_READS = 10;

#define CHILD_ID_HUM 0
#define CHILD_ID_TEMP 1

float lastTemp;
float lastHum;
uint8_t nNoUpdatesTemp;
uint8_t nNoUpdatesHum;
bool metric = true;

MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
DHT dht;


void presentation()  
{ 
  // Send the sketch version information to the gateway
  sendSketchInfo("TemperatureAndHumidity", "1.1");
  
  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP);
  
  metric = getControllerConfig().isMetric;
}


void setup()
{
  dht.setup(DHT_DATA_PIN); // set data pin of DHT sensor
  if (UPDATE_INTERVAL <= dht.getMinimumSamplingPeriod()) {
    Serial.println("Warning: UPDATE_INTERVAL is smaller than supported by the sensor!");
  }
  // Sleep for the time of the minimum sampling period to give the sensor time to power up
  // (otherwise, timeout errors might occure for the first reading)
  wait(dht.getMinimumSamplingPeriod());
}


void loop()      
{  
  
  // Force reading sensor, so it works also after sleep()
  dht.readSensor(true);
  
  // Get temperature from DHT library
  float temperature = dht.getTemperature();
  if (isnan(temperature)) {
    Serial.println("Failed reading temperature from DHT!");
  } else if (temperature != lastTemp || nNoUpdatesTemp == FORCE_UPDATE_N_READS) {
    // Only send temperature if it changed since the last measurement or if we didn't send an update for n times
    lastTemp = temperature;
    if (!metric) {
      temperature = dht.toFahrenheit(temperature);
    }
    // Reset no updates counter
    nNoUpdatesTemp = 0;
    temperature += SENSOR_TEMP_OFFSET;
    send(msgTemp.set(temperature, 1));

    #ifdef MY_DEBUG
    Serial.print("T: ");
    Serial.println(temperature);
    #endif
  } else {
    // Increase no update counter if the temperature stayed the same
    nNoUpdatesTemp++;
  }

  // Get humidity from DHT library
  float humidity = dht.getHumidity();
  if (isnan(humidity)) {
    Serial.println("Failed reading humidity from DHT");
  } else if (humidity != lastHum || nNoUpdatesHum == FORCE_UPDATE_N_READS) {
    // Only send humidity if it changed since the last measurement or if we didn't send an update for n times
    lastHum = humidity;
    // Reset no updates counter
    nNoUpdatesHum = 0;
    send(msgHum.set(humidity, 1));
    
    #ifdef MY_DEBUG
    Serial.print("H: ");
    Serial.println(humidity);
    #endif
  } else {
    // Increase no update counter if the humidity stayed the same
    nNoUpdatesHum++;
  }

  // Sleep for a while to save energy
  //sleep(UPDATE_INTERVAL); 
  wait(UPDATE_INTERVAL);
}

void receive(){
}

However, I would suggest that the functions "wait()" and "smartsleep()" be mentioned in relation to the MySBootloader in a separate point under "https://www.mysensors.org/about/fota". Maybe under a chapter:

Enabling FOTA in your sketch
1.1 DualOptiboot only
--> text as before
1.2 MySBootloader
--> ... use smartsleep() and wait() instead of sleep()...

Summary:

fuse settings 8MHz external crystal:

MYSBL.menu.frequency.MYSBL8=ATmega328 8Mhz ext MYSBootloader_1.3.0-rc.1
MYSBL.menu.frequency.MYSBL8.build.f_cpu=8000000L
MYSBL.menu.frequency.MYSBL8.upload.speed=57600
MYSBL.menu.frequency.MYSBL8.bootloader.low_fuses=0xFF
MYSBL.menu.frequency.MYSBL8.bootloader.high_fuses=0xD2
MYSBL.menu.frequency.MYSBL8.bootloader.extended_fuses=0x06
MYSBL.menu.frequency.MYSBL8.bootloader.unlock_bits=0x3F
MYSBL.menu.frequency.MYSBL8.bootloader.lock_bits=0x0F
MYSBL.menu.frequency.MYSBL8.bootloader.file=MySensors/MYSBootloader_8MHz.hex

if sensebender gateway is connected via usb, only one instance may access the gateway at a time, therefore "OpenHab" must be terminated first
do not use "sleep()" in the sketches. only "smartsleep()" or "wait()".
use the current dev-branch from "https://github.com/mysensors/MySensorsBootloaderRF24

gohan

@rafael156 said in [SOLVED] MYSBootloader FOTA Update hangs on ProMini-3V-8MHz (reboot problem):

// Sleep for a while to save energy
//sleep(UPDATE_INTERVAL);
wait(UPDATE_INTERVAL);

I'd use smartsleep in this case as wait will keep the MCU active and drain battery. Wait is better used in place of "delay"

badmannen

@rafael156 oh crap ... I put in that lowFuse as FF .. ( I read you had it for 8 MHz INTERNAL .. but nooo you wrote external ... ooops ... is there any way to force write it back without connecting an 8 MHz oscillator to the chip .. I only got 16 MHz oscillators .. or am I screwed for that chip until I go and get one?

[SOLVED] MYSBootloader FOTA Update hangs on ProMini-3V-8MHz (reboot problem)

14

11.7k

11.2k

113.1k