RFM69 new driver delay

mickecarlsson

I just checked all my nodes:

Garage - measures temperature/humidity and power usage - uses NEW_DRIVER, Arduino UNO, powered all times.
Storage - measures temperature/humidity and power usage - uses NEW_DRIVER, Arduino UNO powered all times.
Greenhouse - measures temperature/humidity - uses "old" driver, Arduino Pro Mini, battery powered.
Patio - measures temperature/humidity - uses "old" driver, Arduino Pro Mini, battery powered.
Bedroom - measures temperature/humidity - uses "old" driver, Arduino Pro Mini, battery powered.
Kitchen area - measures temperature/humidity - uses "old" driver, Arduino Pro Mini, battery powered.

My nodes are within 40 meters from the gateway.
I will no reprogram the node 4 and 5 to use the new driver to see if that makes any difference.
Node 1 and 2 are the nodes farthest away from the gateway, there is one brick wall and three wood walls between the node and the gateway.

pepson

@mickecarlsson
Please also for all points give info what version MySensors use and if you can upload your sketches for all point.

And Gateway has on RPI3 with version 2.3.0 ? By Serial or ethernet ? And tell me with what controller you use it ? I use with Home Assistant.

And BTW tell me how long Arduino Mini Pro work for you on battery and what battery you use ... and show your project... Did you remove LED from Arduino to save power battery ?
In Sketch you measure % power from battery ? And send to controller ? What controller you use ?

scalz

@pepson @mickecarlsson
in theory, if I remember well, length of antenna should be:

86mm for 868mhz
82mm for 915Mhz
Better check which frequency you can use where you live.

Also this is in ideal world, it depends on:

antenna material
gnd plane size
etc

So when you want to tune your network, you could use a good, 868mhz for example, antenna on gateway (from a reliable supplier, as there are also a lot of unmatched antenna around).
Then you can try to tune emprically, by checking rssi vs length. Add length or cut, and check. If you need more or less length is dependant on above factors.

As already said, we don't recommand mixing new driver with older.. As packet has not the same format.
No eta for fixing rfm69 if issues, too busy for the moment, but we'll try asap.

pepson

@scalz said in RFM69 new driver delay:

So when you want to tune your network, you could use a good, 868mhz for example, antenna on gateway (from a reliable supplier, as there are also a lot of unmatched antenna around).
Then you can try to tune emprically, by checking rssi vs length. Add length or cut, and check. If you need more or less length is dependant on above factors.
As already said, we don't recommand mixing new driver with older.. As packet has not the same format.
No eta for fixing rfm69 if issues, too busy for the moment, but we'll try asap.

Yes i have for my radio anntena 86mm.
On nodes and gateway i am sure that i use freq 868MHz.
Look on my command to build gateway and on my sketches node.
On version 2.2.0 i use gateway (as people write by my command i use NEW DRIVER) and also on node also use NEW DRIVER and in this solution all works perfect with no problem.

When i update gateway and node to 2.3.0 also with NEW DRIVER i have a problem that controll node and connection is no stabilish. In my Home Assistant sometimes i can controll relay but sometimes no reaction on click by Home Assistant. When use on node old driver (but on gateway NEW DRIVER) it is no working. Only on version 2.2.0 on gatewy and node all works perfect.

Is any chance to build gateway on RPI3 with old driver to RFM69HW ? Because as people write in default building on gateway on RPI3 use NEW DRIVER and we can not change it.... It is true ?

scalz

@pepson
My comments about tuning antenna were general, it can be useful for optimizing your network.

I already read what you said previously ;) It should be normal that new&old driver not working together (unless a recent change..).

We'll take a look at which changes are incorrect. I'm using experimental local mysensors version, so I'm a bit off topic regarding official release and no time for debugging, for the moment, as like I said we'll try to check that asap.

Regarding RPI, I'm not using it as gw (I prefer a lower power gw that i can place where i want) so I'm not sure. Take it with a pinch of salt but if i remember, old rfm69 driver spi functions etc are not adapted to linux (whereas new driver is)

If 2.3 is blocking, do you need a particular fix in 2.3 ? Else you could stick to 2.2

mickecarlsson

OK,
Here goes what I have:
Arduino Pro Mini, chinese clones. Regulator and led removed. Soldered on EasyPCB rev 9.
Radio is RFM69 868 MHz with helicoil antenna on the nodes, 86 mm antenna on the Gateway
Bootloader is from https://github.com/MCUdude/MiniCore
The bootloader settings are:
Board: ATmega328
Bootloader: Yes
Variant: 328P / 328PA
BOD: 1.8v
Clock: 1MHz internal
Compiler LTO: Disabled (default)

On the EasyPCB I have only soldered the radio, the antenna and the Arduino. No booster, no capacitors, no resistors.
I have put a link on the REG and run the node on two AA batteries.
The nodes only have one sensor, the BME280.

The controller I use is Domoticz, latest version (I think).

I have now reprogrammed some of the nodes to 2.30 and I use NEW_DRIVER.
Gateway - 2.3.0
Patio - 2.3.0
Test-node - 2.3.0
Kitchen - 2.3.0
Bedroom - 2.3.0
UV and LUX - 2.3.0

No problems at all.
However, I do not use the receive() function on my nodes.
And I see that you use the REPEATER setting, if your node can reach the gateway the disable repeater.

pepson

@mickecarlsson

Tell me for what you change bootloader ? And i also have clone chine arduino pro mini... I also must change bootloader on this Arduino Pro Mini CLONE CHINA ? Because i dont change bootloader after buy...

And if you can show also your antenna...and where you buy this antenna ? I try found on Aliexpres but not found.

And I see that you use the REPEATER setting, if your node can reach the gateway the disable repeater.
But i can not use REPEATER function to to increase the range from the gate - something like the MESH network ?

And is any chance to you test my SKETCH with relay on your arduino ?

mickecarlsson

You don't ned to change bootloader, I do because I run on battery and it fits my need.
I can't test your sketch as I don't have the necessary hardware to test it.
How far apart are your nodes?
My antenna is from AliExpress

pepson

@mickecarlsson
Now my node is very near my Gateway about 6meters. Because now i project my automation in my new home.

But if you only have Arduino Pro Mini with Radio RFM69HW you can test my sketch. I think that you dont need 2xrelay to test it... Please...

But for what is function REPEATER ? To increase range from Gateway to very far node ? Then the node with the repeater function extends the range?

When come back to home i try build node without option REPEATER and try run this...

Also can you give on priv info how upload this bootloader ? I can only write by ArduinoIDE or i must do other actions ?

mickecarlsson

You only need repeater fi you have a node far away that can’t reach the gateway, then you add repeater on a node nearer the gateway.
See here: MySensors Network
And if the node has repeater defined it must allways have power and no Sleep.
Sorry, I can’t test the sketch.

pepson

@mickecarlsson
Can you share me your all sketches ? Thanks
And tell me how you have connected Gateway to RPI3? By ethernet or by serial ? Because i see in your building Gateway that you dont use parameter ETHERNET on port 5003

And anybody has any contact to developer @tekka007 ?

This is info what show in debug on version 2.3.0 gateway and also node on version 2.3.0

pi@hassbian:~/MySensors $ sudo /usr/local/bin/mysgw
Jun 22 17:22:49 INFO  Starting gateway...
Jun 22 17:22:49 INFO  Protocol version - 2.3.0
Jun 22 17:22:49 DEBUG MCO:BGN:INIT GW,CP=RPNGL---,VER=2.3.0
Jun 22 17:22:49 DEBUG TSF:LRT:OK
Jun 22 17:22:49 DEBUG TSM:INIT
Jun 22 17:22:49 DEBUG TSF:WUR:MS=0
Jun 22 17:22:49 DEBUG TSM:INIT:TSP OK
Jun 22 17:22:49 DEBUG TSM:INIT:GW MODE
Jun 22 17:22:49 DEBUG TSM:READY:ID=0,PAR=0,DIS=0
Jun 22 17:22:49 DEBUG MCO:REG:NOT NEEDED
Jun 22 17:22:49 DEBUG Listening for connections on 0.0.0.0:5003
Jun 22 17:22:49 DEBUG MCO:BGN:STP
Jun 22 17:22:49 DEBUG MCO:BGN:INIT OK,TSP=1
Jun 22 17:22:54 DEBUG TSF:MSG:READ,2-2-255,s=255,c=3,t=7,pt=0,l=0,sg=0:
Jun 22 17:22:54 DEBUG TSF:MSG:BC
Jun 22 17:22:54 DEBUG TSF:MSG:FPAR REQ,ID=2
Jun 22 17:22:54 DEBUG TSF:CKU:OK,FCTRL
Jun 22 17:22:54 DEBUG TSF:MSG:GWL OK
Jun 22 17:22:54 DEBUG TSF:MSG:SEND,0-0-2-2,s=255,c=3,t=8,pt=1,l=1,sg=0,ft=0,st=O                 K:0
Jun 22 17:22:56 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=24,pt=1,l=1,sg=0:1
Jun 22 17:22:56 DEBUG TSF:MSG:PINGED,ID=2,HP=1
Jun 22 17:22:57 DEBUG TSF:MSG:SEND,0-0-2-2,s=255,c=3,t=25,pt=1,l=1,sg=0,ft=0,st=                 OK:1
Jun 22 17:22:57 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=15,pt=6,l=2,sg=0:0100
Jun 22 17:22:58 DEBUG TSF:MSG:SEND,0-0-2-2,s=255,c=3,t=15,pt=6,l=2,sg=0,ft=0,st=                 OK:0100
Jun 22 17:22:59 DEBUG TSF:MSG:READ,2-2-0,s=255,c=0,t=17,pt=0,l=5,sg=0:2.3.0
Jun 22 17:22:59 DEBUG TSF:MSG:READ,2-2-0,s=255,c=0,t=17,pt=0,l=5,sg=0:2.3.0
Jun 22 17:23:00 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=6,pt=1,l=1,sg=0:0
Jun 22 17:23:00 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=6,pt=1,l=1,sg=0:0
Jun 22 17:23:03 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=11,pt=0,l=25,sg=0:1xRelay &                  Button-Sypialni
Jun 22 17:23:03 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=11,pt=0,l=25,sg=0:1xRelay &                  Button-Sypialni
Jun 22 17:23:03 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=12,pt=0,l=5,sg=0:2.2.0
Jun 22 17:23:04 DEBUG TSF:MSG:READ,2-2-0,s=1,c=0,t=3,pt=0,l=0,sg=0:
Jun 22 17:23:05 DEBUG TSF:MSG:READ,2-2-0,s=1,c=0,t=3,pt=0,l=0,sg=0:
Jun 22 17:23:05 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=26,pt=1,l=1,sg=0:2
Jun 22 17:23:06 DEBUG TSF:MSG:SEND,0-0-2-2,s=255,c=3,t=27,pt=1,l=1,sg=0,ft=0,st=OK:1
Jun 22 17:23:07 DEBUG TSF:MSG:READ,2-2-0,s=1,c=1,t=2,pt=2,l=2,sg=0:0
Jun 22 17:23:08 DEBUG TSF:MSG:READ,2-2-0,s=1,c=1,t=2,pt=2,l=2,sg=0:0
Jun 22 17:23:08 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=1,pt=0,l=0,sg=0:
Jun 22 17:23:09 DEBUG TSF:MSG:READ,2-2-0,s=255,c=3,t=1,pt=0,l=0,sg=0:

pepson

@mickecarlsson I done next test.
Updated my Gateway on RPI3 to 2.3.0
Then also update my nodes to 2.3.0
One node which i use is to control Switch Relay. It works ok also with Repeater function and also without Repeater function.
Second node is to control cover by relay. It no working correct also with Reapeater and also without Repeater function. Status is not update in the same time. Sometimes no respod reaction on click button.

Below i see SWITCH releay SKETCH and also to Cover.
Please help me.
Also i need help to convert this sketch for Switch 1xRelay to Switch 2x Releay. ANybody can help me. ?

/*
   Relay with button sketch
   modified to work with no uplink
   to gateway and try to maintain sync to controller
*/

// Enable debug prints to serial monitor
#define MY_DEBUG                               // Enable debug prints to serial monitor

// Enable and select radio type attached
#define MY_RADIO_RFM69
#define MY_IS_RFM69HW
#define RFM69_868MH
#define MY_RFM69_NEW_DRIVER

// uncomment if we want to manually assign an ID
#define MY_NODE_ID 2                       // Node id defaults to AUTO (tries to fetch id from controller) 

#define MY_TRANSPORT_WAIT_READY_MS 5000        //set how long to wait for transport ready in milliseconds

#define MY_REPEATER_FEATURE                    // Enabled repeater feature for this node

#include <MySensors.h>
#include <Bounce2.h>

#define RELAY_PIN  5      // Arduino Digital I/O pin number for relay 
#define BUTTON_PIN  3     // Arduino Digital I/O pin number for button 
#define CHILD_ID 1        // Id of the sensor child
#define RELAY_ON 0
#define RELAY_OFF 1

Bounce debouncer = Bounce();
int oldValue = 0;
bool uplinkAvailable = true;
bool state = false;
bool requestState;
bool firstStart = true;
unsigned long uplinkCheckTime ;                // holder for uplink checks
unsigned long uplinkCheckPeriod = 30*1000;     // time between checks for uplink in milliseconds
unsigned long returnWait = 1000;               // how long to wait for return from controller in milliseconds.. adjust as needed
unsigned long oldTime = 0;
unsigned long newTime = 0;
MyMessage msg(CHILD_ID, V_STATUS);

void setup(){
  pinMode(BUTTON_PIN, INPUT_PULLUP);           // Setup the button pin, Activate internal pull-up
  
  debouncer.attach(BUTTON_PIN);                // After setting up the button, setup debouncer
  debouncer.interval(5);

  pinMode(RELAY_PIN, OUTPUT);                 // set relay pin in output mode
  digitalWrite(RELAY_PIN, RELAY_OFF);         // Make sure relay is off when starting up
  send(msg.set(RELAY_OFF), false);           // notify controller to show off state
}

void presentation()  {
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo("1xRelay & Button-Sypialnia", "2.2.0");

  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID, S_BINARY);
}


void loop(){
  if (firstStart) {                            // this code is only run once at startup
    Serial.println("First run started");
    requestTime();                             // get time from controller
    wait (returnWait);                         // delay to allow time to return
    if (oldTime == 0){                         // check to see if there was a return from the time request
      Serial.println("uplink not available");
      uplinkAvailable = false;                 // no uplink established
      uplinkCheckTime = millis();
    }
     else{
      Serial.println("uplink available");
      request( CHILD_ID, V_STATUS);            // get status of switch on controller
      wait (returnWait);                       //wait needed to allow request to return from controller
      Serial.print("controller state --- ");
      Serial.println(requestState);
      if (requestState != state) {             // check that controller is corectly showing the current relay state
        send(msg.set(state), false);           // notify controller of current state
      } 
     }   
  firstStart = false;                                          // set firstStart flag false to prevent code from running again
 }

  debouncer.update();
  int value = debouncer.read();                               // Get the update value
  if (value != oldValue && value == 0) {                      // check for new button push
    state =  !state;                                          // Toggle the state
    digitalWrite(RELAY_PIN, state ? RELAY_ON : RELAY_OFF);    // switch the relay to the new state
    requestTime();
    wait (returnWait);                                               // delay to allow time to return
    if (oldTime != newTime){                                  // if times are different then uplink is available
      send(msg.set(state), false);
      oldTime = newTime;
    }
    else{                                                    // if times are the same no uplink is available
     Serial.println("uplink not available");
      uplinkAvailable = false;                                // no uplink available, set flag false
      uplinkCheckTime = millis();                             // start the timer from now
    }

  }
  oldValue = value;
 
  if (!uplinkAvailable && (millis() - uplinkCheckTime > uplinkCheckPeriod) ) {       // test to see if function should be called
    uplinkCheck();                                                                  // call uplink checking function
  }

}

/*-------------------start of functions--------------------------*/

void receive(const MyMessage &message) {
  if (message.type == V_STATUS) {                                   // check to see if incoming message is for a switch
    switch (message.getCommand()) {                                 // message.getCommand will give us the command type of the incomming message
      case C_SET:                                                   //message is a set command  from controller to update relay state
        state = message.getBool();                                  // get the new state
        digitalWrite(RELAY_PIN, state ? RELAY_ON : RELAY_OFF);      // switch relay to new state
        send(msg.set(state));
        uplinkAvailable = true;                                     //  uplink established
        /*---- Write some debug info----*/
        Serial.print("Incoming change for sensor:");
        Serial.print(message.sensor);
        Serial.print(", New status: ");
        Serial.println(message.getBool());
        break;
      case C_REQ:                                               // message is a returning request from controller
        requestState = message.getBool();                       // update requestState with returning state
        break;
    }
  }
}

void uplinkCheck() {
    requestTime();
    wait (returnWait);                       // wait for time return.. this may need to be varied for your system
   if (oldTime != newTime){
     Serial.println("uplink re-established");
     request( CHILD_ID, V_STATUS);
     wait (returnWait);                        //wait needed to allow request to return from controller
    if (requestState != state) {              // check that controller is corectly showing the current relay state
      send(msg.set(state), false);            // notify controller of current state no ack
      uplinkAvailable = true;                 //  uplink established
      oldTime = newTime;
    }
  }
  uplinkCheckTime = millis();                // reset the checktime
  Serial.println("uplinkchecktime reset");
}


void receiveTime(unsigned long time)
{
  if (firstStart){
    oldTime = time;
    newTime = time;
  }
  else{
  newTime = time;
}
  Serial.print("time received---- " );
  Serial.println(time);
}```

pepson

// Enable debug prints to serial monitor
#define MY_DEBUG

// Enable and select radio type attached
#define MY_RADIO_RFM69
#define MY_IS_RFM69HW
//#define MY_RFM69_FREQUENCY RFM69_868MHZ
#define RFM69_868MH
#define MY_RFM69_NEW_DRIVER

// #define MY_REPEATER_FEATURE

//#define MY_RFM69_CSMA_LIMIT_DBM (-85)

// uncomment if we want to manually assign an ID
#define MY_NODE_ID 1

#include <Bounce2.h>
#include <MySensors.h>
#include <SPI.h>

#define BUTTON_UP_PIN 3  // Arduino Digital I/O pin number for up button
#define BUTTON_DOWN_PIN 4  // Arduino Digital I/O pin number for down button
//#define BUTTON_STOP_PIN 5  // Arduino Digital I/O pin number for stop button
//#define RELAY_DIR_PIN 6  // Arduino Digital I/O pin number for direction relay
//#define RELAY_POWER_PIN 7  // Arduino Digital I/O pin number for power relay
#define RELAY_UP_PIN 5 
#define RELAY_DOWN_PIN 6
#define RELAY_ON 0
#define RELAY_OFF 1
//#define RELAY_DOWN 1
//#define RELAY_UP 0
#define DIRECTION_DOWN 0
#define DIRECTION_UP 1
#define SKETCH_NAME "Roleta w sypialni"
#define SKETCH_VER "2.3"
#define CHILD_ID_COVER 0   // sensor Id of the sensor child
#define STATE_UP 100 // 100 is open - up
#define STATE_DOWN 0 // 0 is closed - down
//#define CHILD_ID_CALIBRATE 1   // sensor Id of the sensor child to calibrate
#define CHILD_ID_SET 1   // sensor Id of the sensor child to init the roll time
#define PRESENT_MESSAGE "Rolety dla Home Assistant"
const int LEVELS = 100; //the number of levels
float rollTime = 20.0; //the overall rolling time of the shutter
const bool IS_ACK = false; //is to acknowlage
static bool initial_state_sent = false;//for hass we need at list one state send at begining

// debouncing parameters
int value = 0;
int oldValueUp = 0;
int oldValueDown = 0;
int oldValueStop = 0;
//static unsigned long last_interrupt_time_up = 0;
//static unsigned long last_interrupt_time_down = 0;
//static unsigned long debounce_time = 200;

Bounce debouncerUp = Bounce();
Bounce debouncerDown = Bounce();
Bounce debouncerStop = Bounce();

// shutter position parameters
float timeOneLevel = rollTime / LEVELS;
int requestedShutterLevel = 0;
int currentShutterLevel = 0;
unsigned long lastLevelTime = 0;
bool isMoving = false;
int directionUpDown;
bool calibrateDown;
bool calibrateUp;
unsigned long calibrationStartTime;
float calibrationTime = 5.0;
bool calibratedDown;
bool calibratedUp;

enum CoverState {
  STOP,
  UP, // Window covering. Up.
  DOWN, // Window covering. Down.
};

static int coverState = STOP;

MyMessage msgUp(CHILD_ID_COVER, V_UP);
MyMessage msgDown(CHILD_ID_COVER, V_DOWN);
MyMessage msgStop(CHILD_ID_COVER, V_STOP);
MyMessage msgPercentage(CHILD_ID_COVER, V_PERCENTAGE);
//MyMessage msgCode(CHILD_ID_SET, V_IR_SEND);

void sendState() {
  // Send current state and status to gateway.
//  send(msgUp.set(coverState == UP));
//  send(msgDown.set(coverState == DOWN));
//  send(msgStop.set(coverState == STOP));
  send(msgPercentage.set(currentShutterLevel));
}

void shuttersUp(void) {
  #ifdef MY_DEBUG
  Serial.println("Shutters going up");
  #endif
  if (digitalRead(RELAY_DOWN_PIN) == RELAY_ON) {
    digitalWrite(RELAY_DOWN_PIN, RELAY_OFF);
    wait(50);
  }
  digitalWrite(RELAY_UP_PIN, RELAY_ON);

  directionUpDown = DIRECTION_UP;
  isMoving = true;
  coverState = UP;
  sendState();
}

void shuttersDown(void) {
  #ifdef MY_DEBUG
  Serial.println("Shutters going down");
  #endif
  if (digitalRead(RELAY_UP_PIN) == RELAY_ON) {
    digitalWrite(RELAY_UP_PIN, RELAY_OFF);
    wait(50);
  }
  digitalWrite(RELAY_DOWN_PIN, RELAY_ON);

  directionUpDown = DIRECTION_DOWN;
  isMoving = true;
  coverState = DOWN;
  sendState();
}

void shuttersHalt(void) {
#ifdef MY_DEBUG
  Serial.println("Shutters halted");
#endif
  digitalWrite(RELAY_UP_PIN, RELAY_OFF);
  digitalWrite(RELAY_DOWN_PIN, RELAY_OFF);

  isMoving = false;
  requestedShutterLevel = currentShutterLevel;
#ifdef MY_DEBUG
  Serial.println("saving state to: ");
  Serial.println(String(currentShutterLevel));
#endif
  saveState(CHILD_ID_COVER, currentShutterLevel);
  coverState = STOP;
  sendState();
}

void changeShuttersLevel(int level) {
  int dir = (level > currentShutterLevel) ? DIRECTION_UP : DIRECTION_DOWN;
  if (isMoving && dir != directionUpDown) {
    shuttersHalt();
  }
  requestedShutterLevel = level;
}

void initShutters() {
#ifdef MY_DEBUG
  Serial.println("Init Cover");
#endif
  shuttersUp();
  wait((rollTime + timeOneLevel * LEVELS) * 1000);
  currentShutterLevel = STATE_UP;
  requestedShutterLevel = currentShutterLevel;
}

void receive(const MyMessage &message) {
#ifdef MY_DEBUG
  Serial.println("recieved incomming message");
  Serial.println("Recieved message for sensor: ");
  Serial.println(String(message.sensor));
  Serial.println("Recieved message with type: ");
  Serial.println(String(message.type));
#endif
  if (message.sensor == CHILD_ID_COVER) {
    switch (message.type) {
      case V_UP:
        //Serial.println(", New status: V_UP");
        changeShuttersLevel(STATE_UP);
        //state = UP;
        //sendState();
        break;

      case V_DOWN:
        //Serial.println(", New status: V_DOWN");
        changeShuttersLevel(STATE_DOWN);
        //state = DOWN;
        //sendState();
        break;

      case V_STOP:
        //Serial.println(", New status: V_STOP");
        shuttersHalt();
        //state = IDLE;
        //sendState();
        break;

      case V_PERCENTAGE:
        //Serial.println(", New status: V_PERCENTAGE");
        //          if (!initial_state_sent) {
        //            #ifdef MY_DEBUG
        //            Serial.println("Receiving initial value from controller");
        //            #endif
        //            initial_state_sent = true;
        //          }
        int per = message.getInt();
        if (per > STATE_UP) {
          per = STATE_UP;
        }
        changeShuttersLevel(per);
        //InitShutters(message.getInt());//send value < 0 or > 100 to calibrate
        //sendState();
        break;
    }
  } 
else if (message.sensor ==  CHILD_ID_SET) {

    if (message.type == V_VAR1) {
      #ifdef MY_DEBUG
      Serial.println(", New status: V_VAR1, with payload: ");
      #endif      
      String strRollTime = message.getString();
      rollTime = strRollTime.toFloat();
      #ifdef MY_DEBUG
      Serial.println("rolltime value: ");
      Serial.println(String(rollTime));
      #endif
      saveState(CHILD_ID_SET, rollTime);
    }
  }
#ifdef MY_DEBUG
  Serial.println("exiting incoming message");
#endif
  return;
}

void before() {

  // Setup the button
  pinMode(BUTTON_UP_PIN, INPUT_PULLUP);
  // Activate internal pull-up
//  digitalWrite(BUTTON_UP_PIN, HIGH);
  //  attachInterrupt(digitalPinToInterrupt(BUTTON_UP_PIN), upButtonPress, FALLING);

  pinMode(BUTTON_DOWN_PIN, INPUT_PULLUP);
  // Activate internal pull-up
//  digitalWrite(BUTTON_DOWN_PIN, HIGH);
  //  attachInterrupt(digitalPinToInterrupt(BUTTON_DOWN_PIN), downButtonPress, FALLING);

//  pinMode(BUTTON_STOP_PIN, INPUT_PULLUP);
  // Activate internal pull-up
//  digitalWrite(BUTTON_STOP_PIN, HIGH);

  // After setting up the button, setup debouncer
  debouncerUp.attach(BUTTON_UP_PIN);
  debouncerUp.interval(5);
  // After setting up the button, setup debouncer
  debouncerDown.attach(BUTTON_DOWN_PIN);
  debouncerDown.interval(5);
  // After setting up the button, setup debouncer
//  debouncerStop.attach(BUTTON_STOP_PIN);
//  debouncerStop.interval(5);

  // Make sure relays are off when starting up
  digitalWrite(RELAY_UP_PIN, RELAY_OFF);
  // Then set relay pins in output mode
  pinMode(RELAY_UP_PIN, OUTPUT);

  // Make sure relays are off when starting up
  digitalWrite(RELAY_DOWN_PIN, RELAY_OFF);
  // Then set relay pins in output mode
  pinMode(RELAY_DOWN_PIN, OUTPUT);
}

void presentation() {
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo(SKETCH_NAME, SKETCH_VER);
  // Register all sensors to gw (they will be created as child devices)
  present(CHILD_ID_COVER, S_COVER, PRESENT_MESSAGE, IS_ACK);
  // present(CHILD_ID_SET, S_CUSTOM);
}

void setup(void) {
  //set up roll time if the saved value is not 255
  #ifdef MY_DEBUG
  Serial.println("getting rolltime from eeprom: ");
  #endif
  float tmpRollTime = loadState(CHILD_ID_SET);
  if (tmpRollTime != 0xff) {
    rollTime = tmpRollTime;
  }
  #ifdef MY_DEBUG
  Serial.println(String(rollTime));
  #endif
  
  int state = loadState(CHILD_ID_COVER);
  
  #ifdef MY_DEBUG
  Serial.println("getting state from eeprom: ");
  Serial.println(String(state));
  #endif
  
//  if (state == 0xff) {
//    initShutters();
//  } else {
    currentShutterLevel = state;
    requestedShutterLevel = state;
//  }
}

void loop(void) {
  if (!initial_state_sent) {
#ifdef MY_DEBUG
    Serial.println("Sending initial value");
#endif
    sendState();
    
   // send(msgCode.set('20.0'));
    //    #ifdef MY_DEBUG
    //    Serial.println("Requesting initial value from controller");
    //    #endif
    //    request(CHILD_ID_COVER, V_PERCENTAGE);
    //    wait(2000, C_SET, V_PERCENTAGE);
    initial_state_sent = true;
  }

  debouncerUp.update();
  value = debouncerUp.read();
  if (value == 0 && value != oldValueUp) {
    if(isMoving){
      shuttersHalt();
    }  
    else{
    calibrateUp = false;
    calibratedUp = false;
    changeShuttersLevel(STATE_UP);
    }
    //state = UP;
    //sendState();
  }
  oldValueUp = value;

  debouncerDown.update();
  value = debouncerDown.read();
  if (value == 0 && value != oldValueDown) {
    if(isMoving){
      shuttersHalt();
    }  
    else{
    calibrateDown = false;
    calibratedDown = false;
    changeShuttersLevel(STATE_DOWN);
    }    
    //state = DOWN;
    //sendState();
  }
  oldValueDown = value;

/*  debouncerStop.update();
  value = debouncerStop.read();
  if (value == 0 && value != oldValueStop) {
    shuttersHalt();
    //state = IDLE;
    //sendState();
  }
  oldValueStop = value;
*/
  if(currentShutterLevel != 100)
  {
    calibrateUp = false;
    calibratedUp = false;
  }
  if(currentShutterLevel != 0)
  {
    calibrateDown = false;
    calibratedDown = false;
  }
  
  if (isMoving) 
  {
    unsigned long _now = millis();
    if (_now - lastLevelTime >= timeOneLevel * 1000) {
      if (directionUpDown == DIRECTION_UP) {
        currentShutterLevel += 1;
      } else {
        currentShutterLevel -= 1;
      }
      currentShutterLevel = constrain(currentShutterLevel, 0, 100);
      #ifdef MY_DEBUG
      Serial.println(String(requestedShutterLevel));
      Serial.println(String(currentShutterLevel));
      #endif
      lastLevelTime = millis();
      send(msgPercentage.set(currentShutterLevel));
    }
    if (currentShutterLevel == requestedShutterLevel) 
    {
      if(currentShutterLevel == 0 && !calibratedDown)
      {
        if(calibrateDown == false)
        {
          calibrateDown = true;
          calibratedDown = false;
          calibrationStartTime = _now;
        }
        else 
        {
          if(calibratedDown == false)
          {
            if (_now - calibrationStartTime >= calibrationTime * 1000)
            {
             calibratedDown = true;
            }
          }
        }
      }
      else if (currentShutterLevel == 100 && !calibratedUp)
      {
        if(calibrateUp == false)
        {
          calibrateUp = true;
          calibratedUp = false;
          calibrationStartTime = _now;
        }
        else 
        {
          if(calibratedUp == false)
          {
            if (_now - calibrationStartTime >= calibrationTime * 1000)
            {
             calibratedUp = true;
            }
          }
        }
      }
      else
      {
        shuttersHalt();
      }
    }
  } 
  else 
  {
    if (requestedShutterLevel != currentShutterLevel) 
    {
      if (requestedShutterLevel > currentShutterLevel) {
        shuttersUp();
      }
      else {
        shuttersDown();
      }
      lastLevelTime = millis();
    }
  }
}

pepson

Finally
In my opinion on MySensors 2.2.0 all my sketches (switch relay and cover ) works better. With no problem. NO PROBLEM.
Cover works perfect and switch works perfect without any timeout and delay. ANd all node works without REPEATER.
My opinion is that in version 2.3.0 something not working correct with radio RFM69HW.
Maybe for sensors which send data from time to time is ok , but for cover which transfer data when cover is roll, it is problem... and gateway can not recived all data when node send position cover. Maybe developer read this thread and can do any changes to correct it.

pepson

@mickecarlsson

ANd tell me how you connect Gateway to your Domoticz Controller ? What path to usb or serial you setup in Domoticz ?

scalz

@pepson said in RFM69 new driver delay:

My opinion is that in version 2.3.0 something not working correct with radio RFM69HW.
Maybe for sensors which send data from time to time is ok , but for cover which transfer data when cover is roll, it is problem... and gateway can not recived all data when node send position cover. Maybe developer read this thread and can do any changes to correct it.

Like I said, we will take a look as soon as we get time. For the moment, busy (at least on my side). And we're a few, using rfm69.
So if 2.2 fixes your issue, it can be a good idea.

pepson

@scalz

Ok thanks. WAiting for info... and good info for me will be that problem with RFM69HW on version 2.3.0 will be resolve and i can update to this version. Now i must come back to version 2.2.0

gohan

If you don't need specific features in 2.3, then stick to 2.2 that works well.

sineverba

@pepson said in RFM69 new driver delay:

Finally
In my opinion on MySensors 2.2.0 all my sketches (switch relay and cover ) works better. With no problem. NO PROBLEM.
Cover works perfect and switch works perfect without any timeout and delay. ANd all node works without REPEATER.
My opinion is that in version 2.3.0 something not working correct with radio RFM69HW.
Maybe for sensors which send data from time to time is ok , but for cover which transfer data when cover is roll, it is problem... and gateway can not recived all data when node send position cover. Maybe developer read this thread and can do any changes to correct it.

RFM69W / HW user here. I can confirm that V 2.3.0 on both nodes and PI has some broken. My nodes, stable for 3+ months, with new version they have issues. In detail, they cannot get ACK. In my sketch, I check for ACK when transmitting, to force the watchdog or no. NO ACK received (1 every 20/30) :(

And my nodes are "perfect". LifePo4 or AA, someone feeded directly, RPI3 with 2.5a... And I repeat, no issues in 3+ months from switching from NRF to RFM.

mickecarlsson

This is my generic temperature/humidity/battery level sketch that I use. I have upgraded all my nodes and gateway to 2.3.0 yesterday and I don't have any issue whatsoever :-)

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * DESCRIPTION
 *
 * This is a sketch I use to measure temperature, humidity and battery level on
 * my Easy/Newbie PCB for MySensors (rev 9)
 * Hardware used:
 * Easy/Newbie PCB for MySensors
 * BME280 (I only use temperature and humidity, all code for barometic pressure removed)
 *
 */

// Enable debug prints to serial monitor
//#define MY_DEBUG
#define   MY_SPLASH_SCREEN_DISABLED  // This saves a couple of bytes
// Enable and select radio type attached
#define   MY_RADIO_RFM69
#define   MY_IS_RFM69HW
#define   MY_RFM69_NEW_DRIVER
#define   MY_RFM69_FREQUENCY RFM69_868MHZ

#include <MySensors.h>
#include <Wire.h>       // Enables the Wire communication protocol.
// Bosch BME280 Embedded Adventures MOD-1022 weather multi-sensor Arduino code, 
// written originally by Embedded Adventures. 
// https://github.com/embeddedadventures/BME280
#include <BME280_MOD-1022.h>
// Internal battery measurement https://github.com/Yveaux/arduino_vcc
#include <Vcc.h>

// Change all text variables here, no need to hunt them down in the sketch
// For sendSketchInfo()
#define SKETCH_NAME       "Generic Temeperature/Humidity"
#define SKETCH_VERSION    "1.13"
// For present()
#define PRESENT_TEMP_TEXT "Temperature Generic"
#define PRESENT_HUM_TEXT  "Humidity Generic"
#define PRESENT_BAT_TEXT  "Batteri Test-3"

// Battery measurements
const float VccMin        = 1.8*1.0;  // Min Vcc level, in Volts. Example for 2xAA Alkaline.
const float VccMax        = 2.0*1.5;  // Max Vcc level, in Volts. Example for 2xAA Alkaline.
const float VccCorrection = 1.0/1.0;  // Measured Vcc by multimeter divided by reported Vcc

Vcc vcc(VccCorrection);

// VARIABLES YOU CAN CHANGE
// Send temperature only if it has changed? 1 = Yes 0 = No.
#define COMPARE_TEMP 0
// Set this value to the minimum change in temperature to measure.
// BME280 has +-0.5 degrees precision, so it really doesn't matter that much.
float tempThreshold = 0.5;
// Send temperature only if changed? 1 = Yes 0 = No.
#define COMPARE_HUM 0
// Set this value to the minimum change in humidity to measure.
// BME280 has +-3% relative humidity precision, so it really doesn't matter that much.
float humThreshold = 0.5;

#define TEMP_CHILD_ID       1
#define HUM_CHILD_ID        2
#define VOLTAGE_CHILD_ID    3

float lastTemperature = -1;   // Store previous measurement
float lastHumidity =    -1;   // Stores the previous measurement
bool reportRSSI = false;      // true = send RSSI to controller
int sendBattery = 6;          // report battery level only after 6 loops = 6*4 minutes = 24 minutes
// Placeholder for batteryloop, set to one above sendBattery so that we get a report on startup
int batteryLoop = sendBattery + 1; 

// Time between send (in milliseconds), in this case, 4 minutes.
unsigned long FOUR_MINUTE_SEND_FREQUENCY = 4 * 60000;

// MYSENSORS COMMUNICATION VARIABLES
MyMessage temperatureMsg(TEMP_CHILD_ID, V_TEMP);
MyMessage humidityMsg(HUM_CHILD_ID, V_HUM);
MyMessage voltageMsg(VOLTAGE_CHILD_ID, V_VOLTAGE);

void setup()
{

#ifdef MY_DEBUG
  Serial.begin(115200);
#endif

  Wire.begin(); // For the BME280 sensor
#ifdef MY_DEBUG
  Serial.println(F("Starting ..."));
#endif
}

void presentation()
{
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo(SKETCH_NAME, SKETCH_VERSION);
  // Present the sensors to the gateway and controller
  present(TEMP_CHILD_ID, S_TEMP, PRESENT_TEMP_TEXT);
  present(HUM_CHILD_ID, S_HUM, PRESENT_HUM_TEXT);
  present(VOLTAGE_CHILD_ID, S_MULTIMETER, PRESENT_BAT_TEXT);
}

void loop()
{
#ifdef MY_DEBUG
  Serial.println(F("Read BME280 and report it's values."));
#endif
  GetTemperatureHumidity();                 // Get temperature and humidity

  if(batteryLoop > sendBattery) {           // Is the batteryLoop higher than sendBattery?
#ifdef MY_DEBUG
    Serial.println(F("Read the battery voltage and report it."));
#endif
    MeasureBattery();                      // Measure and report battery level
    batteryLoop = 0;                       // Reset batteryLoop count
}
#ifdef MY_DEBUG
  Serial.print(F("Go to sleep for: "));
  Serial.print(FOUR_MINUTE_SEND_FREQUENCY / 60000);
  Serial.println(F(" minutes."));
#endif
  batteryLoop++;                           // Increase batteryLoop before we sleep. 
  sleep(FOUR_MINUTE_SEND_FREQUENCY);       // Sleep for 4 minutes
}

/************************************************
* GetTemperatureHumidity()
* Routine for measuring temperature and humidity
* Generic one that fits my need 
************************************************/
void GetTemperatureHumidity()
{
#ifdef MY_DEBUG
  Serial.println("");
  Serial.println(F("BME280 - Requesting new data from sensor module."));
#endif
  BME280.readCompensationParams();            // Need to read the NVM compensation parameters.
  // Normal mode for regular automatic samples
  BME280.writeStandbyTime(tsb_0p5ms);         // tsb = 0.5ms
  BME280.writeFilterCoefficient(fc_16);       // IIR Filter coefficient 16
  BME280.writeOversamplingPressure(os16x);    // pressure x16
  BME280.writeOversamplingTemperature(os8x);  // temperature x8
  BME280.writeOversamplingHumidity(os8x);     // humidity x8
  BME280.writeMode(smNormal);
    
#ifdef MY_DEBUG
  Serial.println(F("Getting new values"));
#endif
  while (BME280.isMeasuring()) {              // Wait for BME280 to fininsh reading data
#ifdef MY_DEBUG
    Serial.println("Measuring...");
#endif
    delay(50);
  }
  Serial.println("Done!");
  // Read out the data - must do this before calling the getxxxxx routines
  BME280.readMeasurements();
  float temperature = BME280.getTemperatureMostAccurate();  // Get the temperature first.
  float humidity = BME280.getHumidityMostAccurate();        // Get the humidity.
#ifdef MY_DEBUG
  Serial.print(F("BME280 - Temperature = "));
  Serial.print(temperature);
  Serial.println(" °C");
  Serial.print(F("BME280 - Humidity = "));
  Serial.print(humidity);
  Serial.println(F(" %"));
#endif
  // Now, let's send the measurements to the gateway.
  // Send temperature if the temperature difference bigger than the threshold
  if (COMPARE_TEMP == 1 && abs(temperature - lastTemperature) < tempThreshold) { 
#ifdef MY_DEBUG
    Serial.print(temperature - lastTemperature);
    Serial.println(F(" Temperature difference too small, don't send it to gateway."));
#endif
  } else {
#ifdef MY_DEBUG
      Serial.println(F("Sending new temperature to the gateway."));
#endif
      send(temperatureMsg.set(temperature, 1));
      lastTemperature = temperature; // Save temperatures for compare in the next round.
  } 
  // Send humidity if the humidity difference is bigger than the threshold.
  if (COMPARE_TEMP == 1 && abs(humidity - lastHumidity) < humThreshold) { 
#ifdef MY_DEBUG
    Serial.print(humidity - lastHumidity);
    Serial.println(F(" Humidity difference too small, don't send it to the gateway."));
#endif
  } else {
#ifdef MY_DEBUG
    Serial.println(F("BME280 - Sending the new humidity to the gateway."));
#endif
    send(humidityMsg.set(humidity, 1));
    lastHumidity = humidity; // Save new humidity to be able to compare in the next round.
  }
#ifdef MY_DEBUG
  Serial.println(F("BME280 - Measurement complete. Putting sensor to sleep."));
#endif
  BME280.writeMode(smSleep);  // set the BME280to sleep mode, save battery
} // End of GetTemperatureHumidity

/*
* MeasureBattery()
* Routine for measuring battery level
* Generic one that fits my need
* NOTE: You need to calibrate the measurement to get correct readings
*/
void MeasureBattery()
{
  float Vbat = vcc.Read_Volts();
  int batteryPercent = static_cast<int>(vcc.Read_Perc(VccMin, VccMax));

#ifdef MY_DEBUG
  Serial.print(F("Battery percent: ")); 
  Serial.print(batteryPercent); 
  Serial.println(" %"); 
  Serial.print(F("Battery Voltage: ")); 
  Serial.print(Vbat); 
  Serial.println(F(" Volts"));
#endif
    sendBatteryLevel(batteryPercent);
    send(voltageMsg.set(Vbat,2)); //send battery in Volt 2 decimal places
}

RFM69 new driver delay

18

11.7k

11.2k

113.1k