Temp Humidity sensor only showing humidity in HA



  • Good day,

    I've created a temperature/humidity sensor using a DHT22. My gateway is a nESP8266 MQTT. I have HA installed in a docker container on my OpenMediaVault server. I'm seeing the sensor populate automatically in the 'Entities' section of HA, unfortunately I'm only seeing the humidity node and not the temp node.

    Below is my sensor sketch, it's mostly stock. I've tried manually defining the node id but that didn't seem to change anything, other than the 'child id' in HA. I also renamed it to 'Greenhouse' just to see if it would update HA. I've tried with persistance on and off, but maybe there is still some bogus data in a pickle file? I'm not really sure how those work.

    Can anyone spot anything in the sketch that would prevent HA from publishing the temperature node? I don't get any errors in the HA logs, and I can see both values being published through MQTT:
    b550b32d-ad44-491c-a08d-315a54d63658-image.png

    /**
     * The MySensors Arduino library handles the wireless radio link and protocol
     * between your home built sensors/actuators and HA controller of choice.
     * The sensors forms a self healing radio network with optional repeaters. Each
     * repeater and gateway builds a routing tables in EEPROM which keeps track of the
     * network topology allowing messages to be routed to nodes.
     *
     * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
     * Copyright (C) 2013-2015 Sensnology AB
     * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
     *
     * Documentation: http://www.mysensors.org
     * Support Forum: http://forum.mysensors.org
     *
     * This program is free software; you can redistribute it and/or
     * modify it under the terms of the GNU General Public License
     * version 2 as published by the Free Software Foundation.
     *
     *******************************
     *
     * REVISION HISTORY
     * Version 1.0: Henrik EKblad
     * Version 1.1 - 2016-07-20: Converted to MySensors v2.0 and added various improvements - Torben Woltjen (mozzbozz)
     * 
     * DESCRIPTION
     * This sketch provides an example of how to implement a humidity/temperature
     * sensor using a DHT11/DHT-22.
     *  
     * For more information, please visit:
     * http://www.mysensors.org/build/humidity
     * 
     */
    
    // Enable debug prints
    #define MY_DEBUG
    
    // Enable and select radio type attached 
    #define MY_RADIO_RF24
    //#define MY_RADIO_RFM69
    //#define MY_RS485
    
    
     
    #include <SPI.h>
    #include <MySensors.h>  
    #include <DHT.h>
    
    // Set this to the pin you connected the DHT's data pin to
    #define DHT_DATA_PIN 3
    
    // Set this offset if the sensor has a permanent small offset to the real temperatures.
    // In Celsius degrees (as measured by the device)
    #define SENSOR_TEMP_OFFSET 0
    
    // Sleep time between sensor updates (in milliseconds)
    // Must be >1000ms for DHT22 and >2000ms for DHT11
    static const uint64_t UPDATE_INTERVAL = 60000;
    
    // Force sending an update of the temperature after n sensor reads, so a controller showing the
    // timestamp of the last update doesn't show something like 3 hours in the unlikely case, that
    // the value didn't change since;
    // i.e. the sensor would force sending an update every UPDATE_INTERVAL*FORCE_UPDATE_N_READS [ms]
    static const uint8_t FORCE_UPDATE_N_READS = 10;
    
    // Set node id for MQTT
    #define MY_NODE_ID 2
    #define CHILD_ID_HUM 2
    #define CHILD_ID_TEMP 1
    
    float lastTemp;
    float lastHum;
    uint8_t nNoUpdatesTemp;
    uint8_t nNoUpdatesHum;
    bool metric = true;
    
    MyMessage msgHum(CHILD_ID_HUM, V_HUM);
    MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
    DHT dht;
    
    
    void presentation()  
    { 
      // Send the sketch version information to the gateway
      sendSketchInfo("Greenhouse", "1.1");
      
      // Register all sensors to gw (they will be created as child devices)
      present(CHILD_ID_HUM, S_HUM);
      present(CHILD_ID_TEMP, S_TEMP);
      
      metric = getControllerConfig().isMetric;
    }
    
    
    void setup()
    {
      dht.setup(DHT_DATA_PIN); // set data pin of DHT sensor
      if (UPDATE_INTERVAL <= dht.getMinimumSamplingPeriod()) {
        Serial.println("Warning: UPDATE_INTERVAL is smaller than supported by the sensor!");
      }
      // Sleep for the time of the minimum sampling period to give the sensor time to power up
      // (otherwise, timeout errors might occure for the first reading)
      sleep(dht.getMinimumSamplingPeriod());
    }
    
    
    void loop()      
    {  
      // Force reading sensor, so it works also after sleep()
      dht.readSensor(true);
      
      // Get temperature from DHT library
      float temperature = dht.getTemperature();
      if (isnan(temperature)) {
        Serial.println("Failed reading temperature from DHT!");
      } else if (temperature != lastTemp || nNoUpdatesTemp == FORCE_UPDATE_N_READS) {
        // Only send temperature if it changed since the last measurement or if we didn't send an update for n times
        lastTemp = temperature;
    
        // apply the offset before converting to something different than Celsius degrees
        temperature += SENSOR_TEMP_OFFSET;
    
        if (!metric) {
          temperature = dht.toFahrenheit(temperature);
        }
        // Reset no updates counter
        nNoUpdatesTemp = 0;
        send(msgTemp.set(temperature, 1));
    
        #ifdef MY_DEBUG
        Serial.print("T: ");
        Serial.println(temperature);
        #endif
      } else {
        // Increase no update counter if the temperature stayed the same
        nNoUpdatesTemp++;
      }
    
      // Get humidity from DHT library
      float humidity = dht.getHumidity();
      if (isnan(humidity)) {
        Serial.println("Failed reading humidity from sDHT");
      } else if (humidity != lastHum || nNoUpdatesHum == FORCE_UPDATE_N_READS) {
        // Only send humidity if it changed since the last measurement or if we didn't send an update for n times
        lastHum = humidity;
        // Reset no updates counter
        nNoUpdatesHum = 0;
        send(msgHum.set(humidity, 1));
        
        #ifdef MY_DEBUG
        Serial.print("H: ");
        Serial.println(humidity);
        #endif
      } else {
        // Increase no update counter if the humidity stayed the same
        nNoUpdatesHum++;
      }
    
      // Sleep for a while to save energy
      sleep(UPDATE_INTERVAL); 
    }
    

    Thanks very much!



  • The IDs for humidity and temperature shown on the HA screenshot and written in the sketch don't match up.

    It looks like you have already presented the sensor node with different child IDs before and HA is still expecting the previous configuration. If you reassign an existing ID to a different type (say, S_HUM to S_TEMP), HA won't update automatically.

    I would suggest doing the following:

    • Power down your sensor node and shutdown the HA docker
    • Delete the existing .pickle persistance file, which may still contain the previous node configuration
    • Edit configuration.yaml and change the file type of the persistance file from .pickle to .json, because it's human readable (and editable).
    • You may also enable debug logging temporarily to get more info about what's happening when a node sends data
    • Restart HA and once the MySensors integration has finished initialization, power up the sensor node again

    If you don't change the current sketch, temperature should show up with the ID 1 and humidity with the ID 2 in HA. I can't spot anything wrong with it.

    If it still doesn't work, have a look at the HA log, e.g. with journalctl -u your-ha.service -f -n 100 | grep mysensors

    You should see that messages are incoming from the sensor node (ID 2) including the sketch name and values for every sensor, that HA subscribes to a MQTT topic for every sensor ID and that HA has saved changes to the persistante.json file.


Log in to reply
 

Suggested Topics

  • 12
  • 5
  • 18
  • 8
  • 3
  • 2
  • 5

174
Online

9.4k
Users

10.0k
Topics

104.4k
Posts