💬 Sonoff relay using MySensors ESP8266 wifi or mqtt gateway

[AndrewZ]

With all my respect to the project and people behind it I believe that MQTT is more widely used than MySensors. So for me it would be more logical to add another MQTT client to the network rather than introduce any additional gateway. Just my 2¢.

[Jan Gatzke]

@AndrewZ

This is not really a gateway. You can use the esp8266 gateway sketch, disable the nrf24 / rfm69 and directly attach sensors. So basically it's an relay actuator which is configured as a mysensors gateway.

[NeverDie]

I think what's throwing everybody off is applying the word "gateway" to this sonoff device. Wouldn't it make more sense to have it remain a relay actuator (i.e. just a node) and to have the mysensors gateway be something else (of which there are many examples on this website)? i.e. it makes more sense to have it be a mysensors node (or MQTT node if that's your architecture) than to have it be a mysensors gateway. Wouldn't it?

[Efflon]

This is not listed as a gateway but under sensors & actuators but maybe a "s/and/relay using" would be a fix of the headline. I selected the mqtt gateway example just because I have a few other NodeMCU's working as just MYS sensors with no radio but it's trivial to just re-use code for any of the other gateways, as you all know. I choose the mqtt addition just for fun and know there are other mqtt examples but nothing working out of the box with my HASS + MYS + mqtt setup. Regarding the gateway naming, at least I don't know any other way of using MYS and ESP8266 than using the gateway sketches with a disabled radio. What should they be called, just node? At the same time, adding a radio to the Sonoff and it's a gateway...

[danbi]

Maybe a good solution to the node/gateway dilemma is adding WiFi transport for nodes to MySensors? Then defining one or more WiFi gateways to connect sensors to. You could then use WiFi enabled devices, such as ESP8266 as sensor nodes. You could use these as radio interfaces to Arduino nodes, with their original serial-to-WiFi firmware and treat it much like the RS485 transport.

[NeverDie]

@danbi
Yup. It's either that or do the MQTT thing (which, personally, I favor, though right now it's a minority opinion) like AndrewZ said.

[Jan Gatzke]

I don't see the problem here. An direct ip connection between the controller and the node is perfect for critical nodes as less components mean less things that can fail. I have flashed a Sonoff Touch switch with the esp8266 gateway sketch and it is running just fine. Or am I missing something?

[Efflon]

@Jan-Gatzke What code modifications have you done to get the touch buttons to work or do they work like "normal" buttons? I really like the built-in form factor and was thinking about ordering a few.

[Jan Gatzke]

@Efflon

All the touch stuff is handheld by an ic. You can use it like an normal button, active low. It is connected to pin 0. I have made a two way switch of it. With a long press I cycle through multiple scenes which control the color of my tv's led light. With a even longer press I can switch the tv light off. I can share the code when I found the time to clean it up.

I like the OTA update function of the esp very much. It's much simpler than the rf24/ Arduino solution. My sketch provides a browser based update function with just 5 lines of code. This was important to me because I don't want to get my switches out off the wall for every update. For the eu version of the sonoff this is mandatory because the programming header does not fit when the device is mounted.

[Efflon]

@Jan-Gatzke Excelletn info, thanks! Yes, please share your code , the state doesn't matter for me at least

[Jan Gatzke]

@Efflon

Ok, I just wiped out (hopefully) all my passwords and IP information.

/**
   The MySensors Arduino library handles the wireless radio link and protocol
   between your home built sensors/actuators and HA controller of choice.
   The sensors forms a self healing radio network with optional repeaters. Each
   repeater and gateway builds a routing tables in EEPROM which keeps track of the
   network topology allowing messages to be routed to nodes.

   Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
   Copyright (C) 2013-2015 Sensnology AB
   Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors

   Documentation: http://www.mysensors.org
   Support Forum: http://forum.mysensors.org

   This program is free software; you can redistribute it and/or
   modify it under the terms of the GNU General Public License
   version 2 as published by the Free Software Foundation.

 *******************************

   REVISION HISTORY
   Version 1.0 - Henrik EKblad
   Contribution by a-lurker and Anticimex,
   Contribution by Norbert Truchsess <norbert.truchsess@t-online.de>
   Contribution by Ivo Pullens (ESP8266 support)

   DESCRIPTION
   The EthernetGateway sends data received from sensors to the WiFi link.
   The gateway also accepts input on ethernet interface, which is then sent out to the radio network.

   VERA CONFIGURATION:
   Enter "ip-number:port" in the ip-field of the Arduino GW device. This will temporarily override any serial configuration for the Vera plugin.
   E.g. If you want to use the defualt values in this sketch enter: 192.168.178.66:5003

   LED purposes:
   - To use the feature, uncomment WITH_LEDS_BLINKING in MyConfig.h
   - RX (green) - blink fast on radio message recieved. In inclusion mode will blink fast only on presentation recieved
   - TX (yellow) - blink fast on radio message transmitted. In inclusion mode will blink slowly
   - ERR (red) - fast blink on error during transmission error or recieve crc error

   See http://www.mysensors.org/build/esp8266_gateway for wiring instructions.
   nRF24L01+  ESP8266
   VCC        VCC
   CE         GPIO4
   CSN/CS     GPIO15
   SCK        GPIO14
   MISO       GPIO12
   MOSI       GPIO13
   GND        GND

   Not all ESP8266 modules have all pins available on their external interface.
   This code has been tested on an ESP-12 module.
   The ESP8266 requires a certain pin configuration to download code, and another one to run code:
   - Connect REST (reset) via 10K pullup resistor to VCC, and via switch to GND ('reset switch')
   - Connect GPIO15 via 10K pulldown resistor to GND
   - Connect CH_PD via 10K resistor to VCC
   - Connect GPIO2 via 10K resistor to VCC
   - Connect GPIO0 via 10K resistor to VCC, and via switch to GND ('bootload switch')

    Inclusion mode button:
   - Connect GPIO5 via switch to GND ('inclusion switch')

   Hardware SHA204 signing is currently not supported!

   Make sure to fill in your ssid and WiFi password below for ssid & pass.
*/

#include <SPI.h>

// Enable debug prints to serial monitor
#define MY_DEBUG

// Use a bit lower baudrate for serial prints on ESP8266 than default in MyConfig.h
#define MY_BAUD_RATE 9600

// Enables and select radio type (if attached)
//#define MY_RADIO_NRF24
//#define MY_RADIO_RFM69

#define MY_GATEWAY_ESP8266

#define MY_ESP8266_SSID "MySSID"
#define MY_ESP8266_PASSWORD "MyPSK"

// Enable UDP communication
//#define MY_USE_UDP

// Set the hostname for the WiFi Client. This is the hostname
// it will pass to the DHCP server if not static.
// #define MY_ESP8266_HOSTNAME "sensor-gateway"

// Enable MY_IP_ADDRESS here if you want a static ip address (no DHCP)
#define MY_IP_ADDRESS 192,168,1,200

// If using static ip you need to define Gateway and Subnet address as well
#define MY_IP_GATEWAY_ADDRESS 192,168,1,254
#define MY_IP_SUBNET_ADDRESS 255,255,255,0

// The port to keep open on node server mode
#define MY_PORT 5003

// How many clients should be able to connect to this gateway (default 1)
#define MY_GATEWAY_MAX_CLIENTS 2

// Controller ip address. Enables client mode (default is "server" mode).
// Also enable this if MY_USE_UDP is used and you want sensor data sent somewhere.
//#define MY_CONTROLLER_IP_ADDRESS 192, 168, 178, 68

// Enable inclusion mode
//#define MY_INCLUSION_MODE_FEATURE

// Enable Inclusion mode button on gateway
// #define MY_INCLUSION_BUTTON_FEATURE
// Set inclusion mode duration (in seconds)
//#define MY_INCLUSION_MODE_DURATION 60
// Digital pin used for inclusion mode button
//#define MY_INCLUSION_MODE_BUTTON_PIN  3


// Flash leds on rx/tx/err
// #define MY_LEDS_BLINKING_FEATURE
// Set blinking period
// #define MY_DEFAULT_LED_BLINK_PERIOD 300

// Led pins used if blinking feature is enabled above
//#define MY_DEFAULT_ERR_LED_PIN 16  // Error led pin
//#define MY_DEFAULT_RX_LED_PIN  16  // Receive led pin
//#define MY_DEFAULT_TX_LED_PIN  16  // the PCB, on board LED

#if defined(MY_USE_UDP)
#include <WiFiUDP.h>
#else
#include <ESP8266WiFi.h>
#endif

#include <WiFiClient.h>
#include <ESP8266WebServer.h>
#include <ESP8266mDNS.h>
#include <ESP8266HTTPUpdateServer.h>


#include <MySensors.h>

#define RELAY_1_Pin  12
#define LED_1_Pin 13
#define TOUCH_1_Pin 0

#define RELAY_1  1
#define TOUCH_1 3
#define TOUCH_2 4

boolean relayon = false;
int activescene = 1;

volatile unsigned long LastChange = 0;
volatile boolean RelayToggleRequired = false;
volatile boolean SceneSwitchRequired = false;
volatile boolean SceneSwitchTriggeredByTimeout = false;
volatile boolean SceneSwitchTriggeredByTimeout2 = false;

MyMessage msg(RELAY_1, V_LIGHT);
MyMessage msg1(TOUCH_1, V_SCENE_ON);
MyMessage msg2(TOUCH_2, V_LIGHT);

ESP8266WebServer httpServer(80);
ESP8266HTTPUpdateServer httpUpdater;
const char* host = "sonofftouch1";
const char* location = "Couch";
char* update_username = "admin";        //Benutzername zum login für die OTA-Programmierung
char* update_password = "MyPassword";      //Passwort
String webPage = "";

unsigned long lastheartbeat = 0;


void buttonChangeCallback() {
  if (digitalRead(TOUCH_1_Pin) == 1) {
    //LED off for feedback
    digitalWrite(LED_1_Pin, 1);
    //Button has been released, trigger one of the two possible options.
    if (millis() - LastChange > 500) {
      //Long Press
      if (!SceneSwitchTriggeredByTimeout) {
        SceneSwitchRequired = true;
      }
    }
    else if (millis() - LastChange > 50) {
      //Short press at least 50 ms for debounce
      RelayToggleRequired = true;
    }
    else {
      //Too short to register as a press
    }
  }
  else {
    //LED on for feedback
    digitalWrite(LED_1_Pin, 0);
    //Just been pressed - do nothing until released.
  }
  LastChange = millis();
  SceneSwitchTriggeredByTimeout = false;
  SceneSwitchTriggeredByTimeout2 = false;
}



void setup() {
  webPage += "<h1>ESP8266 Web Server</h1>";
  webPage += "<br><h1>";
  webPage += host;
  webPage += "</h1>";
  webPage += "<br><h1>";
  webPage += location;
  webPage += "</h1>";
  webPage += "<br><a href=/update>Click here to update</a>";
  pinMode(TOUCH_1_Pin, INPUT_PULLUP);      // sets the digital pin as output
  pinMode(RELAY_1_Pin, OUTPUT);
  pinMode(LED_1_Pin, OUTPUT);
  //LED off
  digitalWrite(LED_1_Pin, 1);

  MDNS.begin(host);
  httpUpdater.setup(&httpServer, "/update", update_username, update_password);
  httpServer.begin();
  MDNS.addService("http", "tcp", 80);
  httpServer.on("/", []() {
    httpServer.send(200, "text/html", webPage);
  });
  Serial.println("Enabling touch switch interrupt");
  attachInterrupt(digitalPinToInterrupt(TOUCH_1_Pin), buttonChangeCallback, CHANGE);
}

void presentation() {
  // Send the sketch version information to the gateway and Controller
  sendSketchInfo("Sonoff Touch Mysensors", "1.0");
  present(RELAY_1, S_LIGHT, "single click/onboard relay");
  present(TOUCH_1, S_SCENE_CONTROLLER, "double click/scene controller");
  present(TOUCH_2, S_LIGHT, "long press virtuel switch");
}


void loop() {
  httpServer.handleClient();
  if (millis() - lastheartbeat > 30000) {
    //sendHeartbeat();
    sendBatteryLevel(90);
    lastheartbeat = millis();
  }

  if (RelayToggleRequired) {
    ToggleRelay();
    RelayToggleRequired = false;
  }

  if (SceneSwitchRequired) {
    SwitchScene();
    SceneSwitchRequired = false;
  }

  if (millis() - LastChange > 600) {
    if (digitalRead(TOUCH_1_Pin) == 0) {
      if (SceneSwitchTriggeredByTimeout == false) {
        SceneSwitchTriggeredByTimeout = true;
        SwitchScene();
      }
    }
  }

  if (millis() - LastChange > 3000) {
    if (digitalRead(TOUCH_1_Pin) == 0) {
      if (SceneSwitchTriggeredByTimeout2 == false) {
        SceneSwitchTriggeredByTimeout2 = true;
        SwitchSceneOff();
      }
    }
  }
}

void receive(const MyMessage &message) {
  // We only expect one type of message from controller. But we better check anyway.
  if (message.type == V_LIGHT) {
    // Change relay state
    if (message.sensor == RELAY_1) {
      digitalWrite(RELAY_1_Pin, message.getBool() ? 1 : 0);
      relayon = message.getBool() ? 1 : 0;
    }
    // Write some debug info
    Serial.print("Incoming change for sensor:");
    Serial.print(message.sensor);
    Serial.print(", New status: ");
    Serial.println(message.getBool());
  }
}

void ToggleRelay() {
  Serial.println("Single Click");
  if (relayon) {
    digitalWrite(RELAY_1_Pin, 0);
    relayon = false;
  }
  else {
    digitalWrite(RELAY_1_Pin, 1);
    relayon = true;
  }
  send(msg.set(relayon ? 1 : 0));
}

void SwitchScene() {
  //Domoticz does not like 1 as scene. So we start with scene 2.
  Serial.println("Long press");
  activescene += 1;
  if (activescene > 6) {
    activescene = 2;
  }
  Serial.print("Activating Scene ");
  Serial.println(activescene);
  send(msg1.set(activescene));
}

void SwitchSceneOff() {
  Serial.println("3sec Long Press");
  send(msg1.set(7));
}

[gohan]

@danbi
Configuring it as a gateway allows you to directly add it to the controller even it is isn't routing anything else than it's local I/O, making it very straightforward

[Efflon]

@Jan-Gatzke Thanks! A Interesting and inspiring code example. Did you think about using the arduinoOTA option instead of the httpUpdater?

[Jan Gatzke]

@Efflon

Yes, I thought about that. But during my tests the web updater was just most reliable and easiest to use. Arduino ota needs extensions to the IDE and sometimes the node was not found. Web updater works out of the box and never made any problems.

[Efflon]

@Jan-Gatzke Great to know!

[Bryden]

This sketch is awesome, First MySensors sketch I have used that worked straight off the bat.

The details page does need a few extra bits of info....

3.3v FTDI tool needed

Hold down the button on the Sonoff when you power it up to enter flash mode.

[Efflon]

@Bryden It's hidden in the code of the sketch "* Hold Sonoff button when attaching FTDI to flash."

[warmaniac]

@Efflon

Can I ask please ? I don't know if I understand correctly principle of working Sonoff under mysensors , I uploaded sketch from here to Sonoff , Sonoff is connected to my WiFi network , now I need to make MQTT gateway connected trought LAN or WiFi to the raspberry where is running Domoticz ? I had nodeMCU will it work ? Thanks much

[gohan]

You would need to use the esp8266 gateway sketch and connect it to domoticz as a new mysensors gateway. IMHO in this case it is easier to flash ESPEasy or espurna and use it as mqtt stand alone, not mysensors since you don't have a real benefit to have it running mysensors

[hek]

@gohan,
it depends on if the controller supports ESPEasy/espurna "out of the box". Not all controllers even have MQTT support.

[Efflon]

@warmaniac the sonoff works just like any sensor except its configured as a gateway since that is what is needed for esp8266+mysensors . Mqtt or ethernet/wifi is just a matter of taste and your setup, skip mqtt if you don't have anything else using it.

[warmaniac]

@Efflon said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

@warmaniac the sonoff works just like any sensor except its configured as a gateway since that is what is needed for esp8266+mysensors . Mqtt or ethernet/wifi is just a matter of taste and your setup, skip mqtt if you don't have anything else using it.

I want to use standalone Sonoff (one device) than I must install broker (Mosquito) on my raspberry where is Domoticz running ? And how can I add than that device or how can this setup looks like.

[Efflon]

@warmaniac You dont need mqtt/mosquitto. Just follow the guide at https://www.domoticz.com/wiki/MySensors for adding a "MySensors Gateway with LAN interface (Ethernet)" then follow the ethernet sketch here https://www.openhardware.io/view/318/Sonoff-relay-using-MySensors-ESP8266-wifi-or-mqtt-gateway

[warmaniac]

@Efflon

Tried LAN sketch after adding new hardware in domoticz this error occurs

2017-04-06 06:28:07.230 MQTT: Connecting to 192.168.2.209:5003
2017-04-06 06:28:07.335 Error: MQTT: disconnected, restarting (rc=2)

after that Sonoff blik twice. What may be wrong ?

Edit:

Understand now , it is added as classic mysensor LAN gateway , now working fine ! I tried to do it complicated way , but it was easy

2017-04-06 06:30:29.756 MySensors: trying to connect to: 192.168.2.209:5003
2017-04-06 06:30:30.757 MySensors: connected to: 192.168.2.209:5003
2017-04-06 06:30:30.758 MySensors: Gateway Ready...
2017-04-06 06:30:30.762 MySensors: Node: 0, Sketch Name: Sonoff ethernet
2017-04-06 06:30:30.763 MySensors: Node: 0, Sketch Version: 1.0
2017-04-06 06:30:30.769 (MQTT) Light/Switch (Light)
2017-04-06 06:30:31.778 MySensors: Gateway Version: 2.1.1
2017-04-06 06:30:31.779 MySensors: Gateway Version: 2.1.1

2017-04-06 06:31:11.939 User: Admin initiated a switch command (87/Sonoff-1/On)
2017-04-06 06:31:11.942 (MQTT) Light/Switch (Sonoff-1)
2017-04-06 06:31:12.789 (MQTT) Light/Switch (Sonoff-1)

[Efflon]

@warmaniac Excellent!

[Bryden]

Does anyone know how I can request the current state of the relay via MQTT.

Eg HASS has rebooted, forgotten what state the switch was previously in, then it wont work untill power is cycled to the sonoff.

I want to send an MQTT message to the sonoff to get its current state. Tried looking over the forums and page and cant seem to see anything about requesting a state from a binary switch / relay actuator

[martinhjelmare]

@Bryden

If you're using the mysensors component in home assistant, you can activate persistence to load devices and last known state when home assistant restarts.

Another option is to use the retain flag when publishing mqtt messages from the gateway. Support for this has been added in mysensors dev branch:
https://github.com/mysensors/MySensors/pull/793

[Matthew Ohlson de Fine]

How do you load the relay sensor in Vera after connecting the Sonoff as a wifi gateway as described?

[warmaniac]

After electricity plugged off , it stops working / not connecting to wifi router, but on manual click it turns on and of , it is problem because I don't use haas config ? I dont know where can I place them, can you help me ? thanks

[user2684]

Hi, I see in the instruction a note about not being tested against 220v so just to confirm it is working fine, I've uploaded the sketch to one of those with the power socket plug embedded and I'm able to control it remotely. Great job!
As a side note, I'd copy and paste the "Sonoff specific details" instructions from the sketch also into the build page. My bad because I've missed them and had to google a bit on how to upload the sketch but maybe also others may experience the same.
Thanks

[Efflon]

@user2684 Thanks for reporting. I have updated the instructions with the Sonoff details.

[betonishard]

Great work!

I was wondering if some of you already know if Espeasy supports the pow versions power usage reporting. I checked the github and couldn't find it. I know Espurna supports it (as a domoticz MQTT). However when I check the REST API of Esputna there is nothing noted about the power consumption (only humidity and temp) requests.

Any help is much appreciated.
Regards, and keep up the good work.

[user2684]

Hi, I have a sonoff device running this sketch since a few weeks now and everything is working great However I've noticed that when the wireless network goes off and then is restored back again the sonoff results still unreachable. When I unplug and plug it again the connection it comes back online. Is this a known behavior? Thanks

[gohan]

is it reachable via IP or is it totally unresponsive?

[user2684]

Totally unresponsive like once disconnected from the wifi (I turn it off from time to time), it is no more able to reconnect. I still need to understand if it happens every time so I was wondering if this was somehow expected or not

[warmaniac]

@gohan said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

is it reachable via IP or is it totally unresponsive?

I had same problem too.. When is longer not turned on, Sonoff disconnects from wifi , that ip is not in client list, in my case I only turn sonoff on throught black button on the top and than it is okay about day-two.

[Nca78]

I have few sonoff and I just installed one with this script to replace a dead 433 device. So thank you very much for the script and the tutorial.

Reports of regular wifi connection losses are what kept me away from sonoff until now. Maybe the script could check wifi connection regularly and force a reconnect. Something like in the link below ?
http://www.esp8266.com/viewtopic.php?f=32&t=8286

[Bryden]

Another I have had these running posts.

I have had 3 Sonoff relays running on 240v 50Hz for 2-3 months straight.

2 of them in IP67 outdoor lights with Phillips LED Lamps, switch on and off several times per day, Not a single hardware issue.

best $6 ever

[Ed1500]

@betonishard ESPeasy I am not sure, but supposedly Tasmota does

[Nca78]

@Bryden said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

Another I have had these running posts.

I have had 3 Sonoff relays running on 240v 50Hz for 2-3 months straight.

2 of them in IP67 outdoor lights with Phillips LED Lamps, switch on and off several times per day, Not a single hardware issue.

best $6 ever

Yes over one month and very reliable, but with Domoticz is not integrating very well with my old 433MHz remote controls (that I use for my remaining 433MHz module until they are replaced).
Making me think about a small plugin board to control the sonoff through serial port, so it would make a real MySensors node for 10$ and avoid all the power supply, relay etc etc soldering and not rely on wifi.

[gohan]

I remember reading non to connect any other serial device while the Sonoff is connected to mains or it would get damaged.

[Ed1500]

@gohan The only time you would need to connect a serial device is I guess when you are flashing the software. There is no needTheThe only time you need to connect a serial device is when you are flashing the software. There is no need to connect it to the mains grid then. Whether it would damage anything i do not know but it is unnecessary and therefore absolutely not recommended to do it. Avoid working on anything that is connected to mains, especially if there is no need to have it connected

[gohan]

I was referring to what @Nca78 said about controlling the sonoff through serial port.

[Ed1500]

@warmaniac you might have solved yr problem already. Anyway, I use the github/computourist software for the SonOff. have been using it for many months. very stable

[Ed1500]

@gohan ah ok. Sometimes I lose track of who is reacting to who. Must be old age

[Nca78]

@gohan said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

I remember reading non to connect any other serial device while the Sonoff is connected to mains or it would get damaged.

I supposed that's when you connect your computer to sonoff using serial adapter ?
I see no reason for damage if both es8266 and atmega are connected to the same VCC/GND.

[gohan]

I think it's because the gnd on the sonoff is shared with neutral from the mains. I have seen pictures of burned stuff but I actually never wanted to try to see if the computer gets fried or not

[Nca78]

@gohan yes with it could happen, but if you just connect a standalone Arduino powered with VCC GND from esp8266 there's no reason to have a problem.

[gohan]

But why would you want to connect another arduino to the sonoff?

[betonishard]

@Ed1500 Thanks for your answer. Went for espurna.. Tested tasmota, but compared to espurna it was kind of slow. Works stable for quite some time now.

[Ed1500]

@betonishard Good to know. I was thinking about trying Tasmota for regular Sonoff, but I will keep slowness in mind

[Nca78]

@gohan said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

But why would you want to connect another arduino to the sonoff?

To have a real MySensors node that can be directly controlled with another node and not relying on wifi and controller.

[gohan]

Sorry but I am still missing the point. If you have to make a mysensors node anyway, why not make a classic relay node?

[Nca78]

@gohan because when using the sonoff I do not have to care about the power supply/safety, to find a case that is safe for electrical device and I only have a few things to solder.
And sonoff is cheaper than buying separately the power supply, case, relay etc

So just solder a few low voltage components on a PCB, plug in the sonoff and get a safe main powered actuator.

Not 100% sure it's worth it yet, still thinking a out it
But main advantage is to reuse it in more complex sonoff devices with multiple relays, power measurement, in wall plugs etc etc

[gohan]

Once you come up with something I'll take a look to better understand what you want to do
I have seen how to hack some of them to add a couple of wires directly on the esp8266 chip to get an i2c bus.

[Jonathan Caes]

How can I create a new device in Vera for a gateway? Can't seem to get that working

[Jonathan Caes]

@efflon Do you know how I can setup the sonoff gateway on the Vera Edge? I used the MySensors plugin to add the sonoff to the network but can't get the relay to toggle.. Help is much appreciated!! Thanks!!

[tkald]

If someone wants, I create a modification to cooperate with DHT22. Data pin of DHT22 is connected to pin 5 of sonoff.

/**
 * The MySensors Arduino library handles the wireless radio link and protocol
 * between your home built sensors/actuators and HA controller of choice.
 * The sensors forms a self healing radio network with optional repeaters. Each
 * repeater and gateway builds a routing tables in EEPROM which keeps track of the
 * network topology allowing messages to be routed to nodes.
 *
 * Created by Henrik Ekblad <henrik.ekblad@mysensors.org>
 * Copyright (C) 2013-2015 Sensnology AB
 * Full contributor list: https://github.com/mysensors/Arduino/graphs/contributors
 *
 * Documentation: http://www.mysensors.org
 * Support Forum: http://forum.mysensors.org
 *
 * This program is free software; you can redistribute it and/or
 * modify it under the terms of the GNU General Public License
 * version 2 as published by the Free Software Foundation.
 *
 *******************************
 *
 * REVISION HISTORY
 * Version 1.0 - Henrik EKblad
 * Contribution by a-lurker and Anticimex,
 * Contribution by Norbert Truchsess <norbert.truchsess@t-online.de>
 * Contribution by Ivo Pullens (ESP8266 support)
 *
 * DESCRIPTION
 * The EthernetGateway sends data received from sensors to the WiFi link.
 * The gateway also accepts input on ethernet interface, which is then sent out to the radio network.
 *
 * VERA CONFIGURATION:
 * Enter "ip-number:port" in the ip-field of the Arduino GW device. This will temporarily override any serial configuration for the Vera plugin.
 * E.g. If you want to use the defualt values in this sketch enter: 192.168.178.66:5003
 *
 * LED purposes:
 * - To use the feature, uncomment any of the MY_DEFAULT_xx_LED_PINs in your sketch, only the LEDs that is defined is used.
 * - RX (green) - blink fast on radio message recieved. In inclusion mode will blink fast only on presentation recieved
 * - TX (yellow) - blink fast on radio message transmitted. In inclusion mode will blink slowly
 * - ERR (red) - fast blink on error during transmission error or recieve crc error
 *
 * See http://www.mysensors.org/build/esp8266_gateway for wiring instructions.
 * nRF24L01+  ESP8266
 * VCC        VCC
 * CE         GPIO4
 * CSN/CS     GPIO15
 * SCK        GPIO14
 * MISO       GPIO12
 * MOSI       GPIO13
 * GND        GND
 *
 * Not all ESP8266 modules have all pins available on their external interface.
 * This code has been tested on an ESP-12 module.
 * The ESP8266 requires a certain pin configuration to download code, and another one to run code:
 * - Connect REST (reset) via 10K pullup resistor to VCC, and via switch to GND ('reset switch')
 * - Connect GPIO15 via 10K pulldown resistor to GND
 * - Connect CH_PD via 10K resistor to VCC
 * - Connect GPIO2 via 10K resistor to VCC
 * - Connect GPIO0 via 10K resistor to VCC, and via switch to GND ('bootload switch')
 *
  * Inclusion mode button:
 * - Connect GPIO5 via switch to GND ('inclusion switch')
 *
 * Hardware SHA204 signing is currently not supported!
 *
 * Make sure to fill in your ssid and WiFi password below for ssid & pass.
 */

/**
 * Sonoff specific details (IM15116002)
 * 
 * The sonoff header left to right, relay above, LED below.
 *  [1]  vcc 3v3
 *   2   rx
 *   3   tx
 *   4   gnd
 *   5   
 *   
 * In arduinoIDE 1.6.* choose Generic ESP8226 module.
 * Hold Sonoff button when attaching FTDI to flash.
 */

// Enable debug prints to serial monitor
#define MY_DEBUG

// Use a bit lower baudrate for serial prints on ESP8266 than default in MyConfig.h
#define MY_BAUD_RATE 9600

// No radio in Sonoff
// Enables and select radio type (if attached)
// #define MY_RADIO_NRF24
// #define MY_RADIO_RFM69

#define MY_GATEWAY_ESP8266

#define MY_ESP8266_SSID "wifissid"
#define MY_ESP8266_PASSWORD "wifipassword"

// Enable UDP communication
//#define MY_USE_UDP

// Set the hostname for the WiFi Client. This is the hostname
// it will pass to the DHCP server if not static.
// #define MY_ESP8266_HOSTNAME "sensor-gateway"

// Enable MY_IP_ADDRESS here if you want a static ip address (no DHCP)
#define MY_IP_ADDRESS 192,168,2,200

// If using static ip you need to define Gateway and Subnet address as well
#define MY_IP_GATEWAY_ADDRESS 192,168,2,1
#define MY_IP_SUBNET_ADDRESS 255,255,255,0

// The port to keep open on node server mode
#define MY_PORT 5003

// How many clients should be able to connect to this gateway (default 1)
#define MY_GATEWAY_MAX_CLIENTS 1

// Controller ip address. Enables client mode (default is "server" mode).
// Also enable this if MY_USE_UDP is used and you want sensor data sent somewhere.
// #define MY_CONTROLLER_IP_ADDRESS 192, 168, 178, 68

/*
// Enable inclusion mode
#define MY_INCLUSION_MODE_FEATURE

// Enable Inclusion mode button on gateway
// #define MY_INCLUSION_BUTTON_FEATURE
// Set inclusion mode duration (in seconds)
#define MY_INCLUSION_MODE_DURATION 60
// Digital pin used for inclusion mode button
#define MY_INCLUSION_MODE_BUTTON_PIN  3


// Set blinking period
// #define MY_DEFAULT_LED_BLINK_PERIOD 300

// Flash leds on rx/tx/err
// Led pins used if blinking feature is enabled above
#define MY_DEFAULT_ERR_LED_PIN 16  // Error led pin
#define MY_DEFAULT_RX_LED_PIN  16  // Receive led pin
#define MY_DEFAULT_TX_LED_PIN  16  // the PCB, on board LED
*/

#if defined(MY_USE_UDP)
#include <WiFiUdp.h>
#endif

#include <ESP8266WiFi.h>
#include <MySensors.h>
#include <Bounce2.h>
#include <SPI.h>
#include <DHT.h>

#define BUTTON_PIN 0  // Sonoff pin number for button
#define RELAY_PIN 12  // Sonoff pin number for relay 
#define LED_PIN 13    // Sonoff pin number for LED
#define RELAY_ON 1
#define RELAY_OFF 0
#define LED_ON 0
#define LED_OFF 1
#define DHT_DATA_PIN 14
#define SENSOR_TEMP_OFFSET 0
static const uint64_t UPDATE_INTERVAL = 5000;
static const uint8_t FORCE_UPDATE_N_READS = 10;
unsigned long SLEEP_TIME = 5000; // Sleep time between reads (in milliseconds)
unsigned long lastRefreshTime = 0; // Use this to implement a non-blocking delay function

// Id of the sensor child
// Set unique id for each sonoff if sub/pub on same mqtt topic
#define CHILD_ID 0
#define CHILD_ID_HUM 1
#define CHILD_ID_TEMP 2

float lastTemp;
float lastHum;
uint8_t nNoUpdatesTemp;
uint8_t nNoUpdatesHum;
bool metric = true;

MyMessage msg(CHILD_ID,V_STATUS);
MyMessage msgHum(CHILD_ID_HUM, V_HUM);
MyMessage msgTemp(CHILD_ID_TEMP, V_TEMP);
DHT dht;

Bounce debouncer = Bounce(); 
int oldValue = 0;
bool state = false;



void setup()  
{  
  // Setup the button
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  // After setting up the button, setup debouncer
  debouncer.attach(BUTTON_PIN);
  debouncer.interval(5);

  // Make sure relays and LED are off when starting up
  digitalWrite(RELAY_PIN, RELAY_OFF);
  digitalWrite(LED_PIN, LED_OFF);

  // Then set relay pins in output mode
  pinMode(RELAY_PIN, OUTPUT);
  pinMode(LED_PIN, OUTPUT);

  dht.setup(DHT_DATA_PIN); // set data pin of DHT sensor
  if (UPDATE_INTERVAL <= dht.getMinimumSamplingPeriod()) {
    Serial.println("Warning: UPDATE_INTERVAL is smaller than supported by the sensor!");
  }
  // Sleep for the time of the minimum sampling period to give the sensor time to power up
  // (otherwise, timeout errors might occure for the first reading)
  sleep(dht.getMinimumSamplingPeriod());
   
}

void presentation()  {
  // Send the sketch version information
  sendSketchInfo("Sonoff ethernet DHT22", "1.0");
  // Register sensor
  present(CHILD_ID, S_BINARY);
  present(CHILD_ID_HUM, S_HUM);
  present(CHILD_ID_TEMP, S_TEMP);
  metric = getControllerConfig().isMetric;
  // Send the current state
  send(msg.set(state?true:false));
  // Blink when ready
  blink();
}


void loop()
{
  debouncer.update();
  // Get the update value
  int value = debouncer.read();
  if (value != oldValue && value==0) {
    // Toggle the state
    state = state?false:true;
    // Change relay state
    digitalWrite(RELAY_PIN, state?RELAY_ON:RELAY_OFF);
    // Change LED state
    digitalWrite(LED_PIN, state?LED_ON:LED_OFF);
    // Send new state
    send(msg.set(state)); 
  }
  oldValue = value;

  boolean needRefresh = (millis() - lastRefreshTime) > SLEEP_TIME;
  if (needRefresh)
  {
      lastRefreshTime = millis();
      
  // Force reading sensor, so it works also after sleep()
  dht.readSensor(true);

  // Get temperature from DHT library
  float temperature = dht.getTemperature();
  if (isnan(temperature)) {
    Serial.println("Failed reading temperature from DHT!");
  } else if (temperature != lastTemp || nNoUpdatesTemp == FORCE_UPDATE_N_READS) {
    // Only send temperature if it changed since the last measurement or if we didn't send an update for n times
    lastTemp = temperature;
    if (!metric) {
      temperature = dht.toFahrenheit(temperature);
    }
    // Reset no updates counter
    nNoUpdatesTemp = 0;
    temperature += SENSOR_TEMP_OFFSET;
    send(msgTemp.set(temperature, 1));

    #ifdef MY_DEBUG
    Serial.print("T: ");
    Serial.println(temperature);
    #endif
  } else {
    // Increase no update counter if the temperature stayed the same
    nNoUpdatesTemp++;
  }

  // Get humidity from DHT library
  float humidity = dht.getHumidity();
  if (isnan(humidity)) {
    Serial.println("Failed reading humidity from DHT");
  } else if (humidity != lastHum || nNoUpdatesHum == FORCE_UPDATE_N_READS) {
    // Only send humidity if it changed since the last measurement or if we didn't send an update for n times
    lastHum = humidity;
    // Reset no updates counter
    nNoUpdatesHum = 0;
    send(msgHum.set(humidity, 1));

    #ifdef MY_DEBUG
    Serial.print("H: ");
    Serial.println(humidity);
    #endif
  } else {
    // Increase no update counter if the humidity stayed the same
    nNoUpdatesHum++;
  }
}
  // Sleep for a while to save energy
  //sleep(UPDATE_INTERVAL); 
}

void receive(const MyMessage &message)
{
  // We only react on status messages from the controller
  // to this CHILD_ID.
  if (message.type==V_STATUS  && message.sensor==CHILD_ID) {
    // Change relay state
    // Only switch if the state is new
    if (message.getBool() != state) {
      state = message.getBool();
      // Change relay state
      digitalWrite(RELAY_PIN, state?RELAY_ON:RELAY_OFF);
      // Change LED state
      digitalWrite(LED_PIN, state?LED_ON:LED_OFF);
       // Send the current state
      send(msg.set(state));  
    }
  }
}

void blink()
{
  digitalWrite(LED_PIN, digitalRead(LED_PIN)?LED_ON:LED_OFF);
  wait(200);
  digitalWrite(LED_PIN, digitalRead(LED_PIN)?LED_ON:LED_OFF);
  wait(200);
  digitalWrite(LED_PIN, digitalRead(LED_PIN)?LED_ON:LED_OFF);
  wait(200);
  digitalWrite(LED_PIN, digitalRead(LED_PIN)?LED_ON:LED_OFF);
}

[Morten Mathiasen]

I think it is an easier and more general solution to use https://github.com/arendst/Sonoff-Tasmota

[gohan]

@Morten-Mathiasen that is the one I'm using on my sonoff pow

[dbemowsk]

@Jonathan-Caes said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

Do you know how I can setup the sonoff gateway on the Vera Edge?

I am using a Vera Plus. I did not go the route of MySensors for my Sonoffs. I use the ESP Easy firmware with a slightly modified Vera plugin. Here is my BLOG post on how to do it.
https://dan.bemowski.info/2017/07/04/using-a-sonoff-with-espeasy-and-vera/

You could still go the MySensors route. I just figured I'd show another alternative to this.

[Jan Gatzke]

It's a shame that we cannot have both, mysensors and the ESP Easy stuff. There has been a project for this: https://github.com/letscontrolit/ESPEasyMySensors

[dbemowsk]

@Jan-Gatzke It is my understanding that ESP Easy can send and receive MQTT messages, couldn't you just use a MySensors MQTT gateway if you wanted to keep it on the MySensors path?

[Jan Gatzke]

@dbemowsk You cannot because MQTT is just a transport and not a strict data format. You can however use MySenSors MQTT + ESP Easy MQTT + a broker + node red + a controller. Node Red can do data conversions and integrate everything.

[dbemowsk]

@Jan-Gatzke I was just speculating. I do not use MQTT, so I am by no means an authority on the subject.

[gohan]

@Jan-Gatzke said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

It's a shame that we cannot have both, mysensors and the ESP Easy stuff. There has been a project for this: https://github.com/letscontrolit/ESPEasyMySensors

There is no real benefit to have the sonoff running mysensors instead of other firmwares, if your controller is able to communicate over mqtt to switch on/off the relay, you are fine

[Jan Gatzke]

@gohan I know some controller are aware of ESP Easy via MQTT. If you controller does not support this directly, you have to integrate it manually (with node red). In my opinion scenarios, where MySensors with ESP Easy frontend would be of use, do still exist.

[Nca78]

@gohan said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

There is no real benefit to have the sonoff running mysensors instead of other firmwares, if your controller is able to communicate over mqtt to switch on/off the relay, you are fine

IMHO there is one, when your controller is down, gateway is down or whatever, you could still have direct control or the light switch from a MySensors button with node to node communication.

[gohan]

How do you do that if the sonoff is only having wifi?

[Nca78]

@gohan said in Sonoff relay using MySensors ESP8266 wifi or mqtt gateway:

How do you do that if the sonoff is only having wifi?

Ah yes in that case you can't and yes there's no benefit

[gohan]

A wired button would be a much fail safe option for sonoffs

[Jan Gatzke]

@gohan won't this option miss some features?

[gohan]

@Jan-Gatzke for a sonoff there aren't many options and also a wired button you are pretty sure it would always work.

[dbemowsk]

For the Sonoffs, you could wire an external button directly to the onboard button which is on GPIO 0, or you could wire it to GPIO 14 which is broken out on the programming header on most Sonoffs. Some older Sonoffs didn't have GPIO 14 on that header. Once you have a button or switch wired on, you can then change the code or do some firmware scripting depending which flavor of firmware you use.

[sam9s]

@dbemowsk Do you know if there is a way to use vera edge / plus with Tasmota firmware instead of EasyESP??

[dbemowsk]

@sam9s I have never played with Tasmota, so I have to say that I don't know. A Vera plugin would have to be coded or modified as I did with the HTTP Switch plugin to make it work if there is not one out there already. I am assuming that you looked at my blog post on the ESP Easy way.

[gohan]

Can the Vera plug in work with mqtt?

[dbemowsk]

@gohan Here is a plugin for MQTT using Vera. You would still need to have an MQTT Broker set up though. I am surprised that there is not an active MQTT plugin for Vera in the plugins section. Didn't find anything when I did a search for MQTT.

[gohan]

I was just asking since tasmota works great on mqtt

[tripy]

I will just leave that here for other like me that wondered for hours why they could flash their sonoff, but it did not react once plugged to the main.

You need to setup your arduino with DOUT as flash mode.
Other mode will flash without errors, but the device will appear bricked.
My settings where:

[kalle]

@tripy yes, you are absolute right - you need to set the flash Mode to DOUT for flashing the newer SONOFF generation (the SONOFF's with the hidden green LED).

[vladimir]

Hello!
Maybe someone here has a code for Sonoff RF with support 433 MHz receiver?

In my opinion, paired with a wireless wall switch, this will turn out to be quite a cheap and convenient solution for lighting control.

The cost of a set of relay and switch about 10 dollars.

[electrik]

Did you try this?
https://github.com/arendst/Sonoff-Tasmota

[vladimir]

@electrik Now I just read the description of this firmware. To do this, I need to understand how to work with MQTT. I hoped to find a simpler solution. Ethernet gateway is much easier to connect.

[electrik]

Mqtt Is really easy to use in fact. Just follow a tutorial to install mosquitto and you're ready to go.
It also depends on your controller of course

[vladimir]

@electrik Thanks you! Now I will order everything I need on TaoBao in China. I just yesterday learned about the existence of the Sonoff module with 433 MHz radio support and wall switches for them.

[gohan]

@vladimir what controller are you using? Most home automation controllers like domoticz and Home Assistant have a quick integration with Tasmota or EspEasy

[vladimir]

@gohan I use OpenHAB 2. As I understand it, it also integrates well with Tasmota.

[gohan]

good, give it a try