💬 Power Meter Pulse Sensor



  • @flopp
    lm393



  • @asgardro said:

    @flopp
    lm393

    Have you trimmed the pot so the LED turns on when your power meter flash?



  • @flopp
    i have done that and calibrated the lm393 , i have a blinking light that triggers the sensor. thats how i am testing...but after initializing sends the value first time and thats it
    sorry to reply so late but have to wait 120seconds between posts lol



  • /**
     * The MySensors Arduino library handles the wireless radio link and protocol
     * between your home built sensors/actuators and HA controller of choice.
     * The sensors forms a self healing radio network with optional repeaters. Each
     * repeater and gateway builds a routing tables in EEPROM which keeps track of the
     * network topology allowing messages to be routed to nodes.
     *
     * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
     * Copyright (C) 2013-2015 Sensnology AB
     * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
     *
     * Documentation: http://www.mysensors.org
     * Support Forum: http://forum.mysensors.org
     *
     * This program is free software; you can redistribute it and/or
     * modify it under the terms of the GNU General Public License
     * version 2 as published by the Free Software Foundation.
     *
     *******************************
     *
     * REVISION HISTORY
     * Version 1.0 - Henrik EKblad
     * 
     * DESCRIPTION
     * This sketch provides an example how to implement a distance sensor using HC-SR04 
     * Use this sensor to measure KWH and Watt of your house meeter
     * You need to set the correct pulsefactor of your meeter (blinks per KWH).
     * The sensor starts by fetching current KWH value from gateway.
     * Reports both KWH and Watt back to gateway.
     *
     * Unfortunately millis() won't increment when the Arduino is in 
     * sleepmode. So we cannot make this sensor sleep if we also want 
     * to calculate/report watt-number.
     * http://www.mysensors.org/build/pulse_power
     */
    
    // Enable debug prints
    #define MY_DEBUG
    
    // Enable and select radio type attached
    #define MY_RADIO_NRF24
    //#define MY_RF24_CHANNEL 74
    //#define MY_RADIO_RFM69
    
    #include <MySensors.h>  
    
    #define DIGITAL_INPUT_SENSOR 3  // The digital input you attached your light sensor.  (Only 2 and 3 generates interrupt!)
    #define PULSE_FACTOR 1000       // Nummber of blinks per KWH of your meeter
    #define SLEEP_MODE false        // Watt-value can only be reported when sleep mode is false.
    #define MAX_WATT 10000          // Max watt value to report. This filetrs outliers.
    #define CHILD_ID 1              // Id of the sensor child
    
    unsigned long SEND_FREQUENCY = 5000; // Minimum time between send (in milliseconds). We don't wnat to spam the gateway.
    double ppwh = ((double)PULSE_FACTOR)/1000; // Pulses per watt hour
    bool pcReceived = false;
    volatile unsigned long pulseCount = 0;   
    volatile unsigned long lastBlink = 0;
    volatile unsigned long watt = 0;
    unsigned long oldPulseCount = 0;   
    unsigned long oldWatt = 0;
    double oldKwh;
    unsigned long lastSend;
    MyMessage wattMsg(CHILD_ID,V_WATT);
    MyMessage kwhMsg(CHILD_ID,V_KWH);
    MyMessage pcMsg(CHILD_ID,V_VAR1);
    
    
    void setup()  
    {  
      // Fetch last known pulse count value from gw
      request(CHILD_ID, V_VAR1);
    
      // Use the internal pullup to be able to hook up this sketch directly to an energy meter with S0 output
      // If no pullup is used, the reported usage will be too high because of the floating pin
      pinMode(DIGITAL_INPUT_SENSOR,INPUT_PULLUP);
    
      attachInterrupt(digitalPinToInterrupt(DIGITAL_INPUT_SENSOR), onPulse, RISING);
      lastSend=millis();
      Serial.println("7");
    }
    
    void presentation() {
      // Send the sketch version information to the gateway and Controller
      sendSketchInfo("Energy Meter", "1.0");
    
      // Register this device as power sensor
      present(CHILD_ID, S_POWER);
      Serial.println("7");
    }
    //Serial.println("6");
    void loop()     
    { 
      unsigned long now = millis();
      // Only send values at a maximum frequency or woken up from sleep
      bool sendTime = now - lastSend > SEND_FREQUENCY;
      if (pcReceived && (SLEEP_MODE || sendTime)) {
        // New watt value has been calculated  
        if (!SLEEP_MODE && watt != oldWatt) {
          // Check that we dont get unresonable large watt value. 
          // could hapen when long wraps or false interrupt triggered
          if (watt<((unsigned long)MAX_WATT)) {
            send(wattMsg.set(watt));  // Send watt value to gw 
          }  
          Serial.print("Watt:");
          Serial.println(watt);
          oldWatt = watt;
        }
    Serial.println("5");
        // Pulse cout has changed
        if (pulseCount != oldPulseCount) {
          send(pcMsg.set(pulseCount));  // Send pulse count value to gw 
          double kwh = ((double)pulseCount/((double)PULSE_FACTOR));     
          oldPulseCount = pulseCount;
          if (kwh != oldKwh) {
            send(kwhMsg.set(kwh, 4));  // Send kwh value to gw 
            oldKwh = kwh;
          }
          Serial.println("4");
        }    
        lastSend = now;
      } else if (sendTime && !pcReceived) {
        // No count received. Try requesting it again
        request(CHILD_ID, V_VAR1);
        lastSend=now;
      }
    Serial.println("3");
      if (SLEEP_MODE) {
        sleep(SEND_FREQUENCY);
      }
      Serial.println("2");
    }
    
    void receive(const MyMessage &message) {
    if (message.type==V_VAR1) {
    Serial.println("rece");
    pulseCount = oldPulseCount = message.getLong();
    Serial.print("Received last pulse count from gw:");
    Serial.println(pulseCount);
    pcReceived = true;
    }
    Serial.println("not_rece");
    }
    
    void onPulse()     
    { 
      if (!SLEEP_MODE) {
        unsigned long newBlink = micros();  
        unsigned long interval = newBlink-lastBlink;
        if (interval<10000L) { // Sometimes we get interrupt on RISING
          return;
        }
        watt = (3600000000.0 /interval) / ppwh;
        lastBlink = newBlink;
        
      } 
     
      pulseCount++;
      Serial.println("1");
      
    }
    
    

    this



  • As the sketch starts by requesting the latest pulse count (e.g starting kWh value) and does not send anything without having received it, how do I "seed" this value to my GW? I am using a MQTT GW, can I construct a MQTT special message containing the value, or how is it supposed to work?



  • @maghac
    I am using Domoticz ans MyS 1.5.1
    You don't have to create VAR1, it will be created when you ask for it or it always exists for each Child.
    If you want VAR1 to be exactly the same as your meter you need to open domoticz.db and set the value or in your sketch.


  • Hardware Contributor

    Anyone knows why I dont get the sleep() function (time) to work properly.

    My hardware is EasyPCB, Pro Mini 3.3v 8mhz, Booster 2xAA and NRF24 radio.
    My software is: standard sketch 2.0.1, with sleep function.

    The problem is the sleep time is 5 times less than declared so maybe timing?
    When i enter sleep(10000) for example the nodes sleeps for 2 sec and wakes up.

    The interupt works fine.

    My sollution was adding *5 to get the correct sleep time - but why doesnt it work?



  • @flopp I had to set pcReceived to true, upload the sketch, run it and then change back to false again and recompile/reupload. I can understand why it does it, since you don't want the pulse counter to reset to 0 if the sensor happens to restart (because you killed the power or whatever).

    What I don't understand is how I can seed the value with the correct initial value.

    Is it the controller (in my case HomeAssistant) or the gateway that is supplying the value?



  • It appears to be the controller that stores the value. I deleted the sensor from HomeAssistant and restarted, when it came back in again it started from zero.


  • Plugin Developer

    @maghac

    This is a hack, but if using json persistence, you can set the count in the JSON file and restart home assistant, with the node turned off. Then turn on the node.



  • @martinhjelmare Yep, I figured I could do that. The absolute value is not so important actually, I'm more interested in the daily/weekly delta, which I hope Grafana can tell me.


  • Mod

    is this the same sensor than the one in the guide?
    http://uk.farnell.com/ams/tsl250r-lf/photodiode-sensor-l-volts/dp/1182346

    Can I also use also photoresistor? (Since I already have one)


  • Hardware Contributor

    @gohan - nope its not the same, and yes you can use a photoresistor (i have just made one) but I needed a transistor for it to work and also it had to be completley dark. Using this on batteries its much better using just a photoresistor because the sensor in the guide draws about 1mA which will drain the batteris very quickly.

    I will post my sensor later.

    Edit: this is the sensor i build:

    0_1486915502085_1.jpg
    0_1486915592318_20170212_135834.jpg

    The node (including pro mini) draws about 50uA sleeping and 170uA not sleeping.
    The photoresistor was 5M ohm in complete dark.


  • Mod

    The guide specifies LM393 Light Sensor or the tsl250r-lf so I thought it was the same since the same name.
    Since the node will be powered with it's power supply, I don't have any battery drain problem in this case. But why did you use a transistor? Can't you just check for a threshold value in the analog input to count as a pulse?


  • Hardware Contributor

    Ok, all I can see is that it doesnt look the same at all.
    @gohan - I tried, and I thought that should work - but for some reason I could not get it to trigger the interupt on the atmega 😞
    Looking the the voltage thresholds it was supposed to work but it didnt. I was thinking it was to low uA but i dont know really.




  • Mod

    @sundberg84

    Instead of the 10k resistor, do you think I could use a potentiometer to "adjust" sensitivity? I would like to avoid messing up the readings with lights entering when opening the cabinet door where the meter is located

    @flopp
    Do you mind sharing your wiring? 940nm, isn't it infrared?


  • Hardware Contributor

    @gohan - a potentiometer is just a variable resistor so why not? Good idea if you have one laying around.
    As i said before though, the try with the transistor is just a try - im not that good with transistors yet and dont know how they work exactly. After this i read somewhere that the base resistor should be bigger to protect the transistor... dont know how to calculate that.



  • @gohan said in 💬 Power Meter Pulse Sensor:

    @sundberg84

    @flopp
    Do you mind sharing your wiring? 940nm, isn't it infrared?

    I connected the photo resistor directly to the LM393.
    I don't know if that is IR.



  • Hello,

    First, thanks for this tutorial !
    I used the code defined in tutorial but I have the following message for "void receive(const MyMessage &message)" :

    'MyMessage' does not name a type
    

    Do you know what can be the cause of this error please ?

    Thanks in advance for your help


  • Mod

    @moumout31 do you have void receive(const MyMessage &message) somewhere in your code or where does it come from?
    Could you post the full error message?

    Have you installed the MySensors library?



  • @mfalkvidd void receive(const MyMessage &message) is in the code.
    MySensors library is installed, I already use it in other nodes.
    It's strange because it works in another computer...

    The full error messages, in french beacause I'm french are :

    Arduino : 1.8.0 (Windows 7), Carte : "Arduino Pro or Pro Mini, ATmega328 (3.3V, 8 MHz)"
    
    _02_Main_loop:271: error: 'MyMessage' does not name a type
    
    In file included from C:\Users\Anne-Laure\Documents\Arduino\libraries\arduino_759467/MySensors.h:257:0,
    
                     from C:\Users\Anne-Laure\Dropbox\Maison\A récupérer sur OneDrive\my_teleinfo_light\_02_Main_loop.ino:118:
    
    C:\Users\Anne-Laure\Documents\Arduino\libraries\arduino_759467/core/MyTransport.cpp: In function 'void transportProcessMessage()':
    
    C:\Users\Anne-Laure\Documents\Arduino\libraries\arduino_759467/core/MyTransport.cpp:745:14: error: cannot resolve overloaded function 'receive' based on conversion to type 'bool'
    
       if (receive) {
    
                  ^
    
    C:\Users\Anne-Laure\Documents\Arduino\libraries\arduino_759467/core/MyTransport.cpp:811:15: error: cannot resolve overloaded function 'receive' based on conversion to type 'bool'
    
        if (receive) {
    
                   ^
    
    exit status 1
    'MyMessage' does not name a type
    
    Bibliothèque non valide trouvée dans C:\Users\Anne-Laure\Documents\Arduino\libraries\MySensors : C:\Users\Anne-Laure\Documents\Arduino\libraries\MySensors
    
    Ce rapport pourrait être plus détaillé avec
    l'option "Afficher les résultats détaillés de la compilation"
    activée dans Fichier -> Préférences.
    

    Thanks for your help


  • Mod

    @moumout31 My guess is that MyMessage is defined in your sketch, overriding the definition in the MySensors library. Could you post your sketch?



  • @mfalkvidd It's strange... It works with an older version of Arduino software... Thus, the problem is solved ! Thanks



  • Hello,

    I don't understand why, but my power meter sensor gives a higher index than the real power meter index after 2 days.
    I think that it counts more pulses than pulses provided by the power meter...
    Does anybody encounter this problem ?
    Can it be cause to bounce for example ?

    Thank you


  • Mod

    @moumout31
    could it be getting some light from another source?



  • @moumout31
    I had same issue, check here for my solution
    https://forum.mysensors.org/topic/4716/two-energy-meter/4



  • Hei.

    How to connect arduino to electricity meter pulse out. Not to led.



  • @gohan No, the light is always switched off in this room and I tried, when I switch on the light, there is no pulse from the sensor.

    @flopp Thanks for your help. What I see in your topic is that you increase from 10000µs to 40000µs the interval to avoid corrupted interrupts, is that correct ?

    Thank you



  • @moumout31
    Yes correct.
    When I checked with Serial Monitor and some serial.print in different places I could see that arduino registered double interrupts



  • @flopp Thanks a lot, I will try this solution and check if it's better !



  • @flopp It seems to work, index on Domoticz is still consistent with the real index... I will see in a few days if it's still the case.
    Thanks a lot for your help !



  • @flopp After a few days, I confirm you that the index is consistent with power meter index.
    However, instant power in watt is not correcly calculated.
    For example, when power meter indicates 550W, about 1500W is calculated by the sketch. Do you know how I can resolve this problem please ?

    Thanks a lot !



  • @moumout31
    Watt calculation is using time between two interrupts.
    How often do you send watt?
    Did you measure watt with a measurement tool How did you get 500 watts from power meter?
    When you send watt you need to measure exact same second otherwise it will not be correct.



  • @flopp Watt is sent every 20 seconds (as done in the original sketch).
    500 watts is the power indicated on the screen of the power meter.



  • Just changed from 1-wire counter to MySensors for logging my power consumption. Using the same LED detector as I did when using 1-wire. Also changed watt limit to 20 000 (my heat pump likes to use 9-10kW sometimes). The wires from the old 1-wire net now provide power for the new MySensors-sensor. I have 10 000 led blinks per kWh. Had som crazy counter values with 1-wire that totally messed up the graphs and haven't seen anything like that with this sketch. Let's hope it stays that way. 😉 Dumping data to Domoticz. This sensor gives me higher resolution as a bonus. The 1-wire counter was read every minute, this every 20-sec. 😉

    0_1490286464866_Domoticz_-_Google_Chrome_2017-03-23_17-27-32_78641890.png

    0_1490286540285_Domoticz_-_Google_Chrome_2017-03-23_17-28-46_94994234.png

    My old 1-wire counter with one crazy value messing upp all the graphs:
    0_1490286637201_Domoticz_-_Google_Chrome_2017-03-23_17-30-09_29365468.png
    I know that you can hold shift and click the value that is crazy to make the graphs show up good but you loose the data for the full day. That's not good. 😉


  • Hardware Contributor

    I seem to be getting a connection to my gateway, while monitoring the two topics for the gateway i only seem to see any activity regarding this sensor on the gateway-out topic, and it keeps sending out a type 2 message (req). The serial monitor of the sensors is showing:

    104198 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    114199 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    124200 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    134201 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    144202 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    154203 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    164204 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    174205 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    184206 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:
    194207 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:

    So it seems to be sending a request package, but i don't see it on the gateway-in topic and i see other sensors sending data to the gateway-in topic so i'm not subscribed to the wrong one. Is this a structural request message or is this the feature that requests the last known message from the gateway? Either way, there doesn't seem to be any sensor data being sent from the node to the gateway.


  • Hardware Contributor

    @Samuel235 said in 💬 Power Meter Pulse Sensor:

    164204 TSF:MSG:SEND,16-16-0-0,s=1,c=2,t=24,pt=0,l=0,sg=0,ft=0,st=OK:

    I dont know if I dont understand you, but it seems like your node is requesting the last pulse counter. I have mentioned this in several threads I have a problem with this (both this thread and rain sensor thread). Im using an ethernet gw and the request reaches the gw but there my error led blinks and it fails to send it back (or recieve it on the node) so it re-request it.

    I have never been able to pinpoint it due to repeaters in between.
    https://forum.mysensors.org/topic/2116/hard-to-grab-time-and-value-sent-from-controller/ (old).


  • Hardware Contributor

    @sundberg84 - You do understand me correctly :). I made a thread on the troubleshooting section of the forum for this simply because i suspected it was normal behaviour, however. It seems that the node isn't sending any other data to the gateway at all and it can not get the previous value as there isn't one. So, my post here and on the troubleshooting section was me aiming to get to this point and then troubleshoot the actual node to see what can be done to get it to send data.


  • Hardware Contributor

    Has anyone came across their pulse meter not sending the message for WATT, the other two messages are being sent perfectly fine. My WATT message has been working all day and suddenly stopped.



  • Make sure that you don't reach your wattage limit in the sketch.


  • Hardware Contributor

    @NiklasO - Where is this value stored? I've cleared the EEPROM and the MQTT topic too, but it still refuses to send the watt value.



  • @Samuel235
    In the sketch, change this
    #define MAX_WATT 10000 // Max watt value to report. This filetrs outliers.
    I have it set to 20000, using 15 000 easily when it's cold outside. 😉 Just make sure that you use the right divider for your pulse/kWh count.


  • Hardware Contributor

    Ahh i see what it is it; its set to not send if it hasn't changed.... how much of a silly error that was from me. The wattage is way below 1000 but because i'm using a normal LED on another arduino flashing at a constant rate to set my node up, its not changing the watt value.

    Back to solving my initial issue now >.<

    Thank you.



  • Ah, I see. Well, I would like the sensor to send data even if it hasn't changed. What did you change?


  • Mod

    Watt usage is normally changing all the time, so you should have data reported quite often



  • @gohan But Samuel235 had that problem? 😉 Edit: well, ok, he had a different setup. I need to read better. 😉


  • Hardware Contributor

    To be honest, i had it running for a while before it stopped sending the WATTS. But i'm guessing this is the issue as if i vary the blinks it sends it. I'de like to see if anyone has this working recently on OpenHAB through means of not touching the node sketch like people have posted before. I have an idea to send the data of the pulse count message onto the request message topic on MQTT and so then when it requests previous count it would have it.


  • Hardware Contributor

    This post is deleted!


  • EDIT:
    This was not the case, I am still debugging the issue, in the mean time I have deleted the code.

    After some debugging it seems that Domoticz messes with the V_WATT and V_KWH, and the solution is to have two sensors, one for kWh and one for W.
    After I changed it, I have consistent W and kWh.
    See also this issue for Home Assistant



  • OK, I think I have nailed it. I am now running a beta code pulling S0 from my energy meter and I am getting consistent results.
    Before when I checked the domoticz.db I got this for Energy:

    sqlite> select Name, sValue from DeviceStatus;
    Storage kWh|0.000;4773.700
    

    Now I get this:

    sqlite> select Name, sValue from DeviceStatus;
    Storage kWh|118.000;11678062.000
    

    Notice that the first field is now with value, previously it was 0.000 (and I have updated the meter count to the actual value)
    And in table Meter I now get consistent results:

    sqlite> SELECT Value, Usage, Date FROM Meter WHERE DeviceRowID=43;
    11678003|1170|2017-07-22 09:25:00
    11678012|1170|2017-07-22 09:30:00
    11678021|1180|2017-07-22 09:35:00
    11678031|1180|2017-07-22 09:40:00
    11678043|1170|2017-07-22 09:45:00
    11678053|1180|2017-07-22 09:50:00
    11678062|1180|2017-07-22 09:55:00
    11678072|1180|2017-07-22 10:00:00
    

    The field Usage is now populated as it should.
    I will let the code run for a couple of days, then I will post the updated code here.



  • Here is a code example that works for me. I have an energy meter with S0 output and I use Domoticz as the controller.

    /**
     * The MySensors Arduino library handles the wireless radio link and protocol
     * between your home built sensors/actuators and HA controller of choice.
     * The sensors forms a self healing radio network with optional repeaters. Each
     * repeater and gateway builds a routing tables in EEPROM which keeps track of the
     * network topology allowing messages to be routed to nodes.
     *
     * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
     * Copyright (C) 2013-2015 Sensnology AB
     * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
     *
     * Documentation: http://www.mysensors.org
     * Support Forum: http://forum.mysensors.org
     *
     * This program is free software; you can redistribute it and/or
     * modify it under the terms of the GNU General Public License
     * version 2 as published by the Free Software Foundation.
     *
     *******************************
     *
     * REVISION HISTORY
     * Version 1.0 - Henrik EKblad
     * Version 1.1 - Mikael Carlsson
     *
     * DESCRIPTION
     * This sketch provides an example how to implement a sensor reading from an energy meter
     * Use this sensor to measure KWH and Watt of your house meeter
     * You need to set the correct pulsefactor of your meeter (blinks per KWH).
     * The sensor starts by fetching current KWH value from gateway.
     * Reports both KWH and Watt back to gateway.
     *
     * Unfortunately millis() won't increment when the Arduino is in
     * sleepmode. So we cannot make this sensor sleep if we also want
     * to calculate/report watt-number.
     * http://www.mysensors.org/build/pulse_power
     */
    
    // Enable debug prints
    #define MY_DEBUG
    
    // Enable and select radio type attached
    #define MY_RADIO_NRF24
    //#define MY_RADIO_RFM69
    
    #include <MySensors.h>
    
    #define DIGITAL_INPUT_SENSOR 3  // The digital input you attached your light sensor.  (Only 2 and 3 generates interrupt!)
    #define PULSE_FACTOR 1000       // Nummber of blinks per KWH of your meter
    #define SLEEP_MODE false        // Watt-value can only be reported when sleep mode is false.
    #define MAX_WATT 10000          // Max watt value to report. This filters bad data.
    #define CHILD_ID 1              // Id of the sensor child
    
    unsigned long SEND_FREQUENCY =
        20000; // Minimum time between send (in milliseconds). We don't want to spam the gateway.
    double ppwh = ((double)PULSE_FACTOR)/1000; // Pulses per watt hour
    bool pcReceived = false;
    volatile unsigned long pulseCount = 0;
    volatile unsigned long lastBlink = 0;
    volatile unsigned long watt = 0;
    unsigned long oldPulseCount = 0;
    unsigned long oldWatt = 0;
    double oldKwh;
    unsigned long lastSend;
    MyMessage wattMsg(CHILD_ID,V_WATT);
    MyMessage kwhMsg(CHILD_ID,V_KWH);
    MyMessage pcMsg(CHILD_ID,V_VAR1);
    
    
    void setup()
    {
        // Fetch last known pulse count value from gw
        request(CHILD_ID, V_VAR1);
    
        // Use the internal pullup to be able to hook up this sketch directly to an energy meter with S0 output
        // If no pullup is used, the reported usage will be too high because of the floating pin
        pinMode(DIGITAL_INPUT_SENSOR,INPUT_PULLUP);
    
        attachInterrupt(digitalPinToInterrupt(DIGITAL_INPUT_SENSOR), onPulse, RISING);
        lastSend=millis();
    }
    
    void presentation()
    {
        // Send the sketch version information to the gateway and Controller
        sendSketchInfo("Energy Meter", "1.0");
    
        // Register this device as power sensor
        present(CHILD_ID, S_POWER);
    }
    
    void loop()
    {
        unsigned long now = millis();
        // Only send values at a maximum frequency or woken up from sleep
        bool sendTime = now - lastSend > SEND_FREQUENCY;
        if (pcReceived && (SLEEP_MODE || sendTime)) {
            // New watt value has been calculated
            if (!SLEEP_MODE && watt != oldWatt) {
                // Check that we dont get unresonable large watt value.
                // could happen when long wraps or false interrupt triggered
                // We need to send in all values at one time to get consistent data
                if (watt<((unsigned long)MAX_WATT)) {
                    send(wattMsg.set(watt));  // Send watt value to gw
                    Serial.print("Watt: ");
                    Serial.println(watt);
                    oldWatt = watt;
                    send(pcMsg.set(pulseCount));  // Send pulse count value to gw
                    Serial.print("pulseCount: ");
                    Serial.println(watt);
                    double kwh = ((double)pulseCount/((double)PULSE_FACTOR));
                    oldPulseCount = pulseCount;
                    send(kwhMsg.set(kwh, 4));  // Send kwh value to gw
                    Serial.print("kWh: ");
                    Serial.println(kwh);
                    oldKwh = kwh;
                }
            }
            lastSend = now;
        } else if (sendTime && !pcReceived) {
            // No count received. Try requesting it again
            request(CHILD_ID, V_VAR1);
            lastSend=now;
        }
    
        if (SLEEP_MODE) {
            sleep(SEND_FREQUENCY);
        }
    }
    
    void receive(const MyMessage &message)
    {
        if (message.type==V_VAR1) {
            pulseCount = oldPulseCount = message.getLong();
            Serial.print("Received last pulse count from gw:");
            Serial.println(pulseCount);
            pcReceived = true;
        }
    }
    
    void onPulse()
    {
        if (!SLEEP_MODE) {
            unsigned long newBlink = micros();
            unsigned long interval = newBlink-lastBlink;
            if (interval<10000L) { // Sometimes we get interrupt on RISING
                return;
            }
            watt = (3600000000.0 /interval) / ppwh;
            lastBlink = newBlink;
        }
        pulseCount++;
    }```


  • One (probably stupid) question about the batter powered option: Since sensor cannot keep track of real time power usage as it sleeps most of the time, would it be possible to do the math on the controller side and get "5min delay real time power usage"?
    By dividing number of pulses since last transmission, is that basically what this sensor is doing when not being powered by batteries?

    I could experiment with 2min delay f.eks, and see how batteries hold. If dht22 temp sensors works over a year with 5min transmission time, i hope 2min delay in pulse meter can hold 6mnt or something?
    Another thing is that the electrical box is all metal, and there is a lot of electricity around the sensor so radio could struggle (I guess a repeater would definitively help)


  • Mod

    Is it only me that is getting a compile error?

    Error: call of overloaded 'set(volatile long unsigned int&)' is ambiguous
    send(wattMsg.set(watt)); \ Send watt value to gw

    error: call of overloaded 'set(volatile long unsigned int&)' is ambiguous
    send(pcMsg.set(pulseCount)); \ Send pulse count value to gw

    followed by all the possible candidates of .set arguments


  • Mod

    @gohan I get the same, both for 2.1.1 and 2.2.0-beta. Strange. I thought there were Jenkins tests that endured the examples compiled.


  • Mod

    Replacing all

    unsigned long
    

    with

    uint32_t
    

    makes the sketch compile fine, but I don't know if that is the correct solution.


  • Mod


  • Admin

    The problem with "unsigned long" is that it can have different size based on platform it's compiled on.

    Like @mfalkvidd says, use int32_t, uint32_t, int16_t and uint16_t which has a fixed width.


  • Mod

    I was suspecting something like that, but I was not sure if changing variable type would affect something else


  • Mod

    Ok, I got it working. On wemos it doesn't count pulses though. On domoticz does it have to configured as the value computed or from device? I'm asking because if you disconnect the sensor, on domoticz I keep seeing the same power reading


  • Mod

    BTW, is there a way to have the pulse meter running on gateway? I got stuck because at startup it asks the controller the last count value and since the controller is not yet connected it just doesn't work.



  • @gohan for the first time use only the watt value....that time oldcounts will not bother.....


  • Mod

    What do you mean? And how do I keep the count of the pulses if I don't get it from controller?


  • Mod

    @hek is it me or the WATT readings are never sent? What could it be? Only V_VAR1 and V_KWH are sent.



  • @gohan How about

    #define MY_TRANSPORT_WAIT_READY_MS 2000
    

    This will start up your code so you won't miss any pulses until controller is ready.
    You may ask for the last known Value in presentation(), then it will be fetched as soon as the controller is really there after startup. This could/should be combined with a bool pcReceived, so you may decide to either add the value received from controller to the counts the node meassured in between or just use the received value (starting from second time value is received from controller).


  • Mod

    That actually is not that critical, as I am going to move to MQTT and that should be working anyway. Right now it is working on a UNO with NRF24, but my biggest issue is the WATT reading that it is missing


  • Mod

    Any more suggestions on the Watt issue?


  • Admin

    Did you by any chance change SLEEP_MODE to true?


  • Mod

    No, I get every pulse reported as soon as it is detected.


  • Mod

    I think I found a problem: the WATT calculation is returning values over 172000 watts and since I put 10000 as the max value, it was not sending anything. I double checked my energy meter and indeed it is 1000 pulses per KWH and this is what I set in sketch


  • Mod

    @hek I said I found the problem, I didn't say I know how to solve it 😅


  • Mod

    Here is the log I get from node

    7230 TSF:MSG:READ,0-0-250,s=1,c=2,t=24,pt=0,l=7,sg=0:1682675
    rece
    
    Received last pulse count from gw:1682675
    
    11817 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=17,pt=5,l=4,sg=0,ft=0,st=OK:528
    Watt:528
    
    Watt:197065
    
    21820 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:1682677
    21913 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:1682.6770
    Watt:196807
    
    36824 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:1682679
    36917 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:1682.6790
    Watt:197368
    
    51827 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:1682681
    51920 TSF:MSG:SEND,250-250-0-0,s=1,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:1682.6810
    Watt:196850
    

    Am I the only one using this sketch?



  • Please post you sketch.


  • Mod



  • How is the pulse counter set up? Is it connected to the S0 port?
    Edit:
    If you are using S0 it is vital that you use a pull down resistor, if you dont’t have that you get false pulses.
    pulse connection


  • Mod

    I'm using the lm393 light detector. Domoticz is able to do a calculation from the pulses to give a Watt value and it is correct but it does it every 5 minutes and it is too slow for me


  • Hardware Contributor

    @gohan - is Domoticz updating anything (except switches) faster than 5 min? I dont think so...


  • Mod

    If you send the watt reading faster it updates like the switch, anyway I need the watt values for node-red also


  • Mod

    Could it be the Light sensor is triggering more interrupts from each pulse?



  • @niklaso

    Hi Niklas,

    I know this is a very old post, but its worth a try. How did you get out the daily Kwh usage? As default my sensor only gives Watts and Kwh (accumulated from start), I have tried to run a Scene in Vera UI7 where there are a function in the sensor called resetKWh(), but it looks like it doesn't do anything. Any tips would be great, thanks.

    Henning



  • @gohan I think it is a little tricky to update domoticz every minute but try update the sql-file, see the domoticz forum
    https://www.domoticz.com/forum/viewtopic.php?t=10183


  • Mod

    The main issue is the fact that the sensor is not calculating the instant power correctly



  • I created this kWh sensor with the TCRT5000 IR Barrier Line Track Sensor.
    My powermeter is a ferarrismeter with 375 rotations per kWh.
    I also had the problem with spikes in the power usage. But after long...too long investigation I solved the problem.
    At my config it was a double issue.

    Issue 1.
    The problem is the pulse width of the rotation.
    The pulse are at night ( low power) much wider that during the day when more power is consumed. At night the spikes in power usage where huge.

    Issue 2.
    Switching on/off the halogen light causes spikes and related to also strange power measurement.

    Solution:
    I added a second arduino mini pro as a pulse regulator between the TCRT5000 and the power meter arduino.
    this arduino triggers on Rising and will always give a 100ms puls. Als debounce is handled (spikes).
    I don't upload the sketch here, I'm a beginning programmer on arduino. It's made on " trail and error" but it functions as it supposed to do.
    If someone wants a copy feel free to contact mee



  • @gohan Did you solve this?
    I get very high watt usage as well. Sometimes like 40 000 - 130 000 watt if I check the serial monitor.
    Of course, those values will never be sent to the controler.


  • Mod

    Nope, I am looking at other things now. Very little time available for too many things. I'm looking at buying CT clamp and do a more direct measurement.



  • Okay. Really annoying. Check this.

    Received last pulse count from gw:2527
    Watt:121065
    22235 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2539
    22246 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.5390
    Watt:121621
    42238 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2551
    42250 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.5510
    Watt:121342
    62239 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2563
    62251 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.5630
    Watt:121539
    82240 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2575
    82251 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.5750
    Watt:121951
    102239 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2589
    102250 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.5890
    Watt:122067
    122243 TSF:MSG:SEND,78-78-0-0,s=3,c=1,t=24,pt=5,l=4,sg=0,ft=0,st=OK:2601
    122254 TSF:MSG:SEND,78-78-0-0,s=2,c=1,t=18,pt=7,l=5,sg=0,ft=0,st=OK:2.6010
    

    The plus count seems OK, right?

    My energy meter is 1000 pluses /kwh

    Here is my sketch. I use Home assistant so i created three sensors for this as I don't think V_VAR1 is supported with S_POWER.
    Otherwise it is the standard example.

    /**
     * The MySensors Arduino library handles the wireless radio link and protocol
     * between your home built sensors/actuators and HA controller of choice.
     * The sensors forms a self healing radio network with optional repeaters. Each
     * repeater and gateway builds a routing tables in EEPROM which keeps track of the
     * network topology allowing messages to be routed to nodes.
     *
     * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
     * Copyright (C) 2013-2015 Sensnology AB
     * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
     *
     * Documentation: http://www.mysensors.org
     * Support Forum: http://forum.mysensors.org
     *
     * This program is free software; you can redistribute it and/or
     * modify it under the terms of the GNU General Public License
     * version 2 as published by the Free Software Foundation.
     *
     *******************************
     *
     * REVISION HISTORY
     * Version 1.0 - Henrik EKblad
     *
     * DESCRIPTION
     * This sketch provides an example how to implement a distance sensor using HC-SR04
     * Use this sensor to measure KWH and Watt of your house meeter
     * You need to set the correct pulsefactor of your meeter (blinks per KWH).
     * The sensor starts by fetching current KWH value from gateway.
     * Reports both KWH and Watt back to gateway.
     *
     * Unfortunately millis() won't increment when the Arduino is in
     * sleepmode. So we cannot make this sensor sleep if we also want
     * to calculate/report watt-number.
     * http://www.mysensors.org/build/pulse_power
     */
    
    // Enable debug prints
    #define MY_DEBUG
    
    // Enable and select radio type attached
    #define MY_RADIO_NRF24
    //#define MY_RADIO_RFM69
    #define MY_NODE_ID 78
    #include <MySensors.h>
    
    #define DIGITAL_INPUT_SENSOR 3  // The digital input you attached your light sensor.  (Only 2 and 3 generates interrupt!)
    #define PULSE_FACTOR 1000       // Nummber of blinks per KWH of your meeter
    #define SLEEP_MODE false        // Watt-value can only be reported when sleep mode is false.
    #define MAX_WATT 20000          // Max watt value to report. This filetrs outliers.
    #define WATT_CHILD_ID 1              // Id of the sensor child
    #define KWH_CHILD_ID 2
    #define PC_CHILD_ID 3
    
    unsigned long SEND_FREQUENCY =
        20000; // Minimum time between send (in milliseconds). We don't wnat to spam the gateway.
    double ppwh = ((double)PULSE_FACTOR)/1000; // Pulses per watt hour
    bool pcReceived = false;
    volatile unsigned long pulseCount = 0;
    volatile unsigned long lastBlink = 0;
    volatile unsigned long watt = 0;
    unsigned long oldPulseCount = 0;
    unsigned long oldWatt = 0;
    double oldKwh;
    unsigned long lastSend;
    MyMessage wattMsg(WATT_CHILD_ID,V_WATT);
    MyMessage kwhMsg(KWH_CHILD_ID,V_KWH);
    MyMessage pcMsg(PC_CHILD_ID,V_VAR1);
    
    
    void setup()
    {
      // Fetch last known pulse count value from gw
      request(PC_CHILD_ID, V_VAR1);
    
      // Use the internal pullup to be able to hook up this sketch directly to an energy meter with S0 output
      // If no pullup is used, the reported usage will be too high because of the floating pin
      pinMode(DIGITAL_INPUT_SENSOR,INPUT_PULLUP);
    
      attachInterrupt(digitalPinToInterrupt(DIGITAL_INPUT_SENSOR), onPulse, RISING);
      lastSend=millis();
    }
    
    void presentation()
    {
      // Send the sketch version information to the gateway and Controller
      sendSketchInfo("Energy Meter", "1.0");
    
      // Register this device as power sensor
      present(WATT_CHILD_ID, S_POWER);
      present(KWH_CHILD_ID, S_POWER);
      present(PC_CHILD_ID, S_CUSTOM);
    }
    
    void loop()
    {
      unsigned long now = millis();
      // Only send values at a maximum frequency or woken up from sleep
      bool sendTime = now - lastSend > SEND_FREQUENCY;
      if (pcReceived && (SLEEP_MODE || sendTime)) {
        // New watt value has been calculated
        if (!SLEEP_MODE && watt != oldWatt) {
          // Check that we dont get unresonable large watt value.
          // could hapen when long wraps or false interrupt triggered
          if (watt<((unsigned long)MAX_WATT)) {
            send(wattMsg.set(watt));  // Send watt value to gw
          }
          Serial.print("Watt:");
          Serial.println(watt);
          oldWatt = watt;
        }
    
        // Pulse cout has changed
        if (pulseCount != oldPulseCount) {
          send(pcMsg.set(pulseCount));  // Send pulse count value to gw
          double kwh = ((double)pulseCount/((double)PULSE_FACTOR));
          oldPulseCount = pulseCount;
          if (kwh != oldKwh) {
            send(kwhMsg.set(kwh, 4));  // Send kwh value to gw
            oldKwh = kwh;
          }
        }
        lastSend = now;
      } else if (sendTime && !pcReceived) {
        // No count received. Try requesting it again
        request(PC_CHILD_ID, V_VAR1);
        lastSend=now;
      }
    
      if (SLEEP_MODE) {
        sleep(SEND_FREQUENCY);
      }
    }
    
    void receive(const MyMessage &message)
    {
      if (message.type==V_VAR1) {
        pulseCount = oldPulseCount = message.getLong();
        Serial.print("Received last pulse count from gw:");
        Serial.println(pulseCount);
        pcReceived = true;
      }
    }
    
    void onPulse()
    {
      if (!SLEEP_MODE) {
        unsigned long newBlink = micros();
        unsigned long interval = newBlink-lastBlink;
        if (interval<10000L) { // Sometimes we get interrupt on RISING
          return;
        }
        watt = (3600000000.0 /interval) / ppwh;
        lastBlink = newBlink;
      }
      pulseCount++;
    }
    
    

    Anyone got any ideas?
    BTW. First i tried the original example sketch, unmodified, with the same result.


  • Mod

    That's pretty much the same problem as I have



  • I think i solved this.
    I don't know if it is a good solution.
    Maybe it is possible to solve in the code?
    I added a 0,1uf ceramic capacitor between DO and GND on the LM393.
    Then i tuned the LM393 until i had it blink as expected.

    I think, in my case the LED pulse from my meeter was to short, it gives a very short blink.
    Anyway.
    I tested it all day and it seems fine now.


  • Mod

    Are you getting instant power measurements correct?



  • Yes. I guess.
    I don't have anything to compare with but i think it is accurate.
    I have a 1000blink/kwh
    Example:
    Node send state every 20 sec.
    pulsecount: 8 pulses every 20 sec.
    Instant power in W is about 1400W

    8 pulses x 3 = pulses /minute =24
    24 pulses x 60 min = pulses /hour = 1440.

    Edit.
    Now I get a new value every 20 sec, before I didn't get any value (W) from the node at all because it was too high. I only received pulse count and kWh earlier.


  • Mod

    Besides the cap, what exactly did you do?



  • Nothing more.
    I use the same arduino, haven't uploaded anything new to it since i tried it last time.

    What I had to do was lower the sensitivity on the LM393 because at first the signal-LED glowed a bit but when i adjusted it to lower sensitivity and closed the door to get it totaly dark the led blinked exactly as the meeter.

    I have it on a bredboard and connected the cap between GND and to pin 3 so it is connected close to the arduino but i guess it shouldn't matter.

    Have you tried it?


  • Mod

    I can't believe it, IT WORKS!!!!! I added the cap directly under the pins of the LM939 board. Thanks man!



  • I am glad to hear it works for you too.


  • Mod

    There is probably a sw way to correct this problem, I'll think about it



  • It waswhat I thought too.
    As I said earlier, when I tested this my conclusion was, short blink, almost a flash will counted as a pulse (kWh) but it does something wrong with the calculation of instant power usage.
    A slower blink will correct this.
    My meeter gives a very short blink.


  • Mod

    Yes, could be that a simple debounce could do the trick but I'll have to look deeper into it. @Yveaux what do you think?


  • Mod

    @xydix Could you try to increase the 10000L to 100000L interval in the OnPulse function and see if it works without the capacitor?


  • Contest Winner

    I tried to build something similar and it is working nicely, thanks for sharing the idea! However, I've noticed the light sensor (alone) consumes 1mA constantly which is quite a lot when used for a battery powered project. Even if I report to the controller once per hour (summing up the power consumption along the way), still the light sensor needs to be always on, meaning I'd probably need to replace batteries after a month or so. Is there any workaround or alternative sensor which I can use or am I doing something completely wrong? Thanks



  • @user2684 I had the same issue when I built this with a standalone atmega328p running on 2x AA's. I set it up with wake on interrupt from the It was constantly drawing 1.6mA to power the tsl257 to detect the flashes. My target was 1+ years on 2 x AA's. My solution to achieve this was to sleep for 125ms, wake up, send power to tsl257 to check light state (on/off), if it changed from previous reading then there was a pulse (well half pulse). By measuring every 125ms I can guarantee to capture fast pulses up to 14.4kW. (3600000/125)/2. It is 20kW max draw for residential in my country. Now:
    Average mA Consumption Sleep 0.1
    Average mA Consumption Wake 0.064516129
    Average mA Consumption Transmit 0.002916667
    Battery Life (2xAAs) = 1.7 years


Log in to reply
 

Suggested Topics

  • 3
  • 5
  • 2
  • 347
  • 109
  • 163

20
Online

11.2k
Users

11.1k
Topics

112.5k
Posts