gw.sleep on battery powered magnet door switch

172pilot

@AWI I was going to ask about that.. I dont see any reason to wake up every 24 hours just to go back to sleep again.. I assume the radio doesn't have any reason to send a keepalive or anything? So, you can omit that number, and it will sleep until interrupted? That's cool..

-Steve

AWI

@172pilot yes, no reason to wake up. Especially if there is a regular wake-up from interrupt to let the controller know it it is alive

Chakkie

@AWI

Thanks for the info. I thought you always have to add the sleep time to the gw.sleep. I will disable the a wake timer by removing the 86400000.

@siod I use one switch for the letterbox and one for the door.

siod

well, as you can see, if you don´t know the libraries exactly you accept things as they are or as they seem to be. I wasn´t aware that you can just set the wakeup function to 0. So this said I would like to thank you @AWI for your patience and your willingness of explaining also the most obvious things! :thumbsup:

treb0r

The sketch works with both reeds switches (2 windows) but how to integreate it with DS18B20 temp sensor? I also power it with battery, so I would like to check the temp eg every 5min and if it is changed then send the new value to the controler. How to wake up arduino only if any window is opened or temp is changed (after 5 min)
Thanks
treb0r

dynamite

@treb0r You can either wake up on the interrupt or on a time period:

bool sleep(int interrupt, int mode, unsigned long ms=0);

interrupt - Interrupt that should trigger the wakeup.
mode - RISING, FALLING, CHANGE
ms - Number of milliseconds to sleep (or 0 to sleep forever).

The sleep method returns true if wake up was triggered by pin change and false means timer woke it up.

172pilot

@treb0r the problem is, you need to wake up the arduino to tell the temp sensor to take a new reading, so the best you can do is to trigger on the interrupts for the Windows and then use the timer to wake up and take the temperature reading, and then you'll have to compare to your saved value to decide whether it has been 5 degrees or not, so you can't completely sleep until that happens..

siod

Hi guys,

unfortunately I have to answer again to this topic because I don´t get my nodes work longer then up to two weeks. I guess it is still a sleep function problem and the problem persits though I am usin ver 2.0 now. Please have a look at my code, any hint is very appreciated!!

I have attached 2 reed switches which should trigger a wakeup and one Hum/Temp Sensor is attached, too. I would like the device to send temp/hum measurements every 15 minutes, what works, but only for a few days or so. Then I also send battery level, that´s all.

I have 3 devices up and running right now, they all fail once in while...

// Sensor Node Schlafzimmer mit HTU21D Temp/Hum Sensor, Fensterkontakte an Interrupt PINS Digital 5&6. Sleep Time 15 Minutwn, wake up wenn Fenster geöffnet/geschlossen wird.
#define MY_RADIO_NRF24 //MySensor Library auf NRF24 Funkmodul einstellen, muss vor MySensor.h Initialisierung geschehen
// Define Node ID
#define MY_NODE_ID 200

//Batterysensor
int BATTERY_SENSE_PIN = A0;  // select the input pin for the battery sense point
int oldBatteryPcnt = 0;
#define CHILD_ID_BATT 7

//Kontaktschalter
//#include <Bounce2.h>
#define CHILD1_ID 1 // Kontaktschalter 1
#define CHILD2_ID 2 // Kontaktschalter 2
#define BUTTON1_PIN  2  // Kontaktschalter 1
#define BUTTON2_PIN  3  // Kontaktschalter 2
int oldValueReed1=-1;
int oldValueReed2=-1;

//Tempsensor
#include <SparkFunHTU21D.h>
#include <Wire.h>
#define CHILD_ID_HUM 3
#define CHILD_ID_TEMP 4
unsigned long SLEEP_TIME = 900000; // Sleep time between reads (in milliseconds)

#include <MySensors.h>
#include <SPI.h>

//tempsensor
HTU21D myHumidity;
float lastTemp;
float lastHum;
//boolean metric = true; 

//Messages
//Battery
MyMessage msgbatt(CHILD_ID_BATT,V_VOLTAGE);
// Kontaktschalter
MyMessage msgReed1(CHILD1_ID,V_TRIPPED); // Kontaktschalter 1
MyMessage msgReed2(CHILD2_ID,V_TRIPPED); // Kontaktschalter 2
//TempMessage
MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);

//Presentation; present sensors to gateway!
void presentation(){
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo("Schlafzimmer Messstation", "2.0");
    
  // Register binary input sensor to gw (they will be created as child devices)
  // You can use S_DOOR, S_MOTION or S_LIGHT here depending on your usage. 
  // If S_LIGHT is used, remember to update variable type you send in. See "msg" above.
  present(CHILD1_ID, S_DOOR); 
  present(CHILD2_ID, S_DOOR); 
    
  //Tempsensor
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP); 
  //metric = getConfig().isMetric;

  //Battery
  present(CHILD_ID_BATT,V_VOLTAGE);
}

//Setup
void setup()  
{  
  //Serial.begin(9600);
  Serial.println("Hello!");
  //Batterysensor
     // use the 1.1 V internal reference
#if defined(__AVR_ATmega2560__)
   analogReference(INTERNAL1V1);
#else
   analogReference(INTERNAL);
#endif

//Tempsensor
  Serial.println("Setting up TempSensor...");
  myHumidity.begin();
  Serial.println("...done!");

// Setup Kontaktschalter 1
  pinMode(BUTTON1_PIN,INPUT);
    // Activate internal pull-up
  digitalWrite(BUTTON1_PIN,HIGH);
// Setup Kontaktschalter 2
  pinMode(BUTTON2_PIN,INPUT);
  // Activate internal pull-up
  digitalWrite(BUTTON2_PIN,HIGH);
}

//Starte den Loop
void loop() 
{
  //Batterysensor
  // get the battery Voltage
  delay(1000);
   int sensorValue = analogRead(BATTERY_SENSE_PIN);
   #ifdef DEBUG
   #endif
   
   // 1M, 470K divider across battery and using internal ADC ref of 1.1V
   // Sense point is bypassed with 0.1 uF cap to reduce noise at that point
   // ((1e6+470e3)/470e3)*1.1 = Vmax = 3.44 Volts
   // 3.44/1023 = Volts per bit = 0.003363075
   float batteryV  = sensorValue * 0.003363075;
   int batteryPcnt = sensorValue / 10;

   #ifdef DEBUG
   Serial.print("Battery Voltage: ");
   Serial.print(batteryV);
   Serial.println(" V");

   Serial.print("Battery percent: ");
   Serial.print(batteryPcnt);
   Serial.println(" %");
   #endif

   if (oldBatteryPcnt != batteryPcnt) {
     // Power up radio after sleep
     sendBatteryLevel(batteryPcnt);
     send(msgbatt.set(batteryPcnt));
     oldBatteryPcnt = batteryPcnt;
   }
   
  //Kontakstschalter 1
   // Short delay to allow buttons to properly settle
  sleep(10);
  // Get the update value
  int valueReed1 = digitalRead(BUTTON1_PIN);
 
  if (valueReed1 != oldValueReed1) {
     // Send in the new value
     send(msgReed1.set(valueReed1==HIGH ? 1 : 0));
     Serial.println("Button 1 geschaltet");
     oldValueReed1 = valueReed1;
  }
  //Kontakstschalter 2
  // Get the update value
  int valueReed2 = digitalRead(BUTTON2_PIN);
 
  if (valueReed2 != oldValueReed2) {
     // Send in the new value
     send(msgReed2.set(valueReed2==HIGH ? 1 : 0));
     Serial.println("Button 2 geschaltet");
     oldValueReed2 = valueReed2;
  }
 
 //Tempsensor
Serial.println("Starte Messung...");
  
    float temp = myHumidity.readTemperature();

  if (isnan(temp)) {
      Serial.println("Failed reading temperature from DHT");
  } else if (temp != lastTemp) {
    lastTemp = temp;
    send(msgTemp.set(temp, 1));
    Serial.print("T: ");
    Serial.println(temp);
  }
  
 float humd = myHumidity.readHumidity();
  if (isnan(humd)) {
      Serial.println("Failed reading humidity from DHT");
  } else if (humd != lastHum) {
      lastHum = humd;
      send(msgHum.set(humd, 1));
      Serial.print("H: ");
      Serial.println(humd);
  }

 Serial.println("Sleep...");
 sleep(BUTTON1_PIN - 2, CHANGE, BUTTON2_PIN - 2, CHANGE, SLEEP_TIME); //sleep a bit 
  
}

sling

@siod

I'm assuming your batteries are empty when you say fail ?
I built 5 of these last week for my dads place.
I set internal pullups to LOW and soldered a 3,3MOhm resistor between VCC and Pin2.
I'm seeing around 30µA when sleeping on two fresh AA batteries.
With internal pullups that would be around 1ma and that would indeed drain the batteries quite fast.

siod

no Sir, batteries are still at around 90% charged.

Nicklas Starkel

@siod , I had the same problem.
I actually ordered a original NRF 24 mini and this seemed to solve some of my problems.
i think another problem I'm having is that my batteries has a huge self discharge (old 3.7v 18650)

On a side note.. I'm with @sling .
Loose the pullups and set them LOW´.
I have a 1MOhm resistor between VCC and PIN 2 and PIN 3 (also 2 switches).
Using the pullup HIGH draws around 130uA versus LOW it draws between 7 to 10uA!

siod

No gentlemen, I don´t think it is a battery problem, maybe a radio problem, but not a battery problem.

But my sketch seems to be ok?

Nca78

@Nicklas-Starkel said:

@siod , I had the same problem.
I actually ordered a original NRF 24 mini and this seemed to solve some of my problems.
i think another problem I'm having is that my batteries has a huge self discharge (old 3.7v 18650)

On a side note.. I'm with @sling .
Loose the pullups and set them LOW´.
I have a 1MOhm resistor between VCC and PIN 2 and PIN 3 (also 2 switches).
Using the pullup HIGH draws around 130uA versus LOW it draws between 7 to 10uA!

That's the best solution with a normal reed switch.
But the best way is to use a "double" reed switch, with both normally opened and normally closed contacts. I use that connected between GND and pin 2 & 3 and set only the unconnected pin to high (so, with pullup). Current will flow only a very short time through the pullup while the node is waking up from sleep, then first thing I do is set connected input low. So nearly 100% of the time input is not connected and current through the reed switch is 0.
I've put a test node on my entrance door, it's been running for over 3 months on a CR2032 cell and has lost only 0.02V meaning it will last at least 2 years, maybe 3.

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * DESCRIPTION
 *
 * Interrupt driven binary switch example with dual interrupts
 * Author: Patrick 'Anticimex' Fallberg
 * Connect one button or door/window reed switch between 
 * digitial I/O pin 3 (BUTTON_PIN below) and GND and the other
 * one in similar fashion on digital I/O pin 2.
 * This example is designed to fit Arduino Nano/Pro Mini
 * 
 * NCA78: Updated to work with one dual normally open/normally closed reed switch on both interrupt pins.

 */


// Enable debug prints
//#define MY_DEBUG 

// Enable and select radio type attached
#define MY_RADIO_NRF24

#include <SPI.h>
#include <MyConfig.h>
#include <MySensors.h>
#include <SystemStatus.h>
#define SKETCH_NAME "NCA Door Sensor"
#define SKETCH_MAJOR_VER "0"
#define SKETCH_MINOR_VER "7"

#define PRIMARY_CHILD_ID 3

#define PRIMARY_BUTTON_PIN 2   // Arduino Digital I/O pin for button/reed switch
#define SECONDARY_BUTTON_PIN 3 // Arduino Digital I/O pin for button/reed switch

#if (PRIMARY_BUTTON_PIN < 2 || PRIMARY_BUTTON_PIN > 3)
#error PRIMARY_BUTTON_PIN must be either 2 or 3 for interrupts to work
#endif
#if (SECONDARY_BUTTON_PIN < 2 || SECONDARY_BUTTON_PIN > 3)
#error SECONDARY_BUTTON_PIN must be either 2 or 3 for interrupts to work
#endif
#if (PRIMARY_BUTTON_PIN == SECONDARY_BUTTON_PIN)
#error PRIMARY_BUTTON_PIN and BUTTON_PIN2 cannot be the same
#endif
#if (PRIMARY_CHILD_ID == SECONDARY_CHILD_ID)
#error PRIMARY_CHILD_ID and SECONDARY_CHILD_ID cannot be the same
#endif

#define MY_PARENT_NODE_ID 0
 

// Change to V_LIGHT if you use S_LIGHT in presentation below
MyMessage msg(PRIMARY_CHILD_ID, V_TRIPPED);
//MyMessage msg2(SECONDARY_CHILD_ID, V_TRIPPED);


// Parameters for VCC measurement
const int VccMin        = 2000;  // Minimum expected Vcc level, in Volts. At 2V the cell should be dead
const int VccMax        = 2900;  // Maximum expected Vcc level, in Volts.
SystemStatus vcc();
int LastBatteryPercent = 200; // so we are sure to send the battery level at first check
bool isEven = false; // to check+send battery level only for each open+close cycles

bool revertValue = false;  // to change this put a jumper on D4/D7 and it is tested at startup


// This is the activated pin, on which the interrupt is set
byte connectedPin = PRIMARY_BUTTON_PIN;
byte connectedPinAtLastSending = 0; // Initialized at 0 so we will always send the first time

void setup()  
{  
  // First thing to do: change clock prescaling to 8 to change from 8MHz to 1MHz
  //  of course not necessary if you already have updated fuses and bootloader...
  #ifndef MY_DEBUG           // only if we are not in debug mode, so we can keep the fast baudrate in debug
    clock_prescale_set (clock_div_8);   
  #endif

  
  
}

void presentation() {
  sleep(250); // sleep to let capacitor recharge a bit
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo(SKETCH_NAME, SKETCH_MAJOR_VER "." SKETCH_MINOR_VER);
  sleep(250); // sleep to let capacitor recharge a bit
  // Register binary input sensor to sensor_node (they will be created as child devices)
  present(PRIMARY_CHILD_ID, S_DOOR);
  sleep(250); // sleep to let capacitor recharge a bit
}

// Loop will iterate on changes on the BUTTON_PINs
void loop() 
{
  // Short delay to allow buttons to properly settle
  sleep(5);

  deActivatePin(PRIMARY_BUTTON_PIN);
  deActivatePin(SECONDARY_BUTTON_PIN);

  // Check if the previously connected pin is now connected. We do that because it's the most likely to be unconnected now
  //  so it's the best way not to lose any current
  byte newConnectedPin = GetNonConnectedPin();
  if (checkPinIsConnected(connectedPin)) {
    // If pin is still connected we set back the value to connected pin
    newConnectedPin = connectedPin;
    #ifdef MY_DEBUG
      Serial.println("Connected pin is connected !");
    #endif
    
  }
  connectedPin = newConnectedPin;
  // If connected pin is different that the one during the last sending of status, we send again
  #ifdef MY_DEBUG
    Serial.print("Connected pin = ");
    Serial.println(connectedPin);
    Serial.print("New Connected pin = ");
    Serial.println(newConnectedPin);
  #endif
  
  if (connectedPin != connectedPinAtLastSending) {
     // Value has changed from last transmission, send the updated value
     send(msg.set(connectedPin==PRIMARY_BUTTON_PIN ? (revertValue ? 0 : 1) : (revertValue ? 1 : 0)));
     connectedPinAtLastSending = connectedPin;
     isEven = !isEven;
  }
  
  if (isEven) {  // send only every two changes for a full open + close cycle
    int currentBatteryPercent = SystemStatus().getVCCPercent(VccMin, VccMax);
    if (currentBatteryPercent != LastBatteryPercent) {
        sleep(100); // sleep 100ms (+65ms wake up time) to let capacitor recharge a bit
        LastBatteryPercent = currentBatteryPercent;
        sendBatteryLevel(currentBatteryPercent);
    }
  }

  #ifdef MY_DEBUG
    Serial.print("Preparing to sleep, pin ");
    Serial.println(GetNonConnectedPin());
    wait(50);
  #endif

  // Activate the non connected pin before setting up interrupt
  activatePin(GetNonConnectedPin());    
  // Sleep until something happens with the door sensor
  sleep(GetNonConnectedPin()-2, CHANGE);
} 

void activatePin(byte pin) {
  // Set pin as input
  pinMode(pin, INPUT);
  // Activate internal pull up
  digitalWrite(pin, HIGH);
}

void deActivatePin(byte pin) {
  // Set back pin as output, low
  pinMode(pin, OUTPUT);
  digitalWrite(pin, LOW);
}

// Will check if pin is grounded (returns true) or not
boolean checkPinIsConnected(byte pin) {
  activatePin(pin);

  // Read value
  byte valPin = digitalRead(pin);
  deActivatePin(pin);

  #ifdef MY_DEBUG
    Serial.print("checkPinIsConnected pin = ");
    Serial.print(pin);
    Serial.print(", value = ");
    Serial.println(valPin);
  #endif
  
  return valPin != HIGH;
}

// Returns the pin that is not connected
byte GetNonConnectedPin() {
  return (connectedPin == PRIMARY_BUTTON_PIN) ? SECONDARY_BUTTON_PIN : PRIMARY_BUTTON_PIN;
}

https://www.aliexpress.com/item/20pcs-lot-3-pin-Reed-Switch-2-5X14MM-GLASS-Green-3-pin-Normally-Open-and-Normally/32507762756.html?spm=2114.13010608.0.0.4LJb9I

siod

Ok guys you convinced me, I will set them LOW instead of HIGH.

Correct?

I just did it the way described here: https://www.mysensors.org/build/binary
There is nothing abaout any resistor...

But will this solve my problem? I am not sure. I had the feeling that the sensors won´t wake up from sleep or so...

LastSamurai

I would be interested too as I have some battery problems with my reed switches too. I guess its VCC | Reed Switch | GND and Reed Switch |1M Ohm Resistor | inputpin, right?

Nicklas Starkel

@siod and @LastSamurai
Connect the REED Switch with one leg to GND and the other leg to PIN2.
And then you put a 1MOhm resistor between VCC and PIN2.

dbemowsk

@siod
@Nicklas-Starkel said:

put a 1MOhm resistor between VCC and PIN2.

This is used as a pull-up resistor to keep the signal to PIN2 active HIGH until the reed switch is closed.

I have never tested and don't know how much of a difference it would make, but you can do the reverse of that too and connect it like this:
GND -- 1MOhm -- PIN2 -- Reed Switch -- VCC

With this setup PIN2 would stay active LOW and in your code you would check to see if it goes HIGH for the switch contact. My thought is that doing it with the resistor to VCC from PIN2, which would be active HIGH, would use a slight bit more power than keeping it active LOW with the resistor from PIN2 to GND . As I said, I have never tested this, so I may be wrong.

sling

@siod

new observation: I have two temp nodes with red Htu21d in them. One keeps locking up randomly. Have to go outside and reset the arduino. I'll try another sensor today and see if it fixes things. Have completely rebuild the node twice now with new parts except the sensor.

gw.sleep on battery powered magnet door switch

19

11.7k

11.2k

113.1k