Multiple interuppts: One Arduino with two door sensors?

[algoritm]

I've been looking around the forum for a solution, but haven't found one. I have one arduino and two door/window sensors. One sensor will be on my apartments front door, while the other sensor will sit on the mailbox-slot.

The problem is that I don't know how to get two interrupts running at the same time. So if the door opens, one interrupt should trigger. And if I get mail (and the slot opens) the second interrupt should trigger.

I'm using an arduino pro mini 328p.

Here's my code:

#include <MySensor.h>
#include <SPI.h>
#include <Bounce2.h>

#define CHILD_ID_DOOR 0
#define CHILD_ID_MAIL 1
#define DOOR_PIN  2  // Arduino Digital I/O pin for button/reed switch
#define MAIL_PIN  3  // Arduino Digital I/O pin for button/reed switch

#define INTERRUPT DOOR_PIN-2 
#define INTERRUPTMAIL_PIN-3 

// For lipo gauge
#include "Arduino.h"
#include "Wire.h"
#include "MAX1704.h"

MAX1704 fuelGauge;
int oldBatteryPcnt = 0;


unsigned long SLEEP_TIME = 86400000; // 1 day


MySensor gw;
Bounce debouncer_door = Bounce(); 
Bounce debouncer_mail = Bounce(); 
int oldValue_door = -1;
int oldValue_mail = -1;

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msgDoor(CHILD_ID_DOOR,V_TRIPPED);
MyMessage msgMail(CHILD_ID_MAIL,V_TRIPPED);

void setup()  
{  
  // Fuel gague
  fuelGauge.reset();
  fuelGauge.quickStart();
  fuelGauge.showConfig();
  
  gw.begin();

  // Setup the button
  pinMode(DOOR_PIN,INPUT);
  // Activate internal pull-up
  digitalWrite(DOOR_PIN,HIGH);
  
  pinMode(MAIL_PIN,INPUT);
  // Activate internal pull-up
  digitalWrite(MAIL_PIN,HIGH);
  
  // After setting up the button, setup debouncer
  debouncer_door.attach(DOOR_PIN);
  debouncer_door.interval(5);
  
  debouncer_mail.attach(DOOR_PIN);
  debouncer_mail.interval(5);
  
  // Register binary input sensor to gw (they will be created as child devices)
  // You can use S_DOOR, S_MOTION or S_LIGHT here depending on your usage. 
  // If S_LIGHT is used, remember to update variable type you send in. See "msg" above.
  gw.present(CHILD_ID_DOOR, S_DOOR);
  gw.present(CHILD_ID_MAIL, S_DOOR);  
}


//  Check if digital input has changed and send in new value
void loop() 
{
  
  // Fuel gauge
  int batteryPcnt = fuelGauge.stateOfCharge();
  
  if (oldBatteryPcnt != batteryPcnt) {
     // Power up radio after sleep
     gw.sendBatteryLevel(batteryPcnt);
     oldBatteryPcnt = batteryPcnt;
   }
  
  // Door
  debouncer_door.update();
  // Get the update value
  int value_door = debouncer_door.read();
 
  if (value_door != oldValue_door) {
     // Send in the new value
     gw.send(msgDoor.set(value_door==HIGH ? 1 : 0));
     oldValue_door = value_door;
  }
  
  // Mail
  debouncer_mail.update();
  // Get the update value
  int value_mail = debouncer_mail.read();
 
  if (value_mail != oldValue_mail) {
     // Send in the new value
     gw.send(msgMail.set(value_mail==HIGH ? 1 : 0));
     oldValue_mail = value_mail;
  }
  
  gw.sleep(INTERRUPT,CHANGE, SLEEP_TIME);
}

I'm a bit proud to have built this into a small enclosure. Here's a photo

[ericvdb]

What is the upsidedown pcb?

[algoritm]

@ericvdb It's a USB charger board (TP4056). The battery is connected to it via a MAX17043 LiPo Fuel Gauge which is soldered directoly onto the usb charger board.

[BulldogLowell]

@algoritm

try setting up the two interrupts this way...

Test it (I compiled but didn't test) and then add in your sleep and battery stuff...

// Simple binary switch example 
//USING TWO INTERRUPTS

#include <MySensor.h>
#include <SPI.h>
#include <Bounce2.h>

#define DOOR_ID 3
#define MAILBOX_ID 2
#define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
#define MAILBOX_PIN 2


MySensor gw;
Bounce debouncer[2];
byte oldValue[2] = {
  -1, -1};

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msg(DOOR_ID,V_TRIPPED);

void setup()  
{  
  gw.begin();
  debouncer[0] = Bounce();
  debouncer[1] = Bounce();
  // Setup the buttons and Activate internal pull-ups
  pinMode(DOOR_PIN,INPUT_PULLUP);
  pinMode(MAILBOX_PIN, INPUT_PULLUP);
  //
  debouncer[0].attach(DOOR_PIN);
  debouncer[1].attach(MAILBOX_PIN);
  debouncer[0].interval(5);
  debouncer[1].interval(5);
  //
  gw.present(DOOR_ID, S_DOOR);
  delay(250);
  gw.present(MAILBOX_ID, S_DOOR);
}
//
void loop() 
{
  for (byte i = 0; i < 2; i++)
  {
    debouncer[i].update();
    int value = debouncer[i].read();
    if (value != oldValue[i]);
    gw.send(msg.setSensor(i).set(value == HIGH? 1 : 0), false); 
    oldValue[i] = value;
  }
}

[algoritm]

Thanks for the help @BulldogLowell!

I read your code, and I can see that you are setting the variables smarter than I. However, I can't seem to understand where you put the interrupts. Is the sensor going to sleep?

The actual button/triggers were not the problem. It was how to set up the interrupts.

[hek]

Have a look at the following provided in api
https://github.com/mysensors/Arduino/blob/master/libraries/MySensors/MySensor.h#L235

It lets you do what you want without much problem (including attaching both interrupts).

[algoritm]

Thank you @hek! I will try and solve it now, and then show my sketch here later.

[BulldogLowell]

@algoritm

OK, I couldn't compile your example so I went at the problems.

I added your battery library and your interrupts:

(compiled but not tested)

// Simple binary switch example 
//USING TWO INTERRUPTS
//
#include <MySensor.h>
#include <SPI.h>
#include <Bounce2.h>
// For lipo gauge
#include "Arduino.h"
#include "Wire.h"
#include "MAX1704.h"
//
#define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
#define MAILBOX_PIN 2
//
MAX1704 fuelGauge;
int oldBatteryPcnt = 0;
//
MySensor gw;
Bounce debouncer[2];
byte oldValue[2] = { -1, -1};
//
unsigned long sleepTime = 86400000UL; // 1 day

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msg(DOOR_PIN,V_TRIPPED);
//
void setup()  
{  
  // Fuel gauge
  fuelGauge.reset();
  fuelGauge.quickStart();
  fuelGauge.showConfig();
  //
  gw.begin();
  debouncer[0] = Bounce();
  debouncer[1] = Bounce();
  // Setup the buttons and Activate internal pull-ups
  pinMode(DOOR_PIN,INPUT_PULLUP);
  pinMode(MAILBOX_PIN, INPUT_PULLUP);
  //
  debouncer[0].attach(DOOR_PIN);
  debouncer[1].attach(MAILBOX_PIN);
  debouncer[0].interval(5);
  debouncer[1].interval(5);
  //
  gw.present(DOOR_PIN, S_DOOR);
  delay(250);
  gw.present(MAILBOX_PIN, S_DOOR);
}
//
void loop() 
{
  // Fuel gauge
  int batteryPcnt = fuelGauge.stateOfCharge();
  if (oldBatteryPcnt != batteryPcnt) 
  {
     gw.sendBatteryLevel(batteryPcnt);
     oldBatteryPcnt = batteryPcnt;
   }
   //
  for (byte i = 0; i < 2; i++)
  {
    debouncer[i].update();
    int value = debouncer[i].read();
    if (value != oldValue[i]);
    gw.send(msg.setSensor(i).set(value == HIGH? 1 : 0), false); 
    oldValue[i] = value; 
  }
  gw.sleep(DOOR_PIN - 2, CHANGE, MAILBOX_PIN - 2, CHANGE, sleepTime);
}

[algoritm]

Thanks @BulldogLowell for all your help! The interrupts are working now, but there is something wrong with the MyMessage function.

MyMessage msg(DOOR_PIN,V_TRIPPED);

Correct me if I am wrong, but it seems like we only instantiate it for the DOOR_PIN, but not for the MAILBOX_PIN. I tried a solution similar to how you instantiate the the bounce functions, but for some reason it does not work.

What happens now is only one message gets sent (for the door). And it's also saying that it is always closed.

gw.send(msg.setSensor(i).set(value == HIGH? 1 : 0), false); 

I can see here that you use the setSensor method to the pin numbers 0 and 1 (interrupt pins?). But shouldn't it use the pins that we declare at the top?

 #define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
 #define MAILBOX_PIN 2

[BulldogLowell]

@BulldogLowell said:

gw.present(DOOR_PIN, S_DOOR);
delay(250);
gw.present(MAILBOX_PIN, S_DOOR);

yeah.... the device numbers need to match the for() counting:

gw.present(DOOR_PIN - 2, S_DOOR);
  delay(250);
  gw.present(MAILBOX_PIN - 2, S_DOOR);

that will instead create a child device zero and one

I think that should do it. that's what I get for not being able to test!

[algoritm]

Thanks again @BulldogLowell

I think I'm going a bit crazy over this. The problem remains. Only the data for the door is being sent (it only sends closed), but not for the mailbox. Is it because I am defining only the door in the code below?

 MyMessage msg(DOOR_PIN,V_TRIPPED);

[BulldogLowell]

@algoritm

same issue, basically.

try this instead... you should only need one instance of MyMessage

MyMessage msg(0,V_TRIPPED);

[algoritm]

The problem remains @BulldogLowell . It's like the arduino is treating the two interrupts as one.

The sensors react when trigger them, but it's only N2S1 (door) that shows up in my gateway (EasyIoT), and it always displays the same value (closed). I'm going to go over the wiring and the code again.

Reading one sensor connected to one interrupt is simple... reading two seems impossible

Here's the current state of the sketch:

// Simple binary switch example 
//USING TWO INTERRUPTS
//
#include <MySensor.h>
#include <SPI.h>
#include <Bounce2.h>
// For lipo gauge
#include "Arduino.h"
#include "Wire.h"
#include "MAX1704.h"
//
#define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
#define MAILBOX_PIN 2
//
MAX1704 fuelGauge;
int oldBatteryPcnt = 0;
//
MySensor gw;
Bounce debouncer[2];
byte oldValue[2] = { -1, -1};
//
unsigned long sleepTime = 86400000UL; // 1 day

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msg(0,V_TRIPPED);
//
void setup()  
{  
  // Fuel gauge
  fuelGauge.reset();
  
  // GW
  gw.begin();
  debouncer[0] = Bounce();
  debouncer[1] = Bounce();
  // Setup the buttons and Activate internal pull-ups
  pinMode(DOOR_PIN,INPUT_PULLUP);
  pinMode(MAILBOX_PIN, INPUT_PULLUP);
  //
  debouncer[0].attach(DOOR_PIN);
  debouncer[1].attach(MAILBOX_PIN);
  debouncer[0].interval(5);
  debouncer[1].interval(5);
  //
  gw.present(DOOR_PIN - 2, S_DOOR);
  delay(250);
  gw.present(MAILBOX_PIN - 2, S_DOOR);
}
//
void loop() 
{
  // Fuel gauge
  int batteryPcnt = fuelGauge.stateOfCharge();
  if (oldBatteryPcnt != batteryPcnt) 
  {
     gw.sendBatteryLevel(batteryPcnt);
     oldBatteryPcnt = batteryPcnt;
   }
   //
  for (byte i = 0; i < 2; i++)
  {
    debouncer[i].update();
    int value = debouncer[i].read();
    if (value != oldValue[i]);
    gw.send(msg.setSensor(i).set(value == HIGH? 1 : 0), false); 
    oldValue[i] = value; 
  }
  gw.sleep(DOOR_PIN - 2, CHANGE, MAILBOX_PIN - 2, CHANGE, sleepTime);
}

[hek]

@algoritm said:

MyMessage msg(<sensorId>,V_TRIPPED);

You must report data on on two different sensor ids.

DOOR_PIN and MAILBOX_PIN was used during presentation so also use them when reporting values to controller.

The sleep function I linked returns which interrupt that was triggered. Use it to determine which sensor to report on.

Debouncer will probably not work if you also sleep the node.

[algoritm]

@BulldogLowell said:

MyMessage msg(0,V_TRIPPED);

So I need to call MyMessage twice. one for each sensor ID? How do I do that without making two instances? That is kind of what I have been trying to do, but I'm having trouble with the syntax.

[BulldogLowell]

like this?

// Simple binary switch example 
//USING TWO INTERRUPTS
//
#include <MySensor.h>
#include <SPI.h>
// For lipo gauge
#include "Arduino.h"
#include "Wire.h"
#include "MAX1704.h"
//
#define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
#define MAILBOX_PIN 2
//
MAX1704 fuelGauge;
int oldBatteryPcnt = 0;
//
MySensor gw;
//
unsigned long sleepTime = 86400000UL; // 1 day

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msg1(DOOR_PIN - 2,V_TRIPPED);
MyMessage msg0(MAILBOX_PIN - 2,V_TRIPPED);
//
void setup()  
{  
  // Fuel gauge
  fuelGauge.reset();
  fuelGauge.quickStart();
  fuelGauge.showConfig();
  //
  gw.begin();
  // Setup the buttons and Activate internal pull-ups
  pinMode(DOOR_PIN,INPUT_PULLUP);
  pinMode(MAILBOX_PIN, INPUT_PULLUP);
  //
  gw.present(DOOR_PIN-2, S_DOOR);
  delay(250);
  gw.present(MAILBOX_PIN-2, S_DOOR);
}
//
void loop() 
{
  // Fuel gauge
  int batteryPcnt = fuelGauge.stateOfCharge();
  if (oldBatteryPcnt != batteryPcnt) 
  {
    gw.sendBatteryLevel(batteryPcnt);
    oldBatteryPcnt = batteryPcnt;
  }
  int value0 = digitalRead(MAILBOX_PIN);
  int value1 = digitalRead(DOOR_PIN);
  gw.send(msg0.set(value0 == HIGH? 1 : 0), false); 
  gw.send(msg1.set(value1 == HIGH? 1 : 0), false); 
  gw.sleep(DOOR_PIN - 2, CHANGE, MAILBOX_PIN - 2, CHANGE, sleepTime);
}

[algoritm]

@BulldogLowell Thank you! It finally works! I'll make a sketch with comments so other people can use it later for reference.

[BulldogLowell]

@algoritm

OK, but we should be able to do it with the sleep/wake returning the interrupt number and executing only the pin change on one child... I have to play with that if I can get this rigged.

[algoritm]

Here's the finished script.

  #include <MySensor.h>
  #include <SPI.h>
  // For lipo gauge
  #include "Arduino.h"
  #include "Wire.h"
  #include "MAX1704.h"

  #define DOOR_ID 3
  #define MAILBOX_ID 2

  #define DOOR_PIN  3  // Arduino Digital I/O pin for button/reed switch
  #define MAILBOX_PIN 2
  //
  MAX1704 fuelGauge;
  int oldBatteryPcnt = 0;
  //
  MySensor gw;
  byte oldValue[2] = { -1, -1};
  //
  unsigned long sleepTime = 86400000UL; // 1 day

  // Change to V_LIGHT if you use S_LIGHT in presentation below
  //MyMessage msg(DOOR_PIN,V_TRIPPED);

  MyMessage msg[2];

  void setup()  
  {  
    // Fuel gauge
    fuelGauge.reset();
    fuelGauge.quickStart();
    fuelGauge.showConfig();
    //
    gw.begin();
    
    // Setup the buttons and Activate internal pull-ups
    pinMode(DOOR_PIN,INPUT_PULLUP);
    pinMode(MAILBOX_PIN, INPUT_PULLUP);

    // Set sensor (pin)
    msg[0].setSensor(DOOR_ID);
    msg[1].setSensor(MAILBOX_ID);

    // Set sensor (type)
    msg[0].setType(V_TRIPPED);
    msg[1].setType(V_TRIPPED);
    
    
    gw.present(DOOR_ID, S_DOOR);
    gw.present(MAILBOX_ID, S_DOOR);
  }
  //
  void loop() 
  {
    // Fuel gauge
    int batteryPcnt = fuelGauge.stateOfCharge();
    if (oldBatteryPcnt != batteryPcnt) 
    {
       gw.sendBatteryLevel(batteryPcnt);
       oldBatteryPcnt = batteryPcnt;
     }
     //
    for (byte i = 0; i < 2; i++)
    {
      debouncer[i].update();
      int value = debouncer[i].read();
      
      //if (value != oldValue[i]);  
      gw.send(msg[i].set(value == HIGH? 1 : 0), false); 
      oldValue[i] = value;
       
    }
    gw.sleep(DOOR_PIN - 2, CHANGE, MAILBOX_PIN - 2, CHANGE, sleepTime);
  }

[gadu]

How about 3 doorsensors? Just +1 on everything?

[BulldogLowell]

@gadu

there are two external interrupts on most Arduino... but Mega has six.
so yes, you can extend the code above if you have the right hardware.

but... @hek 's library may not support more than two.

[tbowmo]

@gadu said:

How about 3 doorsensors? Just +1 on everything?

You could make an or gate, with a couple of diodes, then you only only need 1 interrupt pin. If you need to check which one of the reed switches was triggered, you could wire each of them to a separate input on the arduino as well as the input to the or gate.

[algoritm]

I found this example file to work much better. The battery drained a lot slower.

  // Interrupt driven binary switch example with dual interrupts
  // Author: Patrick 'Anticimex' Fallberg
  // Connect one button or door/window reed switch between 
  // digitial I/O pin 3 (BUTTON_PIN below) and GND and the other
  // one in similar fashion on digital I/O pin 2.
  // This example is designed to fit Arduino Nano/Pro Mini

  // For lipo gauge
  #include "Arduino.h"
  #include "Wire.h"
  #include "MAX1704.h"

  MAX1704 fuelGauge;
  int oldBatteryPcnt = 0;

  #include <MySensor.h>
  #include <SPI.h>

  #define SKETCH_NAME "Binary Sensor"
  #define SKETCH_MAJOR_VER "1"
  #define SKETCH_MINOR_VER "0"

  #define PRIMARY_CHILD_ID 3
  #define SECONDARY_CHILD_ID 4

  #define PRIMARY_BUTTON_PIN 2   // Arduino Digital I/O pin for button/reed switch
  #define SECONDARY_BUTTON_PIN 3 // Arduino Digital I/O pin for button/reed switch

  #if (PRIMARY_BUTTON_PIN < 2 || PRIMARY_BUTTON_PIN > 3)
  #error PRIMARY_BUTTON_PIN must be either 2 or 3 for interrupts to work
  #endif
  #if (SECONDARY_BUTTON_PIN < 2 || SECONDARY_BUTTON_PIN > 3)
  #error SECONDARY_BUTTON_PIN must be either 2 or 3 for interrupts to work
  #endif
  #if (PRIMARY_BUTTON_PIN == SECONDARY_BUTTON_PIN)
  #error PRIMARY_BUTTON_PIN and BUTTON_PIN2 cannot be the same
  #endif
  #if (PRIMARY_CHILD_ID == SECONDARY_CHILD_ID)
  #error PRIMARY_CHILD_ID and SECONDARY_CHILD_ID cannot be the same
  #endif
   
  MySensor sensor_node;

  // Change to V_LIGHT if you use S_LIGHT in presentation below
  MyMessage msg(PRIMARY_CHILD_ID, V_TRIPPED);
  MyMessage msg2(SECONDARY_CHILD_ID, V_TRIPPED);

  void setup()  
  {  
    sensor_node.begin();

    // Setup the buttons
    pinMode(PRIMARY_BUTTON_PIN, INPUT);
    pinMode(SECONDARY_BUTTON_PIN, INPUT);

    // Activate internal pull-ups
    digitalWrite(PRIMARY_BUTTON_PIN, HIGH);
    digitalWrite(SECONDARY_BUTTON_PIN, HIGH);
    
    // Send the sketch version information to the gateway and Controller
    sensor_node.sendSketchInfo(SKETCH_NAME, SKETCH_MAJOR_VER"."SKETCH_MINOR_VER);

    // Register binary input sensor to sensor_node (they will be created as child devices)
    // You can use S_DOOR, S_MOTION or S_LIGHT here depending on your usage. 
    // If S_LIGHT is used, remember to update variable type you send in. See "msg" above.
    sensor_node.present(PRIMARY_CHILD_ID, S_DOOR);  
    sensor_node.present(SECONDARY_CHILD_ID, S_DOOR);  
  }

  // Loop will iterate on changes on the BUTTON_PINs
  void loop() 
  {
    uint8_t value;
    static uint8_t sentValue=2;
    static uint8_t sentValue2=2;

    // Short delay to allow buttons to properly settle
    sensor_node.sleep(5);
    
    value = digitalRead(PRIMARY_BUTTON_PIN);
    
    if (value != sentValue) {
       // Value has changed from last transmission, send the updated value
       sensor_node.send(msg.set(value==HIGH ? 1 : 0));
       sentValue = value;
    }

    value = digitalRead(SECONDARY_BUTTON_PIN);
    
    if (value != sentValue2) {
       // Value has changed from last transmission, send the updated value
       sensor_node.send(msg2.set(value==HIGH ? 1 : 0));
       sentValue2 = value;
    }
    
    // Fuel gauge
    int batteryPcnt = fuelGauge.stateOfCharge();
    if (oldBatteryPcnt != batteryPcnt) 
    {
       sensor_node.sendBatteryLevel(batteryPcnt);
       oldBatteryPcnt = batteryPcnt;
     }
   
    // Sleep until something happens with the sensor
    sensor_node.sleep(PRIMARY_BUTTON_PIN-2, CHANGE, SECONDARY_BUTTON_PIN-2, CHANGE, 0);
  }

[hek]

@algoritm said:

TP4056

Ok, need to have one of these to play with myself.

We should probably have an example of using it distributed with the MySensors library. Might steal something from the code posted here.

[algoritm]

@hek They are great and very cheap. Just make sure you get the latest version of the board (the one with the micro-usb). 10pcs for $7 on Ebay.

[hek]

@algoritm

But the one you linked didn't have any I2C interface. How about this?
http://www.ebay.com.au/itm/Detection-Alarm-Module-A-D-Conversion-IIC-MAX17043-New-LiPo-Fuel-Gauge-Battery-/400749711661?

[algoritm]

@hek The TP4056 is the charger module. I didn't know you meant the fuel gauge. They are two separate boards which I solder together to one part.

[Paul Augusto]

2 part video showing how to tie the TP4056 and MAX17043 boards together and to an arduino pro mini.
Part 1:
MAX17043 LiPo Fuel Gauge connects to Arduino via I2C #1 – 09:07
— Julian Ilett

Part 2:
MAX17043 LiPo Fuel Gauge connects to Arduino via I2C #2 – 07:29
— Julian Ilett